[gentoo-commits] gentoo-x86 commit in net-voip/linphone: metadata.xml linphone-3.5.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-voip/linphone: metadata.xml linphone-3.5.2.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      12/11/19 21:33:29

  Modified:             metadata.xml ChangeLog
  Added:                linphone-3.5.2.ebuild
  Log:
  Version bump wrt bug #397645. Thanks to Andrew Savchenko for his effort on linphone ebuilds.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

Revision  Changes    Path
1.11                 net-voip/linphone/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/metadata.xml?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/metadata.xml?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/metadata.xml?r1=1.10&r2=1.11

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/linphone/metadata.xml,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- metadata.xml	25 Mar 2012 10:23:25 -0000	1.10
+++ metadata.xml	19 Nov 2012 21:33:29 -0000	1.11
@@ -8,6 +8,7 @@
 		<description>Assign to herd and CC me</description>
 	</maintainer>
 	<use>
+		<flag name='gsm-nonstandard'>Support non-standard GSM frequencies</flag>
 		<flag name='video'>Enable video support (display/capture)</flag>
 	</use>
 </pkgmetadata>



1.68                 net-voip/linphone/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	3 May 2012 07:27:47 -0000	1.67
+++ ChangeLog	19 Nov 2012 21:33:29 -0000	1.68
@@ -1,6 +1,13 @@
 # ChangeLog for net-voip/linphone
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.67 2012/05/03 07:27:47 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/ChangeLog,v 1.68 2012/11/19 21:33:29 mgorny Exp $
+
+*linphone-3.5.2 (19 Nov 2012)
+
+  19 Nov 2012; Michał Górny <mgorny@gentoo.org> +files/linphone-3.5.2-nls.patch,
+  +linphone-3.5.2.ebuild, metadata.xml:
+  Version bump wrt bug #397645. Thanks to Andrew Savchenko for his effort on
+  linphone ebuilds.
 
   03 May 2012; Jeff Horelick <jdhore@gentoo.org> linphone-3.1.1.ebuild,
   linphone-3.2.1-r2.ebuild, linphone-3.3.2.ebuild, linphone-3.4.3.ebuild,



1.1                  net-voip/linphone/linphone-3.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/linphone-3.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-voip/linphone/linphone-3.5.2.ebuild?rev=1.1&content-type=text/plain

Index: linphone-3.5.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-voip/linphone/linphone-3.5.2.ebuild,v 1.1 2012/11/19 21:33:29 mgorny Exp $

EAPI="4"

inherit autotools eutils multilib pax-utils versionator

DESCRIPTION="Video softphone based on the SIP protocol"
HOMEPAGE="http://www.linphone.org/"
SRC_URI="mirror://nongnu/${PN}/$(get_version_component_range 1-2).x/sources/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# TODO: run-time test for ipv6: does it need mediastreamer[ipv6]?
IUSE="doc gsm-nonstandard gtk ipv6 ncurses nls ssl video"

RDEPEND=">=media-libs/mediastreamer-2.8.2[video?,ipv6?]
	>=net-libs/libeXosip-3.0.2
	>=net-libs/libosip-3.0.0
	>=net-libs/libsoup-2.26
	>=net-libs/ortp-0.20.0
	gtk? ( dev-libs/glib:2
		>=gnome-base/libglade-2.4.0:2.0
		>=x11-libs/gtk+-2.4.0:2
		x11-libs/libnotify )
	gsm-nonstandard? ( >=media-libs/mediastreamer-2.8.2[gsm] )
	ncurses? ( sys-libs/readline
		sys-libs/ncurses )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-text/sgmltools-lite )
	nls? ( dev-util/intltool
		sys-devel/gettext )"

IUSE_LINGUAS=" fr it de ja es pl cs nl sv pt_BR hu ru zh_CN"
IUSE="${IUSE}${IUSE_LINGUAS// / linguas_}"

pkg_setup() {
	if ! use gtk && ! use ncurses ; then
		ewarn "gtk and ncurses are disabled."
		ewarn "At least one of these use flags are needed to get a front-end."
		ewarn "Only liblinphone is going to be installed."
	fi

	strip-linguas ${IUSE_LINGUAS}
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-nls.patch
	# remove speex check, avoid bug when mediastreamer[-speex]
	sed -i -e '/SPEEX/d' configure.ac || die "patching configure.ac failed"

	# fix path to use lib64
	sed -i -e "s:lib\(/liblinphone\):$(get_libdir)\1:" configure.ac \
		|| die "patching configure.ac failed"

	# removing bundled libs dir prevent them to be reconf
	rm -rf mediastreamer2 oRTP || die "should not die"
	sed -i -e "s:oRTP::;s:mediastreamer2::" Makefile.am \
		|| die "patching Makefile.am failed"

	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--disable-static
		# we don't want -Werror
		--disable-strict
		# don't bundle libs
		--enable-external-ortp
		--enable-external-mediastreamer
		# seems not used, TODO: ask in ml
		--disable-truespeech
		--disable-zrtp
		$(use_enable doc manual)
		$(use_enable gsm-nonstandard nonstandard-gsm)
		$(use_enable gtk gtk_ui)
		$(use_enable ipv6)
		$(use_enable ncurses console_ui)
		$(use_enable nls)
		$(use_enable video)
	)

	econf "${myeconfargs[@]}"
}

src_install() {
	emake DESTDIR="${D}" pkgdocdir="/usr/share/doc/${PF}" install # 415161
	dodoc AUTHORS BUGS ChangeLog NEWS README README.arm TODO
	pax-mark m "${ED}usr/bin/linphone"
}