* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
@ 2012-12-25 4:08 Mike Frysinger (vapier)
0 siblings, 0 replies; 5+ messages in thread
From: Mike Frysinger (vapier) @ 2012-12-25 4:08 UTC (permalink / raw
To: gentoo-commits
vapier 12/12/25 04:08:18
Modified: xbmc-9999.ebuild ChangeLog
Added: xbmc-12.0_rc2.ebuild
Log:
Add USE=java to contain upstream idiocy #434662 by BT. Version bump #443572 by Tomasz Golinski.
(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.125 media-tv/xbmc/xbmc-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.125&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.125&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?r1=1.124&r2=1.125
Index: xbmc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v
retrieving revision 1.124
retrieving revision 1.125
diff -u -r1.124 -r1.125
--- xbmc-9999.ebuild 24 Dec 2012 02:10:04 -0000 1.124
+++ xbmc-9999.ebuild 25 Dec 2012 04:08:18 -0000 1.125
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.124 2012/12/24 02:10:04 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.125 2012/12/25 04:08:18 vapier Exp $
EAPI="4"
@@ -8,25 +8,34 @@
# It might work with py:2.5 but I didn't test that
PYTHON_DEPEND="2:2.6"
-inherit eutils python
+inherit eutils python multiprocessing autotools
-EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
-if [[ ${PV} == "9999" ]] ; then
- inherit git-2 autotools
-else
- inherit autotools
+case ${PV} in
+9999)
+ EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
+ inherit git-2
+ SRC_URI="!java? ( mirror://gentoo/${P}-20121224-generated-addons.tar.xz )"
+ ;;
+*_alpha*|*_beta*|*_rc*)
+ MY_PV="Frodo_${PV#*_}"
+ MY_P="${PN}-${MY_PV}"
+ SRC_URI="https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
+ !java? ( mirror://gentoo/${P}-generated-addons.tar.xz )"
+ KEYWORDS="~amd64 ~x86"
+ ;;
+*)
MY_P=${P/_/-*_}
SRC_URI="http://mirrors.xbmc.org/releases/source/${MY_P}.tar.gz"
KEYWORDS="~amd64 ~x86"
- S=${WORKDIR}/${MY_P}
-fi
+ ;;
+esac
DESCRIPTION="XBMC is a free and open source media-player and entertainment hub"
HOMEPAGE="http://xbmc.org/"
LICENSE="GPL-2"
SLOT="0"
-IUSE="airplay alsa altivec avahi bluetooth bluray cec css debug goom joystick midi mysql nfs profile +projectm pulseaudio pvr +rsxs rtmp +samba sse sse2 sftp udev upnp vaapi vdpau webserver +xrandr"
+IUSE="airplay alsa altivec avahi bluetooth bluray cec css debug goom java joystick midi mysql nfs profile +projectm pulseaudio pvr +rsxs rtmp +samba sse sse2 sftp udev upnp vaapi vdpau webserver +xrandr"
REQUIRED_USE="pvr? ( mysql )"
COMMON_DEPEND="virtual/glu
@@ -102,11 +111,15 @@
RDEPEND="${COMMON_DEPEND}
udev? ( sys-fs/udisks:0 sys-power/upower )"
DEPEND="${COMMON_DEPEND}
+ app-arch/xz-utils
dev-lang/swig
dev-util/gperf
x11-proto/xineramaproto
dev-util/cmake
- x86? ( dev-lang/nasm )"
+ x86? ( dev-lang/nasm )
+ java? ( virtual/jre )"
+
+S=${WORKDIR}/${MY_P}
pkg_setup() {
python_set_active_version 2
@@ -114,18 +127,7 @@
}
src_unpack() {
- if [[ ${PV} == "9999" ]] ; then
- git-2_src_unpack
- cd "${S}"
- rm -f configure
- else
- unpack ${A}
- cd "${S}"
- fi
-
- # Fix case sensitivity
- mv media/Fonts/{a,A}rial.ttf || die
- mv media/{S,s}plash.png || die
+ [[ ${PV} == "9999" ]] && git-2_src_unpack || default
}
src_prepare() {
@@ -135,18 +137,17 @@
rm -f configure
# some dirs ship generated autotools, some dont
+ multijob_init
local d
- for d in \
- . \
- lib/{libdvd/lib*/,cpluff} \
- xbmc/screensavers/rsxs-* \
- xbmc/visualizations/Goom/goom2k4-0
- do
- [[ -e ${d}/configure ]] && continue
- pushd ${d} >/dev/null
- eautoreconf
+ for d in $(printf 'f:\n\techo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
+ [[ -e ${d} ]] && continue
+ pushd ${d/%\/configure/.} >/dev/null
+ AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" \
+ multijob_child_init eautoreconf
popd >/dev/null
done
+ multijob_finish
+ elibtoolize
# Disable internal func checks as our USE/DEPEND
# stuff handles this just fine already #408395
@@ -183,6 +184,8 @@
export HELP2MAN=$(type -P help2man || echo true)
# No configure flage for this #403561
export ac_cv_lib_bluetooth_hci_devid=$(usex bluetooth)
+ # Requiring java is asine #434662
+ export ac_cv_path_JAVA_EXE=$(which $(usex java java true))
econf \
--docdir=/usr/share/doc/${PF} \
1.159 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.159&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.159&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.158&r2=1.159
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.158
retrieving revision 1.159
diff -u -r1.158 -r1.159
--- ChangeLog 24 Dec 2012 02:10:04 -0000 1.158
+++ ChangeLog 25 Dec 2012 04:08:18 -0000 1.159
@@ -1,6 +1,13 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.158 2012/12/24 02:10:04 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.159 2012/12/25 04:08:18 vapier Exp $
+
+*xbmc-12.0_rc2 (25 Dec 2012)
+
+ 25 Dec 2012; Mike Frysinger <vapier@gentoo.org> +xbmc-12.0_rc2.ebuild,
+ xbmc-9999.ebuild:
+ Add USE=java to contain upstream idiocy #434662 by BT. Version bump #443572
+ by Tomasz Golinski.
24 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-9999.ebuild:
Require libcec-2+ #438376 by Ian Whyman.
1.1 media-tv/xbmc/xbmc-12.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.1&content-type=text/plain
Index: xbmc-12.0_rc2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.1 2012/12/25 04:08:18 vapier Exp $
EAPI="4"
# Does not work with py3 here
# It might work with py:2.5 but I didn't test that
PYTHON_DEPEND="2:2.6"
inherit eutils python multiprocessing autotools
case ${PV} in
9999)
EGIT_REPO_URI="git://github.com/xbmc/xbmc.git"
inherit git-2
SRC_URI="!java? ( mirror://gentoo/${P}-20121224-generated-addons.tar.xz )"
;;
*_alpha*|*_beta*|*_rc*)
MY_PV="Frodo_${PV#*_}"
MY_P="${PN}-${MY_PV}"
SRC_URI="https://github.com/xbmc/xbmc/archive/${MY_PV}.tar.gz -> ${P}.tar.gz
!java? ( mirror://gentoo/${P}-generated-addons.tar.xz )"
KEYWORDS="~amd64 ~x86"
;;
*)
MY_P=${P/_/-*_}
SRC_URI="http://mirrors.xbmc.org/releases/source/${MY_P}.tar.gz"
KEYWORDS="~amd64 ~x86"
;;
esac
DESCRIPTION="XBMC is a free and open source media-player and entertainment hub"
HOMEPAGE="http://xbmc.org/"
LICENSE="GPL-2"
SLOT="0"
IUSE="airplay alsa altivec avahi bluetooth bluray cec css debug goom java joystick midi mysql nfs profile +projectm pulseaudio pvr +rsxs rtmp +samba sse sse2 sftp udev upnp vaapi vdpau webserver +xrandr"
REQUIRED_USE="pvr? ( mysql )"
COMMON_DEPEND="virtual/glu
virtual/opengl
app-arch/bzip2
app-arch/unzip
app-arch/zip
app-i18n/enca
airplay? ( app-pda/libplist )
>=dev-lang/python-2.4
dev-libs/boost
dev-libs/fribidi
dev-libs/libcdio[-minimal]
cec? ( >=dev-libs/libcec-2 )
dev-libs/libpcre[cxx]
>=dev-libs/lzo-2.04
dev-libs/tinyxml
dev-libs/yajl
>=dev-python/pysqlite-2
dev-python/simplejson
media-libs/alsa-lib
media-libs/flac
media-libs/fontconfig
media-libs/freetype
>=media-libs/glew-1.5.6
media-libs/jasper
media-libs/jbigkit
>=media-libs/libass-0.9.7
bluray? ( media-libs/libbluray )
css? ( media-libs/libdvdcss )
media-libs/libmad
media-libs/libmodplug
media-libs/libmpeg2
media-libs/libogg
media-libs/libpng
projectm? ( media-libs/libprojectm )
media-libs/libsamplerate
media-libs/libsdl[audio,opengl,video,X]
alsa? ( media-libs/libsdl[alsa] )
>=media-libs/taglib-1.8
media-libs/libvorbis
media-libs/sdl-gfx
>=media-libs/sdl-image-1.2.10[gif,jpeg,png]
media-libs/sdl-mixer
media-libs/sdl-sound
media-libs/tiff
pulseaudio? ( media-sound/pulseaudio )
media-sound/wavpack
|| ( media-libs/libpostproc <media-video/libav-0.8.2-r1 media-video/ffmpeg )
>=virtual/ffmpeg-0.6[encode]
rtmp? ( media-video/rtmpdump )
avahi? ( net-dns/avahi )
nfs? ( net-fs/libnfs )
webserver? ( net-libs/libmicrohttpd )
sftp? ( net-libs/libssh )
net-misc/curl
samba? ( >=net-fs/samba-3.4.6[smbclient] )
bluetooth? ( net-wireless/bluez )
sys-apps/dbus
sys-libs/zlib
virtual/jpeg
mysql? ( virtual/mysql )
x11-apps/xdpyinfo
x11-apps/mesa-progs
vaapi? ( x11-libs/libva[opengl] )
vdpau? (
|| ( x11-libs/libvdpau >=x11-drivers/nvidia-drivers-180.51 )
virtual/ffmpeg[vdpau]
)
x11-libs/libXinerama
xrandr? ( x11-libs/libXrandr )
x11-libs/libXrender"
RDEPEND="${COMMON_DEPEND}
udev? ( sys-fs/udisks:0 sys-power/upower )"
DEPEND="${COMMON_DEPEND}
app-arch/xz-utils
dev-lang/swig
dev-util/gperf
x11-proto/xineramaproto
dev-util/cmake
x86? ( dev-lang/nasm )
java? ( virtual/jre )"
S=${WORKDIR}/${MY_P}
pkg_setup() {
python_set_active_version 2
python_pkg_setup
}
src_unpack() {
[[ ${PV} == "9999" ]] && git-2_src_unpack
default
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-9999-nomythtv.patch
epatch "${FILESDIR}"/${PN}-9999-no-arm-flags.patch #400617
# The mythtv patch touches configure.ac, so force a regen
rm -f configure
# some dirs ship generated autotools, some dont
multijob_init
local d
for d in $(printf 'f:\n\techo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
[[ -e ${d} ]] && continue
pushd ${d/%\/configure/.} >/dev/null
AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" \
multijob_child_init eautoreconf
popd >/dev/null
done
multijob_finish
elibtoolize
# Disable internal func checks as our USE/DEPEND
# stuff handles this just fine already #408395
export ac_cv_lib_avcodec_ff_vdpau_vc1_decode_picture=yes
local squish #290564
use altivec && squish="-DSQUISH_USE_ALTIVEC=1 -maltivec"
use sse && squish="-DSQUISH_USE_SSE=1 -msse"
use sse2 && squish="-DSQUISH_USE_SSE=2 -msse2"
sed -i \
-e '/^CXXFLAGS/{s:-D[^=]*=.::;s:-m[[:alnum:]]*::}' \
-e "1iCXXFLAGS += ${squish}" \
lib/libsquish/Makefile.in || die
# Fix XBMC's final version string showing as "exported"
# instead of the SVN revision number.
export HAVE_GIT=no GIT_REV=${EGIT_VERSION:-exported}
# avoid long delays when powerkit isn't running #348580
sed -i \
-e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
xbmc/linux/*.cpp || die
epatch_user #293109
# Tweak autotool timestamps to avoid regeneration
find . -type f -print0 | xargs -0 touch -r configure
}
src_configure() {
# Disable documentation generation
export ac_cv_path_LATEX=no
# Avoid help2man
export HELP2MAN=$(type -P help2man || echo true)
# No configure flage for this #403561
export ac_cv_lib_bluetooth_hci_devid=$(usex bluetooth)
# Requiring java is asine #434662
export ac_cv_path_JAVA_EXE=$(which $(usex java java true))
econf \
--docdir=/usr/share/doc/${PF} \
--disable-ccache \
--disable-optimizations \
--enable-external-libraries \
--enable-gl \
$(use_enable airplay) \
$(use_enable avahi) \
$(use_enable bluray libbluray) \
$(use_enable cec libcec) \
$(use_enable css dvdcss) \
$(use_enable debug) \
$(use_enable goom) \
--disable-hal \
$(use_enable joystick) \
$(use_enable midi mid) \
$(use_enable mysql) \
$(use_enable nfs) \
$(use_enable profile profiling) \
$(use_enable projectm) \
$(use_enable pulseaudio pulse) \
$(use_enable pvr mythtv) \
$(use_enable rsxs) \
$(use_enable rtmp) \
$(use_enable samba) \
$(use_enable sftp ssh) \
$(use_enable upnp) \
$(use_enable vaapi) \
$(use_enable vdpau) \
$(use_enable webserver) \
$(use_enable xrandr)
}
src_install() {
default
rm "${ED}"/usr/share/doc/*/{LICENSE.GPL,copying.txt}*
domenu tools/Linux/xbmc.desktop
newicon tools/Linux/xbmc-48x48.png xbmc.png
insinto "$(python_get_sitedir)" #309885
doins tools/EventClients/lib/python/xbmcclient.py || die
newbin "tools/EventClients/Clients/XBMC Send/xbmc-send.py" xbmc-send || die
}
pkg_postinst() {
elog "Visit http://wiki.xbmc.org/?title=XBMC_Online_Manual"
}
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
@ 2012-12-25 19:25 Mike Frysinger (vapier)
0 siblings, 0 replies; 5+ messages in thread
From: Mike Frysinger (vapier) @ 2012-12-25 19:25 UTC (permalink / raw
To: gentoo-commits
vapier 12/12/25 19:25:34
Modified: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
Log:
Fix lookup of dirs to autotool #448488 by Ivan.
(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.126 media-tv/xbmc/xbmc-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.126&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.126&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?r1=1.125&r2=1.126
Index: xbmc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v
retrieving revision 1.125
retrieving revision 1.126
diff -u -r1.125 -r1.126
--- xbmc-9999.ebuild 25 Dec 2012 04:08:18 -0000 1.125
+++ xbmc-9999.ebuild 25 Dec 2012 19:25:34 -0000 1.126
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.125 2012/12/25 04:08:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.126 2012/12/25 19:25:34 vapier Exp $
EAPI="4"
@@ -139,9 +139,9 @@
# some dirs ship generated autotools, some dont
multijob_init
local d
- for d in $(printf 'f:\n\techo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
+ for d in $(printf 'f:\n\t@echo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
[[ -e ${d} ]] && continue
- pushd ${d/%\/configure/.} >/dev/null
+ pushd ${d/%configure/.} >/dev/null || die
AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" \
multijob_child_init eautoreconf
popd >/dev/null
1.2 media-tv/xbmc/xbmc-12.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?r1=1.1&r2=1.2
Index: xbmc-12.0_rc2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- xbmc-12.0_rc2.ebuild 25 Dec 2012 04:08:18 -0000 1.1
+++ xbmc-12.0_rc2.ebuild 25 Dec 2012 19:25:34 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.1 2012/12/25 04:08:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.2 2012/12/25 19:25:34 vapier Exp $
EAPI="4"
@@ -127,8 +127,7 @@
}
src_unpack() {
- [[ ${PV} == "9999" ]] && git-2_src_unpack
- default
+ [[ ${PV} == "9999" ]] && git-2_src_unpack || default
}
src_prepare() {
@@ -140,9 +139,9 @@
# some dirs ship generated autotools, some dont
multijob_init
local d
- for d in $(printf 'f:\n\techo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
+ for d in $(printf 'f:\n\t@echo $(BOOTSTRAP_TARGETS)\ninclude bootstrap.mk\n' | emake -f - f) ; do
[[ -e ${d} ]] && continue
- pushd ${d/%\/configure/.} >/dev/null
+ pushd ${d/%configure/.} >/dev/null || die
AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" \
multijob_child_init eautoreconf
popd >/dev/null
1.160 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.160&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.160&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.159&r2=1.160
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.159
retrieving revision 1.160
diff -u -r1.159 -r1.160
--- ChangeLog 25 Dec 2012 04:08:18 -0000 1.159
+++ ChangeLog 25 Dec 2012 19:25:34 -0000 1.160
@@ -1,6 +1,10 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.159 2012/12/25 04:08:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.160 2012/12/25 19:25:34 vapier Exp $
+
+ 25 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
+ xbmc-9999.ebuild:
+ Fix lookup of dirs to autotool #448488 by Ivan.
*xbmc-12.0_rc2 (25 Dec 2012)
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
@ 2012-12-29 4:37 Mike Frysinger (vapier)
0 siblings, 0 replies; 5+ messages in thread
From: Mike Frysinger (vapier) @ 2012-12-29 4:37 UTC (permalink / raw
To: gentoo-commits
vapier 12/12/29 04:37:36
Modified: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
Log:
Depend on tinyxml[stl] since xbmc uses those features #448754#3 by Ben Kohler.
(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.127 media-tv/xbmc/xbmc-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?r1=1.126&r2=1.127
Index: xbmc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- xbmc-9999.ebuild 25 Dec 2012 19:25:34 -0000 1.126
+++ xbmc-9999.ebuild 29 Dec 2012 04:37:36 -0000 1.127
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.126 2012/12/25 19:25:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.127 2012/12/29 04:37:36 vapier Exp $
EAPI="4"
@@ -52,7 +52,7 @@
cec? ( >=dev-libs/libcec-2 )
dev-libs/libpcre[cxx]
>=dev-libs/lzo-2.04
- dev-libs/tinyxml
+ dev-libs/tinyxml[stl]
dev-libs/yajl
>=dev-python/pysqlite-2
dev-python/simplejson
1.3 media-tv/xbmc/xbmc-12.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?r1=1.2&r2=1.3
Index: xbmc-12.0_rc2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- xbmc-12.0_rc2.ebuild 25 Dec 2012 19:25:34 -0000 1.2
+++ xbmc-12.0_rc2.ebuild 29 Dec 2012 04:37:36 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.2 2012/12/25 19:25:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.3 2012/12/29 04:37:36 vapier Exp $
EAPI="4"
@@ -52,7 +52,7 @@
cec? ( >=dev-libs/libcec-2 )
dev-libs/libpcre[cxx]
>=dev-libs/lzo-2.04
- dev-libs/tinyxml
+ dev-libs/tinyxml[stl]
dev-libs/yajl
>=dev-python/pysqlite-2
dev-python/simplejson
1.161 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.161&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.161&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.160&r2=1.161
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.160
retrieving revision 1.161
diff -u -r1.160 -r1.161
--- ChangeLog 25 Dec 2012 19:25:34 -0000 1.160
+++ ChangeLog 29 Dec 2012 04:37:36 -0000 1.161
@@ -1,6 +1,10 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.160 2012/12/25 19:25:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.161 2012/12/29 04:37:36 vapier Exp $
+
+ 29 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
+ xbmc-9999.ebuild:
+ Depend on tinyxml[stl] since xbmc uses those features #448754#3 by Ben Kohler.
25 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
xbmc-9999.ebuild:
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
@ 2012-12-29 4:39 Mike Frysinger (vapier)
0 siblings, 0 replies; 5+ messages in thread
From: Mike Frysinger (vapier) @ 2012-12-29 4:39 UTC (permalink / raw
To: gentoo-commits
vapier 12/12/29 04:39:38
Modified: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
Log:
Require a recent libmicrohttpd version #449082 by Ben Kohler.
(Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)
Revision Changes Path
1.128 media-tv/xbmc/xbmc-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?r1=1.127&r2=1.128
Index: xbmc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- xbmc-9999.ebuild 29 Dec 2012 04:37:36 -0000 1.127
+++ xbmc-9999.ebuild 29 Dec 2012 04:39:38 -0000 1.128
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.127 2012/12/29 04:37:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.128 2012/12/29 04:39:38 vapier Exp $
EAPI="4"
@@ -89,7 +89,7 @@
rtmp? ( media-video/rtmpdump )
avahi? ( net-dns/avahi )
nfs? ( net-fs/libnfs )
- webserver? ( net-libs/libmicrohttpd )
+ webserver? ( >=net-libs/libmicrohttpd-0.9.24 )
sftp? ( net-libs/libssh )
net-misc/curl
samba? ( >=net-fs/samba-3.4.6[smbclient] )
1.4 media-tv/xbmc/xbmc-12.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?r1=1.3&r2=1.4
Index: xbmc-12.0_rc2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- xbmc-12.0_rc2.ebuild 29 Dec 2012 04:37:36 -0000 1.3
+++ xbmc-12.0_rc2.ebuild 29 Dec 2012 04:39:38 -0000 1.4
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.3 2012/12/29 04:37:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.4 2012/12/29 04:39:38 vapier Exp $
EAPI="4"
@@ -89,7 +89,7 @@
rtmp? ( media-video/rtmpdump )
avahi? ( net-dns/avahi )
nfs? ( net-fs/libnfs )
- webserver? ( net-libs/libmicrohttpd )
+ webserver? ( >=net-libs/libmicrohttpd-0.9.24 )
sftp? ( net-libs/libssh )
net-misc/curl
samba? ( >=net-fs/samba-3.4.6[smbclient] )
1.162 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.162&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.162&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.161&r2=1.162
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.161
retrieving revision 1.162
diff -u -r1.161 -r1.162
--- ChangeLog 29 Dec 2012 04:37:36 -0000 1.161
+++ ChangeLog 29 Dec 2012 04:39:38 -0000 1.162
@@ -1,6 +1,10 @@
# ChangeLog for media-tv/xbmc
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.161 2012/12/29 04:37:36 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.162 2012/12/29 04:39:38 vapier Exp $
+
+ 29 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
+ xbmc-9999.ebuild:
+ Require a recent libmicrohttpd version #449082 by Ben Kohler.
29 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
xbmc-9999.ebuild:
^ permalink raw reply [flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
@ 2013-01-15 23:41 Michal Gorny (mgorny)
0 siblings, 0 replies; 5+ messages in thread
From: Michal Gorny (mgorny) @ 2013-01-15 23:41 UTC (permalink / raw
To: gentoo-commits
mgorny 13/01/15 23:41:33
Modified: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog
Log:
Fix sqlite3 module dependency -- the package supports only built-in Python sqlite3, not external pysqlite2.
(Portage version: 2.2.0_alpha152/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)
Revision Changes Path
1.130 media-tv/xbmc/xbmc-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.130&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?rev=1.130&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild?r1=1.129&r2=1.130
Index: xbmc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v
retrieving revision 1.129
retrieving revision 1.130
diff -u -r1.129 -r1.130
--- xbmc-9999.ebuild 29 Dec 2012 20:12:18 -0000 1.129
+++ xbmc-9999.ebuild 15 Jan 2013 23:41:32 -0000 1.130
@@ -1,12 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.129 2012/12/29 20:12:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-9999.ebuild,v 1.130 2013/01/15 23:41:32 mgorny Exp $
EAPI="4"
# Does not work with py3 here
# It might work with py:2.5 but I didn't test that
PYTHON_DEPEND="2:2.6"
+PYTHON_USE_WITH=sqlite
inherit eutils python multiprocessing autotools
@@ -54,7 +55,6 @@
>=dev-libs/lzo-2.04
dev-libs/tinyxml[stl]
dev-libs/yajl
- >=dev-python/pysqlite-2
dev-python/simplejson
media-libs/alsa-lib
media-libs/flac
1.6 media-tv/xbmc/xbmc-12.0_rc2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild?r1=1.5&r2=1.6
Index: xbmc-12.0_rc2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- xbmc-12.0_rc2.ebuild 29 Dec 2012 20:12:18 -0000 1.5
+++ xbmc-12.0_rc2.ebuild 15 Jan 2013 23:41:32 -0000 1.6
@@ -1,12 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.5 2012/12/29 20:12:18 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/xbmc-12.0_rc2.ebuild,v 1.6 2013/01/15 23:41:32 mgorny Exp $
EAPI="4"
# Does not work with py3 here
# It might work with py:2.5 but I didn't test that
PYTHON_DEPEND="2:2.6"
+PYTHON_USE_WITH=sqlite
inherit eutils python multiprocessing autotools
@@ -54,7 +55,6 @@
>=dev-libs/lzo-2.04
dev-libs/tinyxml[stl]
dev-libs/yajl
- >=dev-python/pysqlite-2
dev-python/simplejson
media-libs/alsa-lib
media-libs/flac
1.164 media-tv/xbmc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.164&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?rev=1.164&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-tv/xbmc/ChangeLog?r1=1.163&r2=1.164
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v
retrieving revision 1.163
retrieving revision 1.164
diff -u -r1.163 -r1.164
--- ChangeLog 29 Dec 2012 20:12:18 -0000 1.163
+++ ChangeLog 15 Jan 2013 23:41:32 -0000 1.164
@@ -1,6 +1,11 @@
# ChangeLog for media-tv/xbmc
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.163 2012/12/29 20:12:18 vapier Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-tv/xbmc/ChangeLog,v 1.164 2013/01/15 23:41:32 mgorny Exp $
+
+ 15 Jan 2013; Michał Górny <mgorny@gentoo.org> xbmc-12.0_rc2.ebuild,
+ xbmc-9999.ebuild:
+ Fix sqlite3 module dependency -- the package supports only built-in Python
+ sqlite3, not external pysqlite2.
29 Dec 2012; Mike Frysinger <vapier@gentoo.org> xbmc-12.0_rc2.ebuild,
xbmc-9999.ebuild:
^ permalink raw reply [flat|nested] 5+ messages in thread
end of thread, other threads:[~2013-01-15 23:41 UTC | newest]
Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-25 4:08 [gentoo-commits] gentoo-x86 commit in media-tv/xbmc: xbmc-9999.ebuild xbmc-12.0_rc2.ebuild ChangeLog Mike Frysinger (vapier)
-- strict thread matches above, loose matches on Subject: below --
2012-12-25 19:25 Mike Frysinger (vapier)
2012-12-29 4:37 Mike Frysinger (vapier)
2012-12-29 4:39 Mike Frysinger (vapier)
2013-01-15 23:41 Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox