[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: metadata.xml alsa-utils-1.0.26-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: metadata.xml alsa-utils-1.0.26-r1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      12/11/06 23:17:02

  Modified:             metadata.xml ChangeLog
  Added:                alsa-utils-1.0.26-r1.ebuild
  Log:
  Add USE="ncurses libsamplerate" to control utils that use the respective libs, and expand USE=minimal to control alsa-info (which uses dialog) #441982.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.7                  media-sound/alsa-utils/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	1 Aug 2009 14:49:12 -0000	1.6
+++ metadata.xml	6 Nov 2012 23:17:02 -0000	1.7
@@ -5,4 +5,9 @@
   <maintainer>
     <email>alsa-bugs@gentoo.org</email>
   </maintainer>
+  <use>
+    <flag name='libsamplerate'>install utils that use libsamplerate (e.g. alsaloop)</flag>
+    <flag name='minimal'>omit utils that rely on extra packages (e.g. alsaconf and alsa-info)</flag>
+    <flag name='ncurses'>install utils that use ncurses (e.g. alsamixer)</flag>
+  </use>
 </pkgmetadata>



1.328                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.328&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.328&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.327&r2=1.328

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.327
retrieving revision 1.328
diff -u -r1.327 -r1.328
--- ChangeLog	9 Sep 2012 09:13:26 -0000	1.327
+++ ChangeLog	6 Nov 2012 23:17:02 -0000	1.328
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/alsa-utils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.327 2012/09/09 09:13:26 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.328 2012/11/06 23:17:02 vapier Exp $
+
+*alsa-utils-1.0.26-r1 (06 Nov 2012)
+
+  06 Nov 2012; Mike Frysinger <vapier@gentoo.org> +alsa-utils-1.0.26-r1.ebuild,
+  metadata.xml:
+  Add USE="ncurses libsamplerate" to control utils that use the respective libs,
+  and expand USE=minimal to control alsa-info (which uses dialog) #441982.
 
   09 Sep 2012; Samuli Suominen <ssuominen@gentoo.org>
   -alsa-utils-1.0.23-r1.ebuild, -files/alsa-utils-1.0.23-alsactl-output.patch,



1.1                  media-sound/alsa-utils/alsa-utils-1.0.26-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.26-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.26-r1.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.26-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.26-r1.ebuild,v 1.1 2012/11/06 23:17:02 vapier Exp $

EAPI=4
inherit eutils systemd toolchain-funcs

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${P}.tar.bz2
	!minimal? ( mirror://alsaproject/driver/alsa-driver-1.0.25.tar.bz2 )"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="doc +libsamplerate minimal +ncurses nls selinux"

COMMON_DEPEND=">=media-libs/alsa-lib-${PV}
	libsamplerate? ( media-libs/libsamplerate )
	ncurses? ( >=sys-libs/ncurses-5.7-r7 )
	selinux? ( sec-policy/selinux-alsa )"
RDEPEND="${COMMON_DEPEND}
	!minimal? (
		dev-util/dialog
		sys-apps/pciutils
	)"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	doc? ( app-text/xmlto )"

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-1.0.23-modprobe.d.patch \
		"${FILESDIR}"/${PN}-1.0.25-separate-usr-var-fs.patch
}

src_configure() {
	local myconf
	use doc || myconf='--disable-xmlto'

	local udevdir=/lib/udev
	has_version sys-fs/udev && udevdir="$($(tc-getPKG_CONFIG) --variable=udevdir udev)"

	econf \
		$(use_enable libsamplerate alsaloop) \
		$(use_enable nls) \
		$(use_enable ncurses alsamixer) \
		$(use_enable !minimal alsaconf) \
		"$(systemd_with_unitdir)" \
		--with-udev-rules-dir="${udevdir}"/rules.d \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc ChangeLog README TODO seq/*/README.*

	use minimal || newbin "${WORKDIR}"/alsa-driver-*/utils/alsa-info.sh alsa-info

	newinitd "${FILESDIR}"/alsasound.initd-r5 alsasound
	newconfd "${FILESDIR}"/alsasound.confd-r4 alsasound

	insinto /etc/modprobe.d
	newins "${FILESDIR}"/alsa-modules.conf-rc alsa.conf

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "saving and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
	ewarn "The ALSA core should be built into the kernel or loaded through other"
	ewarn "means. There is no longer any modular auto(un)loading in alsa-utils."
	echo
}