public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in sys-apps/iproute2: iproute2-3.7.0.ebuild iproute2-9999.ebuild ChangeLog
@ 2012-12-14  6:40 Mike Frysinger (vapier)
  0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2012-12-14  6:40 UTC (permalink / raw
  To: gentoo-commits

vapier      12/12/14 06:40:51

  Modified:             iproute2-9999.ebuild ChangeLog
  Added:                iproute2-3.7.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.23                 sys-apps/iproute2/iproute2-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?r1=1.22&r2=1.23

Index: iproute2-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- iproute2-9999.ebuild	1 Jun 2012 04:26:02 -0000	1.22
+++ iproute2-9999.ebuild	14 Dec 2012 06:40:51 -0000	1.23
@@ -1,10 +1,10 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.22 2012/06/01 04:26:02 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.23 2012/12/14 06:40:51 vapier Exp $
 
 EAPI="4"
 
-inherit eutils multilib toolchain-funcs flag-o-matic
+inherit eutils toolchain-funcs flag-o-matic multilib
 
 if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
@@ -12,7 +12,7 @@
 	SRC_URI=""
 	#KEYWORDS=""
 else
-	SRC_URI="mirror://kernel/linux/utils/net/${PN}/${P}.tar.bz2"
+	SRC_URI="mirror://kernel/linux/utils/net/${PN}/${P}.tar.xz"
 	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
 fi
 
@@ -28,6 +28,7 @@
 	!minimal? ( berkdb? ( sys-libs/db ) )
 	atm? ( net-dialup/linux-atm )"
 DEPEND="${RDEPEND}
+	app-arch/xz-utils
 	iptables? ( virtual/pkgconfig )
 	sys-devel/bison
 	sys-devel/flex
@@ -46,6 +47,7 @@
 
 	# build against system headers
 	rm -r include/netinet #include/linux include/ip{,6}tables{,_common}.h include/libiptc
+	sed -i 's:TCPI_OPT_ECN_SEEN:16:' misc/ss.c || die
 
 	# don't build arpd if USE=-berkdb #81660
 	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile
@@ -83,11 +85,17 @@
 
 	emake \
 		DESTDIR="${D}" \
-		SBINDIR=/sbin \
-		DOCDIR=/usr/share/doc/${PF} \
-		MANDIR=/usr/share/man \
+		LIBDIR="${EPREFIX}"/$(get_libdir) \
+		SBINDIR="${EPREFIX}"/sbin \
+		CONFDIR="${EPREFIX}"/etc/iproute2 \
+		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
+		MANDIR="${EPREFIX}"/usr/share/man \
+		ARPDDIR="${EPREFIX}"/var/lib/arpd \
 		install
 
+	dodir /bin
+	mv "${ED}"/{s,}bin/ip || die #330115
+
 	dolib.a lib/libnetlink.a
 	insinto /usr/include
 	doins include/libnetlink.h
@@ -95,7 +103,7 @@
 	if use berkdb ; then
 		dodir /var/lib/arpd
 		# bug 47482, arpd doesn't need to be in /sbin
-		dodir /usr/sbin
-		mv "${ED}"/sbin/arpd "${ED}"/usr/sbin/
+		dodir /usr/bin
+		mv "${ED}"/sbin/arpd "${ED}"/usr/bin/ || die
 	fi
 }



1.204                sys-apps/iproute2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.204&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.204&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?r1=1.203&r2=1.204

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v
retrieving revision 1.203
retrieving revision 1.204
diff -u -r1.203 -r1.204
--- ChangeLog	8 Nov 2012 16:40:45 -0000	1.203
+++ ChangeLog	14 Dec 2012 06:40:51 -0000	1.204
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/iproute2
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.203 2012/11/08 16:40:45 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.204 2012/12/14 06:40:51 vapier Exp $
+
+*iproute2-3.7.0 (14 Dec 2012)
+
+  14 Dec 2012; Mike Frysinger <vapier@gentoo.org> +iproute2-3.7.0.ebuild,
+  iproute2-9999.ebuild:
+  Version bump.
 
   08 Nov 2012; Mike Frysinger <vapier@gentoo.org>
   +files/iproute2-3.6.0-pkg-config.patch, iproute2-3.6.0.ebuild:



1.1                  sys-apps/iproute2/iproute2-3.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-3.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-3.7.0.ebuild?rev=1.1&content-type=text/plain

Index: iproute2-3.7.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-3.7.0.ebuild,v 1.1 2012/12/14 06:40:51 vapier Exp $

EAPI="4"

inherit eutils toolchain-funcs flag-o-matic multilib

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
	inherit git-2
	SRC_URI=""
	#KEYWORDS=""
else
	SRC_URI="mirror://kernel/linux/utils/net/${PN}/${P}.tar.xz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi

DESCRIPTION="kernel routing and traffic control utilities"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"

LICENSE="GPL-2"
SLOT="0"
IUSE="atm berkdb +iptables ipv6 minimal"

RDEPEND="!net-misc/arpd
	iptables? ( >=net-firewall/iptables-1.4.5 )
	!minimal? ( berkdb? ( sys-libs/db ) )
	atm? ( net-dialup/linux-atm )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	iptables? ( virtual/pkgconfig )
	sys-devel/bison
	sys-devel/flex
	>=sys-kernel/linux-headers-2.6.27
	elibc_glibc? ( >=sys-libs/glibc-2.7 )"

S=${WORKDIR}/${P/2} # fluke :/

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.1.0-mtu.patch #291907
	use ipv6 || epatch "${FILESDIR}"/${PN}-3.1.0-no-ipv6.patch #326849

	sed -i \
		-e '/^CC =/d' \
		-e "/^LIBDIR/s:=.*:=/$(get_libdir):" \
		-e "s:-O2:${CFLAGS} ${CPPFLAGS}:" \
		Makefile || die

	# build against system headers
	rm -r include/netinet #include/linux include/ip{,6}tables{,_common}.h include/libiptc
	sed -i 's:TCPI_OPT_ECN_SEEN:16:' misc/ss.c || die

	# don't build arpd if USE=-berkdb #81660
	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile

	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
}

src_configure() {
	tc-export AR CC PKG_CONFIG

	# This sure is ugly.  Should probably move into toolchain-funcs at some point.
	local setns
	pushd "${T}" >/dev/null
	echo 'main(){return setns();};' > test.c
	${CC} ${CFLAGS} ${LDFLAGS} test.c >&/dev/null && setns=y || setns=n
	echo 'main(){};' > test.c
	${CC} ${CFLAGS} ${LDFLAGS} test.c -lresolv >&/dev/null || sed -i '/^LDLIBS/s:-lresolv::' "${S}"/Makefile
	popd >/dev/null

	cat <<-EOF > Config
	TC_CONFIG_ATM := $(usex atm y n)
	TC_CONFIG_XT  := $(usex iptables y n)
	IP_CONFIG_SETNS := ${setns}
	# Use correct iptables dir, #144265 #293709
	IPT_LIB_DIR := $(use iptables && ${PKG_CONFIG} xtables --variable=xtlibdir)
	EOF
}

src_install() {
	if use minimal ; then
		into /
		dosbin tc/tc
		return 0
	fi

	emake \
		DESTDIR="${D}" \
		LIBDIR="${EPREFIX}"/$(get_libdir) \
		SBINDIR="${EPREFIX}"/sbin \
		CONFDIR="${EPREFIX}"/etc/iproute2 \
		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
		MANDIR="${EPREFIX}"/usr/share/man \
		ARPDDIR="${EPREFIX}"/var/lib/arpd \
		install

	dodir /bin
	mv "${ED}"/{s,}bin/ip || die #330115

	dolib.a lib/libnetlink.a
	insinto /usr/include
	doins include/libnetlink.h

	if use berkdb ; then
		dodir /var/lib/arpd
		# bug 47482, arpd doesn't need to be in /sbin
		dodir /usr/bin
		mv "${ED}"/sbin/arpd "${ED}"/usr/bin/ || die
	fi
}





^ permalink raw reply	[flat|nested] only message in thread
only message in thread, other threads:[~2012-12-14  6:41 UTC | newest]

Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-14  6:40 [gentoo-commits] gentoo-x86 commit in sys-apps/iproute2: iproute2-3.7.0.ebuild iproute2-9999.ebuild ChangeLog Mike Frysinger (vapier)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox