[gentoo-commits] gentoo-x86 commit in media-libs/glfw: ChangeLog glfw-2.7.7.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/glfw: ChangeLog glfw-2.7.7.ebuild

[Julian Ospald (hasufell)]

hasufell    12/11/19 20:48:38

  Modified:             ChangeLog
  Added:                glfw-2.7.7.ebuild
  Log:
  version bump wrt #405555
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.15                 media-libs/glfw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glfw/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glfw/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glfw/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/glfw/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	14 Nov 2012 23:31:43 -0000	1.14
+++ ChangeLog	19 Nov 2012 20:48:37 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/glfw
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/glfw/ChangeLog,v 1.14 2012/11/14 23:31:43 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/glfw/ChangeLog,v 1.15 2012/11/19 20:48:37 hasufell Exp $
+
+*glfw-2.7.7 (19 Nov 2012)
+
+  19 Nov 2012; Julian Ospald <hasufell@gentoo.org> +glfw-2.7.7.ebuild,
+  +files/glfw-2.7.7-dyn.patch, +files/glfw-2.7.7-pkgconfig.patch:
+  version bump wrt #405555
 
   14 Nov 2012; Julian Ospald <hasufell@gentoo.org> glfw-2.6.ebuild:
   respect CFLAGS, CC, AR and whatnot wrt #442740



1.1                  media-libs/glfw/glfw-2.7.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glfw/glfw-2.7.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/glfw/glfw-2.7.7.ebuild?rev=1.1&content-type=text/plain

Index: glfw-2.7.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/glfw/glfw-2.7.7.ebuild,v 1.1 2012/11/19 20:48:37 hasufell Exp $

EAPI=5
inherit eutils multilib toolchain-funcs

DESCRIPTION="The Portable OpenGL FrameWork"
HOMEPAGE="http://glfw.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples"

DEPEND="x11-libs/libX11
	x11-libs/libXrandr
	virtual/glu
	virtual/opengl"
RDEPEND="${DEPEND}"

src_prepare() {
	sed -i \
		-e "s:\"docs/:\"/usr/share/doc/${PF}/pdf/:" \
		readme.html \
		|| die "sed failed"

	epatch "${FILESDIR}"/${P}-{dyn,pkgconfig}.patch

	# respect ldflags
	sed -i \
		-e "s/\$(LFLAGS)/\$(LDFLAGS) \$(LFLAGS)/" \
		{lib/x11,examples}/Makefile.x11.in || die "sed Makefile.x11.in failed"

	# respect cflags in linking command
	# build system is messing up CFLAGS variable, so sed is the easy way to go
	sed -i \
		-e "/^libglfw.so/{n;s/\$(CC)/\$(CC) ${CFLAGS}/;}" \
		lib/x11/Makefile.x11.in \
		|| die "sed Makefile.x11.in failed"
}

src_configure() {
	sh ./compile.sh
}

src_compile() {
	emake -C lib/x11 AR=$(tc-getAR) CC=$(tc-getCC) PREFIX=/usr LIBDIR=$(get_libdir) -f Makefile.x11 all libglfw.pc
	use examples && emake -C examples CC=$(tc-getCC) -f Makefile.x11 all
}

src_install() {
	dolib.a lib/x11/libglfw.a
	dolib.so lib/x11/libglfw.so.2.7.7
	dosym libglfw.so.2.7.7 /usr/$(get_libdir)/libglfw.so

	insinto /usr/$(get_libdir)/pkgconfig
	doins lib/x11/libglfw.pc
	doheader -r include/GL
	dohtml -r readme.html
	insinto /usr/share/doc/${PF}/pdf
	doins docs/*.pdf
	dodoc docs/readme.txt

	if use examples; then
		local f
		local MY_EXAMPLES="boing gears listmodes mipmaps
			mtbench mthello particles pong3d splitview
			triangle wave"
		local MY_PICS="mipmaps.tga pong3d_field.tga pong3d_instr.tga
			pong3d_menu.tga pong3d_title.tga
			pong3d_winner1.tga pong3d_winner2.tga"

		docompress -x /usr/share/doc/${PF}/examples
		insinto /usr/share/doc/${PF}/examples

		doins examples/Makefile.x11
		for f in $MY_EXAMPLES; do
			doins examples/${f}.c
		done
		for f in $MY_PICS; do
			doins examples/${f}
		done

		insopts -m0755
		for f in $MY_EXAMPLES; do
			doins examples/${f}
		done
	fi
}