[gentoo-commits] gentoo-x86 commit in media-video/dvdstyler: ChangeLog dvdstyler-2.3.4.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/dvdstyler: ChangeLog dvdstyler-2.3.4.ebuild

[Alexis Ballier (aballier)]

aballier    12/11/07 11:03:26

  Modified:             ChangeLog
  Added:                dvdstyler-2.3.4.ebuild
  Log:
  version bump, should fix bugs #424952 and bug #433573
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.54                 media-video/dvdstyler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdstyler/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdstyler/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdstyler/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/dvdstyler/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	5 May 2012 08:58:59 -0000	1.53
+++ ChangeLog	7 Nov 2012 11:03:26 -0000	1.54
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/dvdstyler
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/dvdstyler/ChangeLog,v 1.53 2012/05/05 08:58:59 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/dvdstyler/ChangeLog,v 1.54 2012/11/07 11:03:26 aballier Exp $
+
+*dvdstyler-2.3.4 (07 Nov 2012)
+
+  07 Nov 2012; Alexis Ballier <aballier@gentoo.org> +dvdstyler-2.3.4.ebuild:
+  version bump, should fix bugs #424952 and bug #433573
 
   05 May 2012; Jeff Horelick <jdhore@gentoo.org> dvdstyler-2.1.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig



1.1                  media-video/dvdstyler/dvdstyler-2.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdstyler/dvdstyler-2.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/dvdstyler/dvdstyler-2.3.4.ebuild?rev=1.1&content-type=text/plain

Index: dvdstyler-2.3.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/dvdstyler/dvdstyler-2.3.4.ebuild,v 1.1 2012/11/07 11:03:26 aballier Exp $

EAPI=4

MY_P=${P/dvds/DVDS}
WX_GTK_VER=2.8

inherit wxwidgets

DESCRIPTION="A cross-platform free DVD authoring application"
HOMEPAGE="http://www.dvdstyler.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug gnome kernel_linux"

COMMON_DEPEND=">=app-cdr/dvd+rw-tools-7.1
	>=media-libs/libexif-0.6.16
	>=media-libs/wxsvg-1.1.9
	>=media-video/dvdauthor-0.7.0
	>=media-video/xine-ui-0.99.1
	virtual/cdrtools
	>=virtual/ffmpeg-0.10[encode]
	virtual/jpeg
	>=x11-libs/wxGTK-2.8.7:2.8[gstreamer,X]
	gnome? ( >=gnome-base/libgnomeui-2 )
	kernel_linux? ( sys-fs/udev )"
RDEPEND="${COMMON_DEPEND}
	>=app-cdr/dvdisaster-0.72.2"
DEPEND="${COMMON_DEPEND}
	virtual/yacc
	app-arch/zip
	app-text/xmlto
	virtual/pkgconfig
	sys-devel/gettext"

S=${WORKDIR}/${MY_P}

src_prepare() {
	use gnome || sed -i -e '/PKG_CONFIG/s:libgnomeui-2.0:dIsAbLeAuToMaGiC&:' configure

	# rmdir: failed to remove `tempfoobar': Directory not empty
	sed -i -e '/rmdir "$$t"/d' docs/Makefile.in || die

	sed -i -e 's:@LIBS@:& -ljpeg:' wxVillaLib/Makefile.in || die #367863
}

src_configure() {
	econf \
	 	--docdir=/usr/share/doc/${PF} \
		$(use_enable debug) \
		--with-wx-config=${WX_CONFIG}
}

src_install() {
	default
	rm -f "${ED}"usr/share/doc/${PF}/{COPYING*,INSTALL*}
}