* [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.7.2.ebuild ChangeLog
@ 2012-11-20 12:06 Eray Aslan (eras)
0 siblings, 0 replies; 2+ messages in thread
From: Eray Aslan (eras) @ 2012-11-20 12:06 UTC (permalink / raw
To: gentoo-commits
eras 12/11/20 12:06:16
Modified: opendkim-2.7.2.ebuild ChangeLog
Log:
Fix building on upgrade - bug #443920
(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 0x77F1F175586A3B1F)
Revision Changes Path
1.2 mail-filter/opendkim/opendkim-2.7.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild?r1=1.1&r2=1.2
Index: opendkim-2.7.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- opendkim-2.7.2.ebuild 17 Nov 2012 13:45:36 -0000 1.1
+++ opendkim-2.7.2.ebuild 20 Nov 2012 12:06:16 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild,v 1.1 2012/11/17 13:45:36 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild,v 1.2 2012/11/20 12:06:16 eras Exp $
EAPI=4
inherit eutils db-use autotools user
@@ -59,6 +59,7 @@
sed -i -e '/^sock/s/t-sign-ss-macro-value-file.sock/t-s-s-m-v-f.sock/' \
opendkim/tests/t-sign-ss-macro-value-file.lua || die
+ epatch "${FILESDIR}/${P}-strl.patch"
eautoreconf
}
1.52 mail-filter/opendkim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.51&r2=1.52
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog 17 Nov 2012 13:45:36 -0000 1.51
+++ ChangeLog 20 Nov 2012 12:06:16 -0000 1.52
@@ -1,6 +1,10 @@
# ChangeLog for mail-filter/opendkim
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.51 2012/11/17 13:45:36 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.52 2012/11/20 12:06:16 eras Exp $
+
+ 20 Nov 2012; Eray Aslan <eras@gentoo.org> +files/opendkim-2.7.2-strl.patch,
+ opendkim-2.7.2.ebuild:
+ Fix building on upgrade - bug #443920
*opendkim-2.7.2 (17 Nov 2012)
^ permalink raw reply [flat|nested] 2+ messages in thread* [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.7.2.ebuild ChangeLog
@ 2012-11-17 13:45 Eray Aslan (eras)
0 siblings, 0 replies; 2+ messages in thread
From: Eray Aslan (eras) @ 2012-11-17 13:45 UTC (permalink / raw
To: gentoo-commits
eras 12/11/17 13:45:36
Modified: ChangeLog
Added: opendkim-2.7.2.ebuild
Log:
Version bump
(Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 0x77F1F175586A3B1F)
Revision Changes Path
1.51 mail-filter/opendkim/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.51&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?rev=1.51&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/ChangeLog?r1=1.50&r2=1.51
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v
retrieving revision 1.50
retrieving revision 1.51
diff -u -r1.50 -r1.51
--- ChangeLog 30 Oct 2012 20:37:50 -0000 1.50
+++ ChangeLog 17 Nov 2012 13:45:36 -0000 1.51
@@ -1,6 +1,11 @@
# ChangeLog for mail-filter/opendkim
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.50 2012/10/30 20:37:50 eras Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/ChangeLog,v 1.51 2012/11/17 13:45:36 eras Exp $
+
+*opendkim-2.7.2 (17 Nov 2012)
+
+ 17 Nov 2012; Eray Aslan <eras@gentoo.org> +opendkim-2.7.2.ebuild:
+ Version bump
*opendkim-2.7.1 (30 Oct 2012)
1.1 mail-filter/opendkim/opendkim-2.7.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild?rev=1.1&content-type=text/plain
Index: opendkim-2.7.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/opendkim/opendkim-2.7.2.ebuild,v 1.1 2012/11/17 13:45:36 eras Exp $
EAPI=4
inherit eutils db-use autotools user
# for betas
#MY_P=${P/_b/.B}
#S=${WORKDIR}/${PN}-2.0.0
#SRC_URI="mirror://sourceforge/opendkim/${MY_P}.tar.gz"
DESCRIPTION="A milter-based application to provide DKIM signing and verification"
HOMEPAGE="http://opendkim.org"
SRC_URI="mirror://sourceforge/opendkim/${P}.tar.gz"
LICENSE="Sendmail-Open-Source BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+berkdb gnutls ldap lua opendbx poll sasl +ssl static-libs unbound"
DEPEND="|| ( mail-filter/libmilter mail-mta/sendmail )
ssl? ( >=dev-libs/openssl-0.9.8 )
berkdb? ( >=sys-libs/db-3.2 )
opendbx? ( >=dev-db/opendbx-1.4.0 )
lua? ( dev-lang/lua )
ldap? ( net-nds/openldap )
sasl? ( dev-libs/cyrus-sasl )
unbound? ( >=net-dns/unbound-1.4.1 net-dns/dnssec-root )
!unbound? ( net-libs/ldns )
gnutls? ( >=net-libs/gnutls-2.11.7 )"
RDEPEND="${DEPEND}
sys-process/psmisc"
REQUIRED_USE="sasl? ( ldap )"
pkg_setup() {
enewgroup milter
# mail-milter/spamass-milter creates milter user with this home directory
# For consistency reasons, milter user must be created here with this home directory
# even though this package doesn't need a home directory for this user (#280571)
enewuser milter -1 -1 /var/lib/milter milter
}
src_prepare() {
sed -i -e 's:/var/db/dkim:/etc/opendkim:g' \
-e 's:/var/db/opendkim:/var/lib/opendkim:g' \
-e 's:/etc/mail:/etc/opendkim:g' \
-e 's:mailnull:milter:g' \
-e 's:^#[[:space:]]*PidFile.*:PidFile /var/run/opendkim/opendkim.pid:' \
opendkim/opendkim.conf.sample opendkim/opendkim.conf.simple.in \
stats/opendkim-reportstats || die
sed -i -e 's:dist_doc_DATA:dist_html_DATA:' libopendkim/docs/Makefile.am \
|| die
# don't go over the sock length and fail
sed -i -e '/^sock/s/t-sign-ss-macro-value-file.sock/t-s-s-m-v-f.sock/' \
opendkim/tests/t-sign-ss-macro-value-file.lua || die
eautoreconf
}
src_configure() {
local myconf
if use berkdb ; then
myconf=$(db_includedir)
myconf="--with-db-incdir=${myconf#-I}"
myconf+=" --enable-popauth"
myconf+=" --enable-query_cache"
myconf+=" --enable-stats"
fi
if use unbound; then
myconf+=" --with-unbound"
else
myconf+=" --with-ldns"
fi
if use ldap; then
myconf+=" $(use_with sasl)"
fi
econf \
$(use_with berkdb db) \
$(use_with opendbx odbx) \
$(use_with lua) \
$(use_enable lua rbl) \
$(use_with ldap openldap) \
$(use_enable poll) \
$(use_enable static-libs static) \
$(use_with gnutls) \
${myconf} \
--docdir=/usr/share/doc/${PF} \
--htmldir=/usr/share/doc/${PF}/html \
--enable-filter \
--enable-adsp_lists \
--enable-dkim_reputation \
--enable-identity_header \
--enable-rate_limit \
--enable-redirect \
--enable-resign \
--enable-replace_rules \
--enable-default_sender \
--enable-sender_macro \
--enable-vbr \
--disable-rpath \
--disable-live-testing
}
src_install() {
emake DESTDIR="${D}" install
dosbin stats/opendkim-reportstats
newinitd "${FILESDIR}/opendkim.init.r2" opendkim
dodir /etc/opendkim /var/lib/opendkim
fowners milter:milter /var/lib/opendkim
# default configuration
if [ ! -f "${ROOT}"/etc/opendkim/opendkim.conf ]; then
grep ^[^#] "${S}"/opendkim/opendkim.conf.simple \
> "${D}"/etc/opendkim/opendkim.conf
if use unbound; then
echo TrustedAnchorFile /etc/dnssec/root-anchors.txt >> "${D}"/etc/opendkim/opendkim.conf
fi
echo UserID milter >> "${D}"/etc/opendkim/opendkim.conf
if use berkdb; then
echo Statistics /var/lib/opendkim/stats.dat >> \
"${D}"/etc/opendkim/opendkim.conf
fi
fi
use static-libs || find "${D}" -name "*.la" -delete
}
pkg_postinst() {
elog "If you want to sign your mail messages and need some help"
elog "please run:"
elog " emerge --config ${CATEGORY}/${PN}"
elog "It will help you create your key and give you hints on how"
elog "to configure your DNS and MTA."
ewarn "Make sure your MTA has r/w access to the socket file."
ewarn "This can be done either by setting UMask to 002 and adding MTA's user"
ewarn "to milter group or you can simply set UMask to 000."
}
pkg_config() {
local selector keysize pubkey
read -p "Enter the selector name (default ${HOSTNAME}): " selector
[[ -n "${selector}" ]] || selector=${HOSTNAME}
if [[ -z "${selector}" ]]; then
eerror "Oddly enough, you don't have a HOSTNAME."
return 1
fi
if [[ -f "${ROOT}"etc/opendkim/${selector}.private ]]; then
ewarn "The private key for this selector already exists."
else
keysize=1024
# generate the private and public keys
opendkim-genkey -b ${keysize} -D "${ROOT}"etc/opendkim/ \
-s ${selector} -d '(your domain)' && \
chown milter:milter \
"${ROOT}"etc/opendkim/"${selector}".private || \
{ eerror "Failed to create private and public keys." ; return 1; }
chmod go-r "${ROOT}"etc/opendkim/"${selector}".private
fi
# opendkim selector configuration
echo
einfo "Make sure you have the following settings in your /etc/opendkim/opendkim.conf:"
einfo " Keyfile /etc/opendkim/${selector}.private"
einfo " Selector ${selector}"
# MTA configuration
echo
einfo "If you are using Postfix, add following lines to your main.cf:"
einfo " smtpd_milters = unix:/var/run/opendkim/opendkim.sock"
einfo " non_smtpd_milters = unix:/var/run/opendkim/opendkim.sock"
einfo " and read http://www.postfix.org/MILTER_README.html"
# DNS configuration
einfo "After you configured your MTA, publish your key by adding this TXT record to your domain:"
cat "${ROOT}"etc/opendkim/${selector}.txt
einfo "t=y signifies you only test the DKIM on your domain. See following page for the complete list of tags:"
einfo " http://www.dkim.org/specs/rfc4871-dkimbase.html#key-text"
einfo
einfo "Also look at the ADSP http://tools.ietf.org/html/rfc5617"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-11-20 12:06 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-11-20 12:06 [gentoo-commits] gentoo-x86 commit in mail-filter/opendkim: opendkim-2.7.2.ebuild ChangeLog Eray Aslan (eras)
-- strict thread matches above, loose matches on Subject: below --
2012-11-17 13:45 Eray Aslan (eras)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox