[gentoo-commits] gentoo-x86 commit in net-irc/weechat: weechat-0.3.9.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-irc/weechat: weechat-0.3.9.1.ebuild ChangeLog

[Daniel Kuehn (lejonet)]

lejonet     12/11/10 15:34:02

  Modified:             ChangeLog
  Added:                weechat-0.3.9.1.ebuild
  Log:
  Bumped the version
  
  (Portage version: 2.2.0_alpha110_p51/cvs/Linux x86_64)

Revision  Changes    Path
1.118                net-irc/weechat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?rev=1.118&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?rev=1.118&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/ChangeLog?r1=1.117&r2=1.118

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v
retrieving revision 1.117
retrieving revision 1.118
diff -u -r1.117 -r1.118
--- ChangeLog	5 Oct 2012 19:41:29 -0000	1.117
+++ ChangeLog	10 Nov 2012 15:34:02 -0000	1.118
@@ -1,6 +1,11 @@
 # ChangeLog for net-irc/weechat
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v 1.117 2012/10/05 19:41:29 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/ChangeLog,v 1.118 2012/11/10 15:34:02 lejonet Exp $
+
+*weechat-0.3.9.1 (10 Nov 2012)
+
+  10 Nov 2012;  <lejonet@gentoo.org> +weechat-0.3.9.1.ebuild:
+  Bumped the version
 
   05 Oct 2012; Tomáš Chvátal <scarabeus@gentoo.org> weechat-0.3.9.ebuild,
   weechat-9999.ebuild:



1.1                  net-irc/weechat/weechat-0.3.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/weechat-0.3.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/weechat/weechat-0.3.9.1.ebuild?rev=1.1&content-type=text/plain

Index: weechat-0.3.9.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/weechat/weechat-0.3.9.1.ebuild,v 1.1 2012/11/10 15:34:02 lejonet Exp $

EAPI=4

PYTHON_DEPEND="python? 2" # it can use only ONE python, so stick with two for now

EGIT_REPO_URI="git://git.sv.gnu.org/weechat.git"
[[ ${PV} == "9999" ]] && GIT_ECLASS="git-2"
inherit python multilib cmake-utils ${GIT_ECLASS}

DESCRIPTION="Portable and multi-interface IRC client."
HOMEPAGE="http://weechat.org/"
[[ ${PV} == "9999" ]] || SRC_URI="http://${PN}.org/files/src/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
if [[ ${PV} == "9999" ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-linux ~amd64-linux"
fi

NETWORKS="+irc"
PLUGINS="+alias +charset +fifo +logger +relay +rmodifier +scripts +spell +xfer"
#INTERFACES="+ncurses gtk"
SCRIPT_LANGS="guile lua +perl +python ruby tcl"
IUSE="${SCRIPT_LANGS} ${PLUGINS} ${INTERFACES} ${NETWORKS} +crypt doc nls +ssl"

RDEPEND="
	net-misc/curl[ssl]
	sys-libs/ncurses
	charset? ( virtual/libiconv )
	guile? ( dev-scheme/guile )
	lua? ( dev-lang/lua[deprecated] )
	perl? ( dev-lang/perl )
	ruby? ( >=dev-lang/ruby-1.9 )
	ssl? ( net-libs/gnutls )
	spell? ( app-text/aspell )
	tcl? ( >=dev-lang/tcl-8.4.15 )
"
#	ncurses? ( sys-libs/ncurses )
#	gtk? ( x11-libs/gtk+:2 )
DEPEND="${RDEPEND}
	nls? ( >=sys-devel/gettext-0.15 )
"

DOCS="AUTHORS ChangeLog NEWS README"

#REQUIRED_USE=" || ( ncurses gtk )"

LANGS=( cs de es fr hu it ja pl pt_BR ru )
for X in "${LANGS[@]}" ; do
	IUSE="${IUSE} linguas_${X}"
done

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	local i

	# fix libdir placement
	sed -i \
		-e "s:lib/:$(get_libdir)/:g" \
		-e "s:lib\":$(get_libdir)\":g" \
		CMakeLists.txt || die "sed failed"

	# install only required translations
	for i in "${LANGS[@]}" ; do
		if ! use linguas_${i} ; then
			sed -i \
				-e "/${i}.po/d" \
				po/CMakeLists.txt || die
		fi
	done
}

# alias, rmodifier, xfer
src_configure() {
	# $(cmake-utils_use_enable gtk)
	# $(cmake-utils_use_enable ncurses)
	local mycmakeargs=(
		"-DENABLE_NCURSES=ON"
		"-DENABLE_LARGEFILE=ON"
		"-DENABLE_DEMO=OFF"
		"-DENABLE_GTK=OFF"
		$(cmake-utils_use_enable nls)
		$(cmake-utils_use_enable crypt GCRYPT)
		$(cmake-utils_use_enable spell ASPELL)
		$(cmake-utils_use_enable charset)
		$(cmake-utils_use_enable fifo)
		$(cmake-utils_use_enable irc)
		$(cmake-utils_use_enable logger)
		$(cmake-utils_use_enable relay)
		$(cmake-utils_use_enable scripts)
		$(cmake-utils_use_enable scripts script)
		$(cmake-utils_use_enable perl)
		$(cmake-utils_use_enable python)
		$(cmake-utils_use_enable ruby)
		$(cmake-utils_use_enable lua)
		$(cmake-utils_use_enable tcl)
		$(cmake-utils_use_enable guile)
		$(cmake-utils_use_enable doc)
	)

	cmake-utils_src_configure
}