[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: ChangeLog stunnel-4.54.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: ChangeLog stunnel-4.54.ebuild

[Lance Albertson (ramereth)]

ramereth    12/12/25 04:25:06

  Modified:             ChangeLog
  Added:                stunnel-4.54.ebuild
  Log:
  Version bump, fix init script, fixes #448298 & #436268
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 27F4B742)

Revision  Changes    Path
1.132                net-misc/stunnel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.132&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.132&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?r1=1.131&r2=1.132

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v
retrieving revision 1.131
retrieving revision 1.132
diff -u -r1.131 -r1.132
--- ChangeLog	19 Oct 2012 08:47:01 -0000	1.131
+++ ChangeLog	25 Dec 2012 04:25:06 -0000	1.132
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/stunnel
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.131 2012/10/19 08:47:01 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.132 2012/12/25 04:25:06 ramereth Exp $
+
+*stunnel-4.54 (25 Dec 2012)
+
+  25 Dec 2012; Lance Albertson <ramereth@gentoo.org> +stunnel-4.54.ebuild,
+  +files/stunnel-4.54-listen-queue.patch,
+  +files/stunnel-4.54-xforwarded-for.patch,
+  files/stunnel.initd-start-stop-daemon:
+  Version bump, fix init script, fixes #448298 & #436268
 
   19 Oct 2012; Christoph Junghans <ottxor@gentoo.org> stunnel-4.44-r1.ebuild:
   added prefix support (bug #435792)



1.1                  net-misc/stunnel/stunnel-4.54.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-4.54.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-4.54.ebuild?rev=1.1&content-type=text/plain

Index: stunnel-4.54.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-4.54.ebuild,v 1.1 2012/12/25 04:25:06 ramereth Exp $

EAPI="4"

inherit autotools ssl-cert eutils user

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://stunnel.mirt.net/"
SRC_URI="ftp://ftp.stunnel.org/stunnel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="ipv6 selinux tcpd xforward listen-queue"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=dev-libs/openssl-0.9.8k"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_prepare() {
	use xforward && epatch "${FILESDIR}/stunnel-${PV}-xforwarded-for.patch"
	use listen-queue && epatch "${FILESDIR}/stunnel-${PV}-listen-queue.patch"
	eautoreconf

	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_configure() {
	econf $(use_enable ipv6) \
		--with-ssl="${EPREFIX}"/usr \
		$(use_enable tcpd libwrap)
}

src_install() {
	emake DESTDIR="${D}" install
	rm -rf "${ED}"/usr/share/doc/${PN}
	rm -f "${ED}"/etc/stunnel/stunnel.conf-sample "${ED}"/usr/bin/stunnel3 \
		"${ED}"/usr/share/man/man8/stunnel.{fr,pl}.8

	# The binary was moved to /usr/bin with 4.21,
	# symlink for backwards compatibility
	dosym ../bin/stunnel /usr/sbin/stunnel

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	doins "${FILESDIR}"/stunnel.conf
	newinitd "${FILESDIR}"/stunnel.initd-start-stop-daemon stunnel

	keepdir /var/run/stunnel
	fowners stunnel:stunnel /var/run/stunnel
}

pkg_postinst() {
	if [ ! -f "${EROOT}"/etc/stunnel/stunnel.key ]; then
		install_cert /etc/stunnel/stunnel
		chown stunnel:stunnel "${EROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
		chmod 0640 "${EROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
	fi

	einfo "If you want to run multiple instances of stunnel, create a new config"
	einfo "file ending with .conf in /etc/stunnel/. **Make sure** you change "
	einfo "\'pid= \' with a unique filename."
}