* [gentoo-commits] gentoo-x86 commit in dev-python/PyQt4: metadata.xml PyQt4-4.9.6-r1.ebuild ChangeLog
@ 2012-12-26 3:11 Davide Pesavento (pesa)
0 siblings, 0 replies; only message in thread
From: Davide Pesavento (pesa) @ 2012-12-26 3:11 UTC (permalink / raw
To: gentoo-commits
pesa 12/12/26 03:11:43
Modified: metadata.xml ChangeLog
Added: PyQt4-4.9.6-r1.ebuild
Log:
EAPI=5 to be able to use slot operators in sip dependency. Sync USE flags with pyside: rename assistant to help, add script and scripttools (bug 431460 by Arfrever).
(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)
Revision Changes Path
1.12 dev-python/PyQt4/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/metadata.xml?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/metadata.xml?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/metadata.xml?r1=1.11&r2=1.12
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/PyQt4/metadata.xml,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- metadata.xml 13 May 2012 14:08:01 -0000 1.11
+++ metadata.xml 26 Dec 2012 03:11:43 -0000 1.12
@@ -7,10 +7,13 @@
<flag name="X">Build QtGui, QtDesigner and QtScriptTools modules</flag>
<flag name="assistant">Build QtHelp and QtAssistant modules</flag>
<flag name="declarative">Build QtDeclarative module</flag>
+ <flag name="help">Build QtHelp module</flag>
<flag name="kde">Select <pkg>media-libs/phonon</pkg> as Phonon variant (needed for KDE)</flag>
<flag name="multimedia">Build QtMultimedia module</flag>
<flag name="opengl">Build QtOpenGL module</flag>
<flag name="phonon">Build phonon module</flag>
+ <flag name="script">Build QtScript module</flag>
+ <flag name="scripttools">Build QtScriptTools module</flag>
<flag name="sql">Build QtSql module</flag>
<flag name="svg">Build QtSvg module</flag>
<flag name="webkit">Build QtWebKit module</flag>
1.204 dev-python/PyQt4/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/ChangeLog?rev=1.204&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/ChangeLog?rev=1.204&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/ChangeLog?r1=1.203&r2=1.204
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/PyQt4/ChangeLog,v
retrieving revision 1.203
retrieving revision 1.204
diff -u -r1.203 -r1.204
--- ChangeLog 10 Dec 2012 11:20:38 -0000 1.203
+++ ChangeLog 26 Dec 2012 03:11:43 -0000 1.204
@@ -1,6 +1,14 @@
# ChangeLog for dev-python/PyQt4
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/PyQt4/ChangeLog,v 1.203 2012/12/10 11:20:38 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/PyQt4/ChangeLog,v 1.204 2012/12/26 03:11:43 pesa Exp $
+
+*PyQt4-4.9.6-r1 (26 Dec 2012)
+
+ 26 Dec 2012; Davide Pesavento <pesa@gentoo.org> +PyQt4-4.9.6-r1.ebuild,
+ metadata.xml:
+ EAPI=5 to be able to use slot operators in sip dependency. Sync USE flags with
+ pyside: rename assistant to help, add script and scripttools (bug 431460 by
+ Arfrever).
*PyQt4-4.9.6 (10 Dec 2012)
1.1 dev-python/PyQt4/PyQt4-4.9.6-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/PyQt4-4.9.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/PyQt4/PyQt4-4.9.6-r1.ebuild?rev=1.1&content-type=text/plain
Index: PyQt4-4.9.6-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/PyQt4/PyQt4-4.9.6-r1.ebuild,v 1.1 2012/12/26 03:11:43 pesa Exp $
EAPI=5
PYTHON_DEPEND="*"
PYTHON_EXPORT_PHASE_FUNCTIONS="1"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="*-jython *-pypy-*"
inherit eutils qt4-r2 python toolchain-funcs
DESCRIPTION="Python bindings for the Qt toolkit"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/pyqt/intro/ http://pypi.python.org/pypi/PyQt"
if [[ ${PV} == *_pre* ]]; then
MY_P="PyQt-x11-gpl-snapshot-${PV%_pre*}-${REVISION}"
SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${MY_P}.tar.gz"
else
MY_P="PyQt-x11-gpl-${PV}"
SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
fi
LICENSE="|| ( GPL-2 GPL-3 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="X dbus debug declarative doc examples help kde multimedia opengl phonon script scripttools sql svg webkit xmlpatterns"
REQUIRED_USE="
declarative? ( X )
help? ( X )
multimedia? ( X )
opengl? ( X )
phonon? ( X )
scripttools? ( X script )
sql? ( X )
svg? ( X )
webkit? ( X )
"
# Minimal supported version of Qt.
QT_PV="4.8.0:4"
RDEPEND="
>=dev-python/sip-4.14.2:=
>=x11-libs/qt-core-${QT_PV}
X? (
>=x11-libs/qt-gui-${QT_PV}[dbus?]
>=x11-libs/qt-test-${QT_PV}
)
dbus? (
>=dev-python/dbus-python-0.80
>=x11-libs/qt-dbus-${QT_PV}
)
declarative? ( >=x11-libs/qt-declarative-${QT_PV} )
help? ( >=x11-libs/qt-assistant-${QT_PV} )
multimedia? ( >=x11-libs/qt-multimedia-${QT_PV} )
opengl? ( >=x11-libs/qt-opengl-${QT_PV} )
phonon? (
kde? ( media-libs/phonon )
!kde? ( || ( >=x11-libs/qt-phonon-${QT_PV} media-libs/phonon ) )
)
script? ( >=x11-libs/qt-script-${QT_PV} )
sql? ( >=x11-libs/qt-sql-${QT_PV} )
svg? ( >=x11-libs/qt-svg-${QT_PV} )
webkit? ( >=x11-libs/qt-webkit-${QT_PV} )
xmlpatterns? ( >=x11-libs/qt-xmlpatterns-${QT_PV} )
"
DEPEND="${RDEPEND}
dbus? ( virtual/pkgconfig )
"
S=${WORKDIR}/${MY_P}
PYTHON_VERSIONED_EXECUTABLES=("/usr/bin/pyuic4")
src_prepare() {
qt4-r2_src_prepare
# Support qreal on arm architecture (bug 322349).
use arm && epatch "${FILESDIR}/${PN}-4.7.3-qreal_float_support.patch"
# Use proper include directory for phonon.
sed -i -e "s:^\s\+generate_code(\"phonon\":&, extra_include_dirs=[\"${EPREFIX}/usr/include/phonon\"]:" \
configure.py || die
if ! use dbus; then
sed -i -e 's/^\(\s\+\)check_dbus()/\1pass/' configure.py || die
fi
python_copy_sources
preparation() {
if [[ $(python_get_version -l --major) == 3 ]]; then
rm -fr pyuic/uic/port_v2
else
rm -fr pyuic/uic/port_v3
fi
}
python_execute_function -s preparation
}
pyqt4_use_enable() {
use $1 && echo --enable=${2:-Qt$(echo ${1:0:1} | tr '[:lower:]' '[:upper:]')${1:1}}
}
src_configure() {
configuration() {
local myconf=(
"$(PYTHON)" configure.py
--confirm-license
--bindir="${EPREFIX}/usr/bin"
--destdir="${EPREFIX}$(python_get_sitedir)"
--sipdir="${EPREFIX}/usr/share/sip"
--assume-shared
--no-timestamp
--qsci-api
$(use debug && echo --debug)
--enable=QtCore
--enable=QtNetwork
--enable=QtXml
$(pyqt4_use_enable X QtDesigner) $(use X || echo --no-designer-plugin)
$(pyqt4_use_enable X QtGui)
$(pyqt4_use_enable X QtTest)
$(pyqt4_use_enable dbus QtDBus)
$(pyqt4_use_enable declarative)
$(pyqt4_use_enable help)
$(pyqt4_use_enable multimedia)
$(pyqt4_use_enable opengl QtOpenGL)
$(pyqt4_use_enable phonon phonon)
$(pyqt4_use_enable script)
$(pyqt4_use_enable scripttools QtScriptTools)
$(pyqt4_use_enable sql)
$(pyqt4_use_enable svg)
$(pyqt4_use_enable webkit QtWebKit)
$(pyqt4_use_enable xmlpatterns QtXmlPatterns)
AR="$(tc-getAR) cqs"
CC="$(tc-getCC)"
CFLAGS="${CFLAGS}"
CFLAGS_RELEASE=
CXX="$(tc-getCXX)"
CXXFLAGS="${CXXFLAGS}"
CXXFLAGS_RELEASE=
LINK="$(tc-getCXX)"
LINK_SHLIB="$(tc-getCXX)"
LFLAGS="${LDFLAGS}"
LFLAGS_RELEASE=
RANLIB=
STRIP=
)
echo "${myconf[@]}"
"${myconf[@]}" || die
local mod
for mod in QtCore \
$(use X && echo QtDesigner QtGui) \
$(use dbus && echo QtDBus) \
$(use declarative && echo QtDeclarative) \
$(use opengl && echo QtOpenGL); do
# Run eqmake4 inside the qpy subdirectories to respect
# CC, CXX, CFLAGS, CXXFLAGS, LDFLAGS and avoid stripping.
pushd qpy/${mod} > /dev/null || return
eqmake4 $(ls w_qpy*.pro)
popd > /dev/null || return
# Fix insecure runpaths.
sed -i -e "/^LFLAGS\s*=/ s:-Wl,-rpath,${BUILDDIR}/qpy/${mod}::" \
${mod}/Makefile || die "Failed to fix rpath for ${mod}"
done
# Avoid stripping of libpythonplugin.so.
if use X; then
pushd designer > /dev/null || return
eqmake4 python.pro
popd > /dev/null || return
fi
}
python_execute_function -s configuration
}
src_install() {
installation() {
# INSTALL_ROOT is used by designer/Makefile, other Makefiles use DESTDIR.
emake DESTDIR="${T}/images/${PYTHON_ABI}" INSTALL_ROOT="${T}/images/${PYTHON_ABI}" install
}
python_execute_function -s installation
python_merge_intermediate_installation_images "${T}/images"
dodoc NEWS THANKS
if use doc; then
dohtml -r doc/html/*
fi
if use examples; then
insinto /usr/share/doc/${PF}
doins -r examples
fi
}
pkg_postinst() {
python_mod_optimize PyQt4
}
pkg_postrm() {
python_mod_cleanup PyQt4
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-12-26 3:12 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-26 3:11 [gentoo-commits] gentoo-x86 commit in dev-python/PyQt4: metadata.xml PyQt4-4.9.6-r1.ebuild ChangeLog Davide Pesavento (pesa)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox