[gentoo-commits] gentoo-x86 commit in www-client/google-chrome: google-chrome-24.0.1312.2_alpha165266.ebuild ChangeLog google-chrome-24.0.1312.1_alpha164922.ebuild

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

From: "Michael Weber (xmw)" <xmw@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in www-client/google-chrome: google-chrome-24.0.1312.2_alpha165266.ebuild ChangeLog google-chrome-24.0.1312.1_alpha164922.ebuild
Date: Fri,  2 Nov 2012 01:38:45 +0000 (UTC)	[thread overview]
Message-ID: <20121102013845.9568C21600@flycatcher.gentoo.org> (raw)

xmw         12/11/02 01:38:45

  Modified:             ChangeLog
  Added:                google-chrome-24.0.1312.2_alpha165266.ebuild
  Removed:              google-chrome-24.0.1312.1_alpha164922.ebuild
  Log:
  Dev channel bump
  
  (Portage version: 2.1.11.31/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.209                www-client/google-chrome/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome/ChangeLog?rev=1.209&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome/ChangeLog?rev=1.209&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome/ChangeLog?r1=1.208&r2=1.209

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/google-chrome/ChangeLog,v
retrieving revision 1.208
retrieving revision 1.209
diff -u -r1.208 -r1.209
--- ChangeLog	31 Oct 2012 20:06:35 -0000	1.208
+++ ChangeLog	2 Nov 2012 01:38:45 -0000	1.209
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/google-chrome
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/ChangeLog,v 1.208 2012/10/31 20:06:35 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/ChangeLog,v 1.209 2012/11/02 01:38:45 xmw Exp $
+
+*google-chrome-24.0.1312.2_alpha165266 (02 Nov 2012)
+
+  02 Nov 2012; Michael Weber <xmw@gentoo.org>
+  -google-chrome-24.0.1312.1_alpha164922.ebuild,
+  +google-chrome-24.0.1312.2_alpha165266.ebuild:
+  Dev channel bump
 
 *google-chrome-24.0.1312.1_alpha164922 (31 Oct 2012)
 *google-chrome-23.0.1271.60_beta164911 (31 Oct 2012)



1.1                  www-client/google-chrome/google-chrome-24.0.1312.2_alpha165266.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome/google-chrome-24.0.1312.2_alpha165266.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome/google-chrome-24.0.1312.2_alpha165266.ebuild?rev=1.1&content-type=text/plain

Index: google-chrome-24.0.1312.2_alpha165266.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome/google-chrome-24.0.1312.2_alpha165266.ebuild,v 1.1 2012/11/02 01:38:45 xmw Exp $

EAPI="4"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
	sv sw ta te th tr uk vi zh_CN zh_TW"

inherit chromium eutils multilib pax-utils unpacker

DESCRIPTION="The web browser from Google"
HOMEPAGE="http://www.google.com/chrome"

case ${PV} in
	*_alpha*)
		SLOT="unstable"
		MY_PV=${PV/_alpha/-r}
		;;
	*_beta*)
		SLOT="beta"
		MY_PV=${PV/_beta/-r}
		;;
	*_p*)
		SLOT="stable"
		MY_PV=${PV/_p/-r}
		;;
	*)
		die "Invalid value for \${PV}: ${PV}"
		;;
esac

MY_PN="${PN}-${SLOT}"
MY_P="${MY_PN}_${MY_PV}"

SRC_BASE="http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_"
SRC_URI="amd64? ( ${SRC_BASE}amd64.deb ) x86? ( ${SRC_BASE}i386.deb )"

LICENSE="google-chrome"
KEYWORDS="-* ~amd64 ~x86"
IUSE="+plugins"
RESTRICT="mirror strip"

RDEPEND="
	app-arch/bzip2
	app-misc/ca-certificates
	dev-libs/atk
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/libgcrypt
	dev-libs/nspr
	dev-libs/nss
	gnome-base/gconf:2
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	net-print/cups
	sys-apps/dbus
	|| ( >=sys-devel/gcc-4.4.0[-nocxx] >=sys-devel/gcc-4.4.0[cxx] )
	sys-fs/udev
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXScrnSaver
	x11-libs/pango
	x11-misc/xdg-utils
"

# Add blockers for the other slots.
for x in 0 beta stable unstable; do
	if [[ ${SLOT} != ${x} ]]; then
		RDEPEND+=" !${CATEGORY}/${PN}:${x}"
	fi
done

QA_PREBUILT="*"
S=${WORKDIR}

pkg_nofetch() {
	eerror "Please do not report bugs for google-chrome fetch failures."
	eerror "The problem will be resolved with the next version bump."
	eerror "Sync your portage tree and try again."
}

pkg_setup() {
	CHROME_HOME="opt/google/chrome/"
	chromium_suid_sandbox_check_kernel_config
	declare -f src_install
}

src_install() {
	pax-mark m ${CHROME_HOME}chrome || die
	rm -rf usr/share/menu || die
	mv usr/share/doc/${PN} usr/share/doc/${PF} || die

	pushd "${CHROME_HOME}locales" > /dev/null || die
	chromium_remove_language_paks
	popd

	mv opt usr "${D}" || die

	fperms u+s "/${CHROME_HOME}chrome-sandbox" || die

	if use plugins ; then
		local plugins="--extra-plugin-dir=/usr/$(get_libdir)/nsbrowser/plugins"
		sed -e "/^exec/ i set -- \"${plugins}\" \"\$@\"" \
			-i "${D}${CHROME_HOME}google-chrome" || die
	fi

	domenu "${D}${CHROME_HOME}google-chrome.desktop" || die
	local size
	for size in 16 22 24 32 48 64 128 256 ; do
		insinto /usr/share/icons/hicolor/${size}x${size}/apps
		newins "${D}${CHROME_HOME}product_logo_${size}.png" google-chrome.png
	done

	# Compatibility symlink for newer udev, bug 423415.
	dosym "/usr/$(get_libdir)/libudev.so" "${CHROME_HOME}libudev.so.0"
}

any_cpu_missing_flag() {
	local value=$1
	grep '^flags' /proc/cpuinfo | grep -qv "$value"
}

pkg_preinst() {
	chromium_pkg_preinst
	if any_cpu_missing_flag sse2; then
		ewarn "The bundled PepperFlash plugin requires a CPU that supports the"
		ewarn "SSE2 instruction set, and at least one of your CPUs does not"
		ewarn "support this feature. Disabling PepperFlash."
		sed -e "/^exec/ i set -- --disable-bundled-ppapi-flash \"\$@\"" \
			-i "${D}${CHROME_HOME}google-chrome" || die
	fi
}

pkg_postinst() {
	chromium_pkg_postinst

	einfo
	elog "Please notice the bundled flash player (PepperFlash)."
	elog "You can (de)activate all flash plugins via chrome://plugins"
	einfo
}

                 reply	other threads:[~2012-11-02  1:39 UTC|newest]

Thread overview: [no followups] expand[flat|nested]  mbox.gz  Atom feed

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20121102013845.9568C21600@flycatcher.gentoo.org \
    --to=xmw@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

Be sure your reply has a Subject: header at the top and a blank line before the message body.

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox