* [gentoo-commits] gentoo-x86 commit in dev-db/postgresql-base: postgresql-base-9.2.2.ebuild postgresql-base-9.0.11.ebuild postgresql-base-9.1.7.ebuild postgresql-base-8.4.15.ebuild postgresql-base-8.3.22.ebuild ChangeLog
@ 2012-12-10 6:01 Patrick Lauer (patrick)
0 siblings, 0 replies; only message in thread
From: Patrick Lauer (patrick) @ 2012-12-10 6:01 UTC (permalink / raw
To: gentoo-commits
patrick 12/12/10 06:01:02
Modified: ChangeLog
Added: postgresql-base-9.2.2.ebuild
postgresql-base-9.0.11.ebuild
postgresql-base-9.1.7.ebuild
postgresql-base-8.4.15.ebuild
postgresql-base-8.3.22.ebuild
Log:
Bump
(Portage version: 2.2.0_alpha147/cvs/Linux x86_64, unsigned Manifest commit)
Revision Changes Path
1.216 dev-db/postgresql-base/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/ChangeLog?rev=1.216&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/ChangeLog?rev=1.216&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/ChangeLog?r1=1.215&r2=1.216
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v
retrieving revision 1.215
retrieving revision 1.216
diff -u -r1.215 -r1.216
--- ChangeLog 1 Dec 2012 19:10:30 -0000 1.215
+++ ChangeLog 10 Dec 2012 06:01:02 -0000 1.216
@@ -1,6 +1,18 @@
# ChangeLog for dev-db/postgresql-base
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.215 2012/12/01 19:10:30 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/ChangeLog,v 1.216 2012/12/10 06:01:02 patrick Exp $
+
+*postgresql-base-8.3.22 (10 Dec 2012)
+*postgresql-base-9.1.7 (10 Dec 2012)
+*postgresql-base-8.4.15 (10 Dec 2012)
+*postgresql-base-9.0.11 (10 Dec 2012)
+*postgresql-base-9.2.2 (10 Dec 2012)
+
+ 10 Dec 2012; Patrick Lauer <patrick@gentoo.org>
+ +postgresql-base-8.3.22.ebuild, +postgresql-base-8.4.15.ebuild,
+ +postgresql-base-9.0.11.ebuild, +postgresql-base-9.1.7.ebuild,
+ +postgresql-base-9.2.2.ebuild:
+ Bump
01 Dec 2012; Raúl Porcel <armin76@gentoo.org> postgresql-base-8.3.21.ebuild,
postgresql-base-8.4.14.ebuild, postgresql-base-9.0.10.ebuild,
1.1 dev-db/postgresql-base/postgresql-base-9.2.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.2.2.ebuild?rev=1.1&content-type=text/plain
Index: postgresql-base-9.2.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.2.2.ebuild,v 1.1 2012/12/10 06:01:02 patrick Exp $
EAPI="4"
WANT_AUTOMAKE="none"
inherit autotools eutils flag-o-matic multilib prefix versionator
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~ppc-macos ~x86-solaris"
SLOT="$(get_version_component_range 1-2)"
# Comment the following five lines when not a beta or rc.
#MY_PV="${PV//_}"
#MY_FILE_PV="${SLOT}$(get_version_component_range 4)"
#S="${WORKDIR}/postgresql-${MY_FILE_PV}"
SRC_URI="mirror://postgresql/source/v${MY_FILE_PV}/postgresql-${MY_FILE_PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}beta3.tbz2"
# Comment the following three lines when a beta or rc.
S="${WORKDIR}/postgresql-${PV}"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-${SLOT}beta3.tbz2"
LICENSE="POSTGRESQL"
DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
# No tests to be done for clients and libraries
RESTRICT="test"
LINGUAS="af cs de en es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
IUSE="doc kerberos ldap nls pam pg_legacytimestamp readline ssl threads zlib"
for lingua in ${LINGUAS} ; do
IUSE+=" linguas_${lingua}"
done
wanted_languages() {
local enable_langs
for lingua in ${LINGUAS} ; do
use linguas_${lingua} && enable_langs+="${lingua} "
done
echo -n ${enable_langs}
}
RDEPEND="!!dev-db/libpq
!!dev-db/postgresql
!!dev-db/postgresql-client
!!dev-db/postgresql-libs
sys-apps/less
>=app-admin/eselect-postgresql-1.0.10
virtual/libintl
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
readline? ( sys-libs/readline )
ssl? ( >=dev-libs/openssl-0.9.6-r1 )
zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
!!<sys-apps/sandbox-2.0
sys-devel/bison
sys-devel/flex
nls? ( sys-devel/gettext )
"
PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
# Support /var/run or /run for the socket directory
[[ ! -d /run ]] && RUNDIR=/var
src_prepare() {
epatch "${WORKDIR}/autoconf.patch" \
"${WORKDIR}/base.patch" \
"${WORKDIR}/bool.patch"
eprefixify src/include/pg_config_manual.h
# to avoid collision - it only should be installed by server
rm "${S}/src/backend/nls.mk"
# because psql/help.c includes the file
ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/" || die
sed -e "s|@RUNDIR@|${RUNDIR}|g" \
-i src/include/pg_config_manual.h || \
die "RUNDIR sed failed"
eautoconf
}
src_configure() {
case ${CHOST} in
*-darwin*|*-solaris*)
use nls && append-libs intl
;;
esac
export LDFLAGS_SL="${LDFLAGS}"
export LDFLAGS_EX="${LDFLAGS}"
local PO="${EPREFIX%/}"
econf \
--prefix="${PO}/usr/$(get_libdir)/postgresql-${SLOT}" \
--datadir="${PO}/usr/share/postgresql-${SLOT}" \
--docdir="${PO}/usr/share/doc/postgresql-${SLOT}" \
--sysconfdir="${PO}/etc/postgresql-${SLOT}" \
--includedir="${PO}/usr/include/postgresql-${SLOT}" \
--mandir="${PO}/usr/share/postgresql-${SLOT}/man" \
--without-tcl \
--without-perl \
--without-python \
$(use_with readline) \
$(use_with kerberos krb5) \
$(use_with kerberos gssapi) \
"$(use_enable nls nls "$(wanted_languages)")" \
$(use_with pam) \
$(use_enable !pg_legacytimestamp integer-datetimes) \
$(use_with ssl openssl) \
$(use_enable threads thread-safety) \
$(use_with zlib) \
$(use_with ldap)
}
src_compile() {
emake
cd "${S}/contrib"
emake
}
src_install() {
emake DESTDIR="${D}" install
insinto /usr/include/postgresql-${SLOT}/postmaster
doins "${S}"/src/include/postmaster/*.h
dodir /usr/share/postgresql-${SLOT}/man/
cp -r "${S}"/doc/src/sgml/man{1,7} "${ED}"/usr/share/postgresql-${SLOT}/man/ || die
rm "${ED}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,pg_{controldata,ctl,resetxlog},post{gres,master}}.1
docompress /usr/share/postgresql-${SLOT}/man/man{1,7}
dodoc README HISTORY doc/{TODO,bug.template}
cd "${S}/contrib"
emake DESTDIR="${D}" install
cd "${S}"
dodir /etc/eselect/postgresql/slots/${SLOT}
echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\"" > \
"${ED}/etc/eselect/postgresql/slots/${SLOT}/base"
keepdir /etc/postgresql-${SLOT}
}
pkg_postinst() {
postgresql-config update
elog "If you need a global psqlrc-file, you can place it in:"
elog " ${EROOT%/}/etc/postgresql-${SLOT}/"
}
pkg_postrm() {
postgresql-config update
}
1.1 dev-db/postgresql-base/postgresql-base-9.0.11.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.0.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.0.11.ebuild?rev=1.1&content-type=text/plain
Index: postgresql-base-9.0.11.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.0.11.ebuild,v 1.1 2012/12/10 06:01:02 patrick Exp $
EAPI="4"
WANT_AUTOMAKE="none"
inherit autotools eutils flag-o-matic multilib prefix versionator
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~ppc-macos ~x86-solaris"
DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-9.0-r3.tbz2"
LICENSE="POSTGRESQL"
S="${WORKDIR}/postgresql-${PV}"
# No tests to be done for clients and libraries
RESTRICT="test"
LINGUAS="af cs de en es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
IUSE="doc kerberos ldap nls pam pg_legacytimestamp readline ssl threads zlib"
for lingua in ${LINGUAS} ; do
IUSE+=" linguas_${lingua}"
done
wanted_languages() {
local enable_langs
for lingua in ${LINGUAS} ; do
use linguas_${lingua} && enable_langs+="${lingua} "
done
echo -n ${enable_langs}
}
RDEPEND=">=app-admin/eselect-postgresql-1.0.7
virtual/libintl
!!dev-db/libpq
!!dev-db/postgresql
!!dev-db/postgresql-client
!!dev-db/postgresql-libs
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
readline? ( sys-libs/readline )
ssl? ( >=dev-libs/openssl-0.9.6-r1 )
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
sys-devel/bison
sys-devel/flex
!!<sys-apps/sandbox-2.0
nls? ( sys-devel/gettext )"
PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
# Support /var/run or /run for the socket directory
[[ ! -d /run ]] && RUNDIR=/var
src_prepare() {
epatch "${WORKDIR}/autoconf.patch" "${WORKDIR}/base.patch" \
"${WORKDIR}/bool.patch"
eprefixify src/include/pg_config_manual.h
# to avoid collision - it only should be installed by server
rm "${S}/src/backend/nls.mk"
# because psql/help.c includes the file
ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/" || die
sed -e "s|@RUNDIR@|${RUNDIR}|g" \
-i src/include/pg_config_manual.h || \
die "RUNDIR sed failed"
eautoconf
}
src_configure() {
case ${CHOST} in
*-darwin*|*-solaris*)
use nls && append-libs intl
;;
esac
export LDFLAGS_SL="${LDFLAGS}"
export LDFLAGS_EX="${LDFLAGS}"
local PO="${EPREFIX%/}"
econf --prefix="${PO}/usr/$(get_libdir)/postgresql-${SLOT}" \
--datadir="${PO}/usr/share/postgresql-${SLOT}" \
--docdir="${PO}/usr/share/doc/postgresql-${SLOT}" \
--includedir="${PO}/usr/include/postgresql-${SLOT}" \
--mandir="${PO}/usr/share/postgresql-${SLOT}/man" \
--sysconfdir="${PO}/etc/postgresql-${SLOT}" \
--without-tcl \
--without-perl \
--without-python \
$(use_with kerberos krb5) \
$(use_with kerberos gssapi) \
$(use_with ldap) \
"$(use_enable nls nls "$(wanted_languages)")" \
$(use_with pam) \
$(use_enable !pg_legacytimestamp integer-datetimes) \
$(use_with readline) \
$(use_with ssl openssl) \
$(use_enable threads thread-safety) \
$(use_with zlib)
}
src_compile() {
emake
cd "${S}/contrib"
emake
}
src_install() {
emake DESTDIR="${D}" install
insinto /usr/include/postgresql-${SLOT}/postmaster
doins "${S}"/src/include/postmaster/*.h
dodir /usr/share/postgresql-${SLOT}/man/
cp -r "${S}"/doc/src/sgml/man{1,7} "${ED}"/usr/share/postgresql-${SLOT}/man/ || die
rm "${ED}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,pg_controldata,pg_ctl,pg_resetxlog,postgres,postmaster}.1
docompress /usr/share/postgresql-${SLOT}/man/man{1,7}
dodoc README HISTORY doc/{README.*,TODO,bug.template}
cd "${S}/contrib"
emake DESTDIR="${D}" install
cd "${S}"
dodir /etc/eselect/postgresql/slots/${SLOT}
echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\"" \
> "${ED}/etc/eselect/postgresql/slots/${SLOT}/base"
keepdir /etc/postgresql-${SLOT}
}
pkg_postinst() {
postgresql-config update
elog "If you need a global psqlrc-file, you can place it in:"
elog " ${EROOT%/}/etc/postgresql-${SLOT}/"
einfo
einfo "If this is your first install of PostgreSQL, you 'll want to:"
einfo " source /etc/profile"
einfo "In your open terminal sessions."
}
pkg_postrm() {
postgresql-config update
}
1.1 dev-db/postgresql-base/postgresql-base-9.1.7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.1.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.1.7.ebuild?rev=1.1&content-type=text/plain
Index: postgresql-base-9.1.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-9.1.7.ebuild,v 1.1 2012/12/10 06:01:02 patrick Exp $
EAPI="4"
WANT_AUTOMAKE="none"
inherit autotools eutils flag-o-matic multilib prefix versionator
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~ppc-macos ~x86-solaris"
SLOT="$(get_version_component_range 1-2)"
S="${WORKDIR}/postgresql-${PV}"
DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-9.1-r1.tbz2"
LICENSE="POSTGRESQL"
# No tests to be done for clients and libraries
RESTRICT="test"
LINGUAS="af cs de en es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
IUSE="doc kerberos ldap nls pam pg_legacytimestamp readline ssl threads zlib"
for lingua in ${LINGUAS} ; do
IUSE+=" linguas_${lingua}"
done
wanted_languages() {
local enable_langs
for lingua in ${LINGUAS} ; do
use linguas_${lingua} && enable_langs+="${lingua} "
done
echo -n ${enable_langs}
}
RDEPEND="!!dev-db/libpq
!!dev-db/postgresql
!!dev-db/postgresql-client
!!dev-db/postgresql-libs
>=app-admin/eselect-postgresql-1.0.10
virtual/libintl
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
readline? ( sys-libs/readline )
ssl? ( >=dev-libs/openssl-0.9.6-r1 )
zlib? ( sys-libs/zlib )
"
DEPEND="${RDEPEND}
!!<sys-apps/sandbox-2.0
sys-devel/bison
sys-devel/flex
nls? ( sys-devel/gettext )
"
PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
# Support /var/run or /run for the socket directory
[[ ! -d /run ]] && RUNDIR=/var
src_prepare() {
epatch "${WORKDIR}/autoconf.patch" \
"${WORKDIR}/base.patch" \
"${WORKDIR}/bool.patch"
eprefixify src/include/pg_config_manual.h
# to avoid collision - it only should be installed by server
rm "${S}/src/backend/nls.mk"
# because psql/help.c includes the file
ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/" || die
sed -e "s|@RUNDIR@|${RUNDIR}|g" \
-i src/include/pg_config_manual.h || \
die "RUNDIR sed failed"
eautoconf
}
src_configure() {
case ${CHOST} in
*-darwin*|*-solaris*)
use nls && append-libs intl
;;
esac
export LDFLAGS_SL="${LDFLAGS}"
export LDFLAGS_EX="${LDFLAGS}"
local PO="${EPREFIX%/}"
econf \
--prefix="${PO}/usr/$(get_libdir)/postgresql-${SLOT}" \
--datadir="${PO}/usr/share/postgresql-${SLOT}" \
--docdir="${PO}/usr/share/doc/postgresql-${SLOT}" \
--sysconfdir="${PO}/etc/postgresql-${SLOT}" \
--includedir="${PO}/usr/include/postgresql-${SLOT}" \
--mandir="${PO}/usr/share/postgresql-${SLOT}/man" \
--without-tcl \
--without-perl \
--without-python \
$(use_with readline) \
$(use_with kerberos krb5) \
$(use_with kerberos gssapi) \
"$(use_enable nls nls "$(wanted_languages)")" \
$(use_with pam) \
$(use_enable !pg_legacytimestamp integer-datetimes) \
$(use_with ssl openssl) \
$(use_enable threads thread-safety) \
$(use_with zlib) \
$(use_with ldap)
}
src_compile() {
emake -j1
cd "${S}/contrib"
emake
}
src_install() {
emake DESTDIR="${D}" install
insinto /usr/include/postgresql-${SLOT}/postmaster
doins "${S}"/src/include/postmaster/*.h
dodir /usr/share/postgresql-${SLOT}/man/
cp -r "${S}"/doc/src/sgml/man{1,7} "${ED}"/usr/share/postgresql-${SLOT}/man/ || die
rm "${ED}/usr/share/postgresql-${SLOT}/man/man1"/{initdb,pg_{controldata,ctl,resetxlog},post{gres,master}}.1
docompress /usr/share/postgresql-${SLOT}/man/man{1,7}
dodoc README HISTORY doc/{TODO,bug.template}
cd "${S}/contrib"
emake DESTDIR="${D}" install
cd "${S}"
dodir /etc/eselect/postgresql/slots/${SLOT}
echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\"" > \
"${ED}/etc/eselect/postgresql/slots/${SLOT}/base"
keepdir /etc/postgresql-${SLOT}
}
pkg_postinst() {
postgresql-config update
elog "If you need a global psqlrc-file, you can place it in:"
elog " ${EROOT%/}/etc/postgresql-${SLOT}/"
einfo
einfo "If this is your first install of PostgreSQL, you 'll want to:"
einfo " source /etc/profile"
einfo "In your open terminal sessions."
}
pkg_postrm() {
postgresql-config update
}
1.1 dev-db/postgresql-base/postgresql-base-8.4.15.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.4.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.4.15.ebuild?rev=1.1&content-type=text/plain
Index: postgresql-base-8.4.15.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.4.15.ebuild,v 1.1 2012/12/10 06:01:02 patrick Exp $
EAPI="4"
WANT_AUTOMAKE="none"
inherit autotools eutils multilib prefix versionator
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-8.4-r2.tbz2"
LICENSE="POSTGRESQL"
S="${WORKDIR}/postgresql-${PV}"
# No tests to be done for clients and libraries
RESTRICT="test"
LINGUAS="af cs de en es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
IUSE="doc kerberos ldap nls pam pg_legacytimestamp readline ssl threads zlib"
for lingua in ${LINGUAS} ; do
IUSE+=" linguas_${lingua}"
done
wanted_languages() {
local enable_langs
for lingua in ${LINGUAS} ; do
use linguas_${lingua} && enable_langs+="${lingua} "
done
echo -n ${enable_langs}
}
RDEPEND=">=app-admin/eselect-postgresql-1.0.7
virtual/libintl
!!dev-db/libpq
!!dev-db/postgresql
!!dev-db/postgresql-client
!!dev-db/postgresql-libs
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
readline? ( >=sys-libs/readline-4.1 )
ssl? ( >=dev-libs/openssl-0.9.6-r1 )
zlib? ( >=sys-libs/zlib-1.1.3 )"
DEPEND="${RDEPEND}
!!<sys-apps/sandbox-2.0
>=sys-devel/bison-1.875
sys-devel/flex
nls? ( sys-devel/gettext )"
PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
# Support /var/run or /run for the socket directory
[[ ! -d /run ]] && RUNDIR=/var
src_prepare() {
epatch "${WORKDIR}/autoconf.patch" "${WORKDIR}/base.patch" \
"${WORKDIR}/bool.patch" "${WORKDIR}/darwin.patch" \
"${WORKDIR}/SuperH.patch"
eprefixify src/include/pg_config_manual.h
# to avoid collision - it only should be installed by server
rm "${S}/src/backend/nls.mk"
# because psql/help.c includes the file
ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/" || die
sed -e "s|@RUNDIR@|${RUNDIR}|g" \
-i src/include/pg_config_manual.h || \
die "RUNDIR sed failed"
eautoconf
}
src_configure() {
export LDFLAGS_SL="${LDFLAGS}"
local PO="${EPREFIX%/}"
econf --prefix="${PO}/usr/$(get_libdir)/postgresql-${SLOT}" \
--datadir="${PO}/usr/share/postgresql-${SLOT}" \
--docdir="${PO}/usr/share/doc/postgresql-${SLOT}" \
--includedir="${PO}/usr/include/postgresql-${SLOT}" \
--mandir="${PO}/usr/share/postgresql-${SLOT}/man" \
--sysconfdir="${PO}/etc/postgresql-${SLOT}" \
--without-tcl \
--without-perl \
--without-python \
$(use_with kerberos krb5) \
$(use_with kerberos gssapi) \
$(use_with ldap) \
"$(use_enable nls nls "$(wanted_languages)")" \
$(use_with pam) \
$(use_enable !pg_legacytimestamp integer-datetimes ) \
$(use_with readline) \
$(use_with ssl openssl) \
$(use_enable threads thread-safety) \
$(use_with zlib)
}
src_compile() {
emake
cd "${S}/contrib"
emake
}
src_install() {
emake DESTDIR="${D}" install
insinto /usr/include/postgresql-${SLOT}/postmaster
doins "${S}"/src/include/postmaster/*.h
rm -r "${ED}/usr/share/doc/postgresql-${SLOT}/html"
rm "${ED}"/usr/share/postgresql-${SLOT}/man/man1/{initdb,pg_{controldata,ctl,resetxlog},post{gres,master}}.1
docompress /usr/share/postgresql-${SLOT}/man/man{1,7}
dodoc README HISTORY doc/{README.*,TODO,bug.template}
cd "${S}/contrib"
emake DESTDIR="${D}" install
cd "${S}"
dodir /etc/eselect/postgresql/slots/${SLOT}
echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\"" \
> "${ED}/etc/eselect/postgresql/slots/${SLOT}/base"
keepdir /etc/postgresql-${SLOT}
}
pkg_postinst() {
postgresql-config update
elog "If you need a global psqlrc-file, you can place it in:"
elog " ${EROOT%/}/etc/postgresql-${SLOT}/"
einfo
einfo "If this is your first install of PostgreSQL, you 'll want to:"
einfo " source /etc/profile"
einfo "In your open terminal sessions."
}
pkg_postrm() {
postgresql-config update
}
1.1 dev-db/postgresql-base/postgresql-base-8.3.22.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.3.22.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.3.22.ebuild?rev=1.1&content-type=text/plain
Index: postgresql-base-8.3.22.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/postgresql-base/postgresql-base-8.3.22.ebuild,v 1.1 2012/12/10 06:01:02 patrick Exp $
EAPI="4"
WANT_AUTOMAKE="none"
inherit autotools eutils multilib prefix versionator
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
DESCRIPTION="PostgreSQL libraries and clients"
HOMEPAGE="http://www.postgresql.org/"
SRC_URI="mirror://postgresql/source/v${PV}/postgresql-${PV}.tar.bz2
http://dev.gentoo.org/~titanofold/postgresql-patches-8.3-r2.tbz2"
LICENSE="POSTGRESQL"
S="${WORKDIR}/postgresql-${PV}"
# No tests to be done for clients and libraries
RESTRICT="test"
LINGUAS="af cs de en es fa fr hr hu it ko nb pl pt_BR ro ru sk sl sv tr zh_CN zh_TW"
IUSE="doc kerberos ldap nls pam pg-intdatetime readline ssl threads zlib"
for lingua in ${LINGUAS} ; do
IUSE+=" linguas_${lingua}"
done
wanted_languages() {
local enable_langs
for lingua in ${LINGUAS} ; do
use linguas_${lingua} && enable_langs+="${lingua} "
done
echo -n ${enable_langs}
}
RDEPEND=">=app-admin/eselect-postgresql-1.0.10
virtual/libintl
!!dev-db/libpq
!!dev-db/postgresql
!!dev-db/postgresql-client
!!dev-db/postgresql-libs
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
readline? ( >=sys-libs/readline-4.1 )
ssl? ( >=dev-libs/openssl-0.9.6-r1 )
zlib? ( >=sys-libs/zlib-1.1.3 )"
DEPEND="${RDEPEND}
!!<sys-apps/sandbox-2.0
>=sys-devel/bison-1.875
sys-devel/flex
nls? ( sys-devel/gettext )"
PDEPEND="doc? ( ~dev-db/postgresql-docs-${PV} )"
# Support /var/run or /run for the socket directory
[[ ! -d /run ]] && RUNDIR=/var
src_prepare() {
epatch "${WORKDIR}/autoconf.patch" "${WORKDIR}/base.patch" \
"${WORKDIR}/bool.patch" "${WORKDIR}/darwin.patch" \
"${WORKDIR}/relax_ssl_perms.patch" "${WORKDIR}/SuperH.patch"
eprefixify src/include/pg_config_manual.h
# to avoid collision - it only should be installed by server
rm "${S}/src/backend/nls.mk"
# because psql/help.c includes the file
ln -s "${S}/src/include/libpq/pqsignal.h" "${S}/src/bin/psql/" || die
sed -e "s|@RUNDIR@|${RUNDIR}|g" \
-i src/include/pg_config_manual.h || \
die "RUNDIR sed failed"
eautoconf
}
src_configure() {
export LDFLAGS_SL="${LDFLAGS}"
local PO="${EPREFIX%/}"
econf --prefix="${PO}/usr/$(get_libdir)/postgresql-${SLOT}" \
--datadir="${PO}/usr/share/postgresql-${SLOT}" \
--includedir="${PO}/usr/include/postgresql-${SLOT}" \
--mandir="${PO}/usr/share/postgresql-${SLOT}/man" \
--sysconfdir="${PO}/etc/postgresql-${SLOT}" \
--without-docdir \
--without-perl \
--without-python \
--without-tcl \
$(use_with kerberos krb5) \
$(use_with kerberos gssapi) \
$(use_with ldap) \
"$(use_enable nls nls "$(wanted_languages)")" \
$(use_with pam) \
$(use_enable pg-intdatetime integer-datetimes ) \
$(use_with readline) \
$(use_with ssl openssl) \
$(use_enable threads thread-safety) \
$(use_with zlib)
}
src_compile() {
emake
cd "${S}/contrib"
emake
}
src_install() {
emake DESTDIR="${D}" install
insinto /usr/include/postgresql-${SLOT}/postmaster
doins "${S}"/src/include/postmaster/*.h
dodir /usr/share/postgresql-${SLOT}/man/man1
rm "${ED}"/usr/share/postgresql-${SLOT}/man/man1/{initdb,ipcclean,pg_{controldata,ctl,resetxlog},post{gres,master}}.1
docompress /usr/share/postgresql-${SLOT}/man/man{1,7}
dodoc README HISTORY doc/{README.*,TODO,bug.template}
cd "${S}/contrib"
emake DESTDIR="${D}" install
cd "${S}"
dodir /etc/eselect/postgresql/slots/${SLOT}
echo "postgres_ebuilds=\"\${postgres_ebuilds} ${PF}\"" \
> "${ED}/etc/eselect/postgresql/slots/${SLOT}/base"
keepdir /etc/postgresql-${SLOT}
}
pkg_postinst() {
postgresql-config update
elog "If you need a global psqlrc-file, you can place it in:"
elog " ${EROOT%/}/etc/postgresql-${SLOT}/"
einfo
einfo "If this is your first install of PostgreSQL, you 'll want to:"
einfo " source /etc/profile"
einfo "In your open terminal sessions."
}
pkg_postrm() {
postgresql-config update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-12-10 6:01 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-12-10 6:01 [gentoo-commits] gentoo-x86 commit in dev-db/postgresql-base: postgresql-base-9.2.2.ebuild postgresql-base-9.0.11.ebuild postgresql-base-9.1.7.ebuild postgresql-base-8.4.15.ebuild postgresql-base-8.3.22.ebuild ChangeLog Patrick Lauer (patrick)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox