[gentoo-commits] gentoo-x86 commit in app-pda/gtkpod: metadata.xml ChangeLog gtkpod-2.1.2-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-pda/gtkpod: metadata.xml ChangeLog gtkpod-2.1.2-r1.ebuild

[Justin Lecher (jlec)]

jlec        12/11/02 11:37:11

  Modified:             metadata.xml ChangeLog
  Added:                gtkpod-2.1.2-r1.ebuild
  Log:
  app-pda/gtkpod: Fid for buffer overflow, #434220
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.5                  app-pda/gtkpod/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/gtkpod/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	10 May 2012 07:24:16 -0000	1.4
+++ metadata.xml	2 Nov 2012 11:37:11 -0000	1.5
@@ -1,9 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <herd>pda</herd>
-  <use>
-    <flag name='clutter'>Enable clutter support for displaying coverart</flag>
-    <flag name='webkit'>Enable webkit support for finding coverart</flag>
-  </use>
+	<herd>pda</herd>
+	<use>
+		<flag name="clutter">Enable clutter support for displaying coverart</flag>
+		<flag name="webkit">Enable webkit support for finding coverart</flag>
+	</use>
 </pkgmetadata>



1.115                app-pda/gtkpod/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/ChangeLog?r1=1.114&r2=1.115

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog	23 Sep 2012 12:06:55 -0000	1.114
+++ ChangeLog	2 Nov 2012 11:37:11 -0000	1.115
@@ -1,6 +1,12 @@
 # ChangeLog for app-pda/gtkpod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.114 2012/09/23 12:06:55 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.115 2012/11/02 11:37:11 jlec Exp $
+
+*gtkpod-2.1.2-r1 (02 Nov 2012)
+
+  02 Nov 2012; Justin Lecher <jlec@gentoo.org> +gtkpod-2.1.2-r1.ebuild,
+  +files/gtkpod-2.1.2-bffr-overflow.patch, metadata.xml:
+  Fid for buffer overflow, #434220
 
   23 Sep 2012; Samuli Suominen <ssuominen@gentoo.org> -gtkpod-2.1.1-r3.ebuild,
   -files/gtkpod-2.1.1-segfault_with_directory_creation.patch:



1.1                  app-pda/gtkpod/gtkpod-2.1.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/gtkpod-2.1.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/gtkpod/gtkpod-2.1.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: gtkpod-2.1.2-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/gtkpod-2.1.2-r1.ebuild,v 1.1 2012/11/02 11:37:11 jlec Exp $

EAPI=4
inherit eutils gnome2-utils

DESCRIPTION="A graphical user interface to the Apple productline"
HOMEPAGE="http://gtkpod.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2 FDL-1.2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="aac clutter curl cdr flac gstreamer mp3 vorbis webkit"

COMMON_DEPEND="dev-libs/gdl:3
	>=dev-libs/glib-2.28.5
	>=dev-libs/libxml2-2.7.7
	>=dev-util/anjuta-2.91
	>=media-libs/libgpod-0.7.0
	>=media-libs/libid3tag-0.15
	>=x11-libs/gtk+-3.0.8:3
	aac? ( media-libs/faad2 )
	clutter? ( media-libs/clutter-gtk:1.0 )
	curl? ( >=net-misc/curl-7.10 )
	cdr? (
		>=app-cdr/brasero-3
		media-libs/musicbrainz:3
		)
	flac? ( media-libs/flac )
	gstreamer? ( >=media-libs/gst-plugins-base-0.10.25:0.10 )
	mp3? ( media-sound/lame )
	vorbis? (
		media-libs/libvorbis
		media-sound/vorbis-tools
		)
	webkit? ( >=net-libs/webkit-gtk-1.3:3 )"
RDEPEND="${COMMON_DEPEND}
	gstreamer? ( media-plugins/gst-plugins-meta:0.10 )"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	sys-devel/flex
	sys-devel/gettext
	virtual/os-headers
	virtual/pkgconfig"

src_prepare() {
	# Make sure SLOT="4" is not used. Everyone should move from "3" to "5" directly.
	sed -i -e '/PKG_CONFIG/s:libmusicbrainz4:&sLoT4iSdEpReCaTeD:' configure || die

	# /path/to/install: '/path/to/app-pda/gtkpod-2.1.2_beta2/image/usr/share/gtkpod/data/rhythmbox.gep’: File exists
	sed -i -e '/^dist_profiles_DATA/s:=.*:=:' plugins/sjcd/data/Makefile.in || die

	sed -i -e 's:python:python2:' scripts/sync-palm-jppy.py || die

	epatch "${FILESDIR}"/${P}-bffr-overflow.patch
}

src_configure() {
	export GST_INSPECT=true #420279

	econf \
		--disable-static \
		$(use_enable webkit plugin-coverweb) \
		$(use_enable clutter plugin-clarity) \
		$(use_enable gstreamer plugin-media-player) \
		$(use_enable cdr plugin-sjcd) \
		$(use_with curl) \
		$(use_with vorbis ogg) \
		$(use_with flac) \
		$(use_with aac mp4)
}

src_install() {
	emake \
		DESTDIR="${D}" \
		docdir=/usr/share/doc/${PF}/html \
		figuresdir=/usr/share/doc/${PF}/html/figures \
		install

	prune_libtool_files --all

	dodoc AUTHORS ChangeLog NEWS README TODO TROUBLESHOOTING
	rm -f "${ED}"/usr/share/gtkpod/data/{AUTHORS,COPYING}
}

pkg_preinst() {
	gnome2_icon_savelist
	gnome2_schemas_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	gnome2_schemas_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	gnome2_schemas_update
}