[gentoo-commits] gentoo-x86 commit in media-libs/coin: coin-3.1.3-r2.ebuild metadata.xml ChangeLog coin-3.1.0.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/coin: coin-3.1.3-r2.ebuild metadata.xml ChangeLog coin-3.1.0.ebuild

[Justin Lecher (jlec)]

jlec        12/12/26 14:30:07

  Modified:             metadata.xml ChangeLog
  Added:                coin-3.1.3-r2.ebuild
  Removed:              coin-3.1.0.ebuild
  Log:
  media-libs/coin: Add fix for build with gcc-4.7, #448614; move to EAPI=5 and autotools-utils.eclass; add some prefix awareness; drop old
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.6                  media-libs/coin/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/coin/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	24 Sep 2011 09:39:11 -0000	1.5
+++ metadata.xml	26 Dec 2012 14:30:07 -0000	1.6
@@ -1,10 +1,10 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer>
-	<email>reavertm@gentoo.org</email>
-</maintainer>
-<use>
-	<flag name="simage">Texture loading via <pkg>media-libs/simage</pkg> library</flag>
-</use>
+  <maintainer>
+    <email>reavertm@gentoo.org</email>
+  </maintainer>
+  <use>
+    <flag name="simage">Texture loading via <pkg>media-libs/simage</pkg> library</flag>
+  </use>
 </pkgmetadata>



1.41                 media-libs/coin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/coin/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog	5 May 2012 08:02:38 -0000	1.40
+++ ChangeLog	26 Dec 2012 14:30:07 -0000	1.41
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/coin
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/ChangeLog,v 1.40 2012/05/05 08:02:38 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/ChangeLog,v 1.41 2012/12/26 14:30:07 jlec Exp $
+
+*coin-3.1.3-r2 (26 Dec 2012)
+
+  26 Dec 2012; Justin Lecher <jlec@gentoo.org> -coin-3.1.0.ebuild,
+  +coin-3.1.3-r2.ebuild, +files/coin-3.1.3-gcc-4.7.patch,
+  files/coin-3.1.3-pkgconfig-partial.patch, metadata.xml:
+  Add fix for build with gcc-4.7, #448614; move to EAPI=5 and
+  autotools-utils.eclass; add some prefix awareness; drop old
 
   05 May 2012; Jeff Horelick <jdhore@gentoo.org> coin-3.1.0.ebuild,
   coin-3.1.3-r1.ebuild:



1.1                  media-libs/coin/coin-3.1.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/coin-3.1.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/coin/coin-3.1.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: coin-3.1.3-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/coin/coin-3.1.3-r2.ebuild,v 1.1 2012/12/26 14:30:07 jlec Exp $

EAPI=5

inherit autotools-utils flag-o-matic

MY_P=${P/c/C}

DESCRIPTION="A high-level 3D graphics toolkit, fully compatible with SGI Open Inventor 2.1."
HOMEPAGE="http://www.coin3d.org/"
SRC_URI="ftp://ftp.coin3d.org/pub/coin/src/all/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 PEL )"
KEYWORDS="~amd64 ~ppc ~x86"
SLOT="0"
IUSE="bzip2 debug doc javascript openal simage static-libs threads zlib"

# NOTE: expat is not really needed as --enable-system-expat is broken
RDEPEND="
	dev-libs/expat
	media-libs/fontconfig
	media-libs/freetype:2
	virtual/opengl
	virtual/glu
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXext
	bzip2? ( app-arch/bzip2 )
	javascript? ( dev-lang/spidermonkey )
	openal? ( media-libs/openal )
	simage? ( media-libs/simage )
	zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	x11-proto/xextproto
	doc? ( app-doc/doxygen )
"
S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}"/${PN}-3.1.0-javascript.patch
	"${FILESDIR}"/${P}-pkgconfig-partial.patch
	"${FILESDIR}"/${P}-gcc-4.7.patch
)

DOCS=(
	AUTHORS FAQ FAQ.legal NEWS README RELNOTES THANKS
	docs/{ChangeLog.v${PV},HACKING,oiki-launch.txt}
)

src_configure() {
	append-cppflags -I"${EPREFIX}/usr/include/freetype2"
	# Prefer link-time linking over dlopen
	local myeconfargs=(
		htmldir="/usr/share/doc/${PF}/html"
		--disable-dl-fontconfig
		--disable-dl-freetype
		--disable-dl-libbzip2
		--disable-dl-openal
		--disable-dl-simage
		--disable-dl-zlib
		--disable-dyld
		--disable-loadlibrary
		--disable-man
		--disable-java-wrapper
		--enable-3ds-import
		--enable-compact
		--enable-dl-glu
		--enable-dl-spidermonkey
		--enable-system-expat
		--includedir="/usr/include/${PN}"
		--with-fontconfig
		--with-freetype
		$(use_with bzip2)
		$(use_enable debug)
		$(use_enable debug symbols)
		$(use_enable doc html)
		$(use_enable javascript javascript-api)
		$(use_with javascript spidermonkey)
		$(use_enable openal sound)
		$(use_with openal)
		$(use_with simage)
		$(use_enable threads threadsafe)
		$(use_with zlib)
		)
	autotools-utils_src_configure
}

src_install() {
	# Remove Coin from Libs.private
	sed -e '/Libs.private/s/ -lCoin//' -i "${BUILD_DIR}"/Coin.pc || die

	autotools-utils_src_install
}