* [gentoo-commits] gentoo-x86 commit in games-strategy/defcon-demo: ChangeLog defcon-demo-1.60.ebuild
@ 2012-12-31 14:10 Julian Ospald (hasufell)
0 siblings, 0 replies; only message in thread
From: Julian Ospald (hasufell) @ 2012-12-31 14:10 UTC (permalink / raw
To: gentoo-commits
hasufell 12/12/31 14:10:22
Modified: ChangeLog
Added: defcon-demo-1.60.ebuild
Log:
version bump wrt #448434
(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)
Revision Changes Path
1.7 games-strategy/defcon-demo/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/defcon-demo/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/defcon-demo/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/defcon-demo/ChangeLog?r1=1.6&r2=1.7
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/defcon-demo/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog 20 Dec 2012 07:25:37 -0000 1.6
+++ ChangeLog 31 Dec 2012 14:10:21 -0000 1.7
@@ -1,6 +1,11 @@
# ChangeLog for games-strategy/defcon-demo
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/defcon-demo/ChangeLog,v 1.6 2012/12/20 07:25:37 tupone Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/defcon-demo/ChangeLog,v 1.7 2012/12/31 14:10:21 hasufell Exp $
+
+*defcon-demo-1.60 (31 Dec 2012)
+
+ 31 Dec 2012; Julian Ospald <hasufell@gentoo.org> +defcon-demo-1.60.ebuild:
+ version bump wrt #448434
20 Dec 2012; Tupone Alfredo <tupone@gentoo.org> defcon-demo-1.42.ebuild:
Migrate to EAPI=5.
1.1 games-strategy/defcon-demo/defcon-demo-1.60.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/defcon-demo/defcon-demo-1.60.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-strategy/defcon-demo/defcon-demo-1.60.ebuild?rev=1.1&content-type=text/plain
Index: defcon-demo-1.60.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/defcon-demo/defcon-demo-1.60.ebuild,v 1.1 2012/12/31 14:10:21 hasufell Exp $
EAPI=5
inherit eutils toolchain-funcs gnome2-utils games
MY_PN=defcon
MY_PV=${PV:0:3}
MY_PVR=1
MY_P=defcon_${MY_PV}-${MY_PVR}
DESCRIPTION="Global thermonuclear war simulation with multiplayer support"
HOMEPAGE="http://www.introversion.co.uk/defcon/"
SRC_URI="x86? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_i386.deb )
amd64? ( http://www.introversion.co.uk/defcon/downloads/${MY_P}_amd64.deb )"
LICENSE="Introversion"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="+system-libs"
RESTRICT="mirror strip"
# glibc discussion:
# http://forums.introversion.co.uk/defcon/viewtopic.php?t=4016
RDEPEND="
media-libs/libogg
media-libs/libvorbis
>=sys-libs/glibc-2.3
x11-libs/libX11
x11-libs/libXau
x11-libs/libXext
x11-libs/libXdmcp
system-libs? ( media-libs/libsdl )"
DEPEND=""
QA_PREBUILT="${GAMES_PREFIX_OPT:1}/${PN}/lib/${MY_PN}.bin.x86"
S=${WORKDIR}/usr/local/games/${MY_PN}
src_unpack() {
default
unpack ./data.tar.gz
cd "${S}" || die
# maintain compatibility with old installation/script
[[ -e lib64 ]] && { mv lib64 lib || die ;}
[[ -e ${MY_PN}.bin.x86_64 ]] && { mv ${MY_PN}.bin.x86_64 ${MY_PN}.bin.x86 || die ;}
}
src_prepare() {
# FindPath scripts are ugly and unnecessary
if use system-libs ; then
rm -f lib/lib*
fi
sed \
-e "s:GAMEDIR:${GAMES_PREFIX_OPT}/${PN}:g" \
"${FILESDIR}"/${MY_PN} > "${T}"/${MY_PN} \
|| die "sed failed"
echo "int chdir(const char *d) { return 0; }" > chdir.c \
|| die "echo failed"
}
src_compile() {
echo "$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c"
$(tc-getCC) ${CFLAGS} ${LDFLAGS} -fPIC -shared -o lib/chdir.so chdir.c || die
}
src_install() {
local dir=${GAMES_PREFIX_OPT}/${PN}
insinto "${dir}/lib"
doins *.dat
exeinto "${dir}"/lib
doexe lib/*.so
doexe ${MY_PN}.bin.x86
doicon -s 128 ${MY_PN}.png
# Can be upgraded to full version, so is not installed as "demo"
dogamesbin "${T}"/${MY_PN}
make_desktop_entry ${MY_PN} "Defcon"
prepgamesdirs
}
pkg_preinst() {
games_pkg_preinst
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
gnome2_icon_cache_update
elog "Screenshots will appear in ~/.${MY_PN}/lib"
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-12-31 14:10 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-31 14:10 [gentoo-commits] gentoo-x86 commit in games-strategy/defcon-demo: ChangeLog defcon-demo-1.60.ebuild Julian Ospald (hasufell)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox