[gentoo-commits] gentoo-x86 commit in www-plugins/lightspark: lightspark-0.7.0.ebuild ChangeLog lightspark-0.5.7.ebuild

[gentoo-commits] gentoo-x86 commit in www-plugins/lightspark: lightspark-0.7.0.ebuild ChangeLog lightspark-0.5.7.ebuild

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    12/10/29 13:36:30

  Modified:             ChangeLog
  Added:                lightspark-0.7.0.ebuild
  Removed:              lightspark-0.5.7.ebuild
  Log:
  Version bump. Drop old.
  
  (Portage version: 2.2.0_alpha137/cvs/Linux x86_64)

Revision  Changes    Path
1.46                 www-plugins/lightspark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	14 Aug 2012 13:51:17 -0000	1.45
+++ ChangeLog	29 Oct 2012 13:36:30 -0000	1.46
@@ -1,6 +1,14 @@
 # ChangeLog for www-plugins/lightspark
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v 1.45 2012/08/14 13:51:17 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/ChangeLog,v 1.46 2012/10/29 13:36:30 chithanh Exp $
+
+*lightspark-0.7.0 (29 Oct 2012)
+
+  29 Oct 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +lightspark-0.7.0.ebuild, -files/lightspark-0.5.7-llvm-3.1_0000.patch,
+  -files/lightspark-0.5.7-llvm-3.1_0002.patch,
+  -files/lightspark-0.6.0.1-gcc-4.5_0001.patch, -lightspark-0.5.7.ebuild:
+  Version bump. Drop old.
 
   14 Aug 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
   lightspark-0.6.0.1.ebuild:



1.1                  www-plugins/lightspark/lightspark-0.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/lightspark-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-plugins/lightspark/lightspark-0.7.0.ebuild?rev=1.1&content-type=text/plain

Index: lightspark-0.7.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-plugins/lightspark/lightspark-0.7.0.ebuild,v 1.1 2012/10/29 13:36:30 chithanh Exp $

EAPI=4
inherit cmake-utils nsplugins multilib

DESCRIPTION="High performance flash player"
HOMEPAGE="http://lightspark.sourceforge.net/"
SRC_URI="http://launchpad.net/${PN}/trunk/${P}/+download/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl ffmpeg gles nsplugin profile pulseaudio rtmp sdl"

RDEPEND=">=dev-cpp/libxmlpp-2.33.1:2.6
	>=dev-libs/boost-1.42
	dev-libs/libpcre[cxx]
	media-fonts/liberation-fonts
	media-libs/libpng
	media-libs/libsdl
	>=sys-devel/llvm-3
	x11-libs/cairo
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/pango
	curl? (
		net-misc/curl
	)
	ffmpeg? (
		virtual/ffmpeg
	)
	!gles? (
		>=media-libs/glew-1.5.3
		virtual/opengl
	)
	gles? (
		media-libs/mesa[gles2]
	)
	pulseaudio? (
		media-sound/pulseaudio
	)
	rtmp? (
		media-video/rtmpdump
	)
	virtual/jpeg"
DEPEND="${RDEPEND}
	amd64? ( dev-lang/nasm )
	x86? ( dev-lang/nasm )
	virtual/pkgconfig"

S=${WORKDIR}/${P/_rc*/}

src_configure() {
	local audiobackends
	use pulseaudio && audiobackends+="pulse"
	use sdl && audiobackends+="sdl"

	local mycmakeargs=(
		$(cmake-utils_use curl ENABLE_CURL)
		$(cmake-utils_use gles ENABLE_GLES2)
		$(cmake-utils_use ffmpeg ENABLE_LIBAVCODEC)
		$(cmake-utils_use nsplugin COMPILE_PLUGIN)
		$(cmake-utils_use profile ENABLE_MEMORY_USAGE_PROFILING)
		$(cmake-utils_use profile ENABLE_PROFILING)
		$(cmake-utils_use rtmp ENABLE_RTMP)
		-DAUDIO_BACKEND="${audiobackends}"
		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so

	# default to sdl audio if pulseaudio plugin is not built, bug #406197
	if use sdl && ! use pulseaudio; then
		sed -i 's/backend = pulseaudio/backend = sdl/' "${ED}/etc/xdg/${PN}.conf" || die
	fi
}

pkg_postinst() {
	if use nsplugin && ! has_version www-plugins/gnash; then
		elog "Lightspark now supports gnash fallback for its browser plugin."
		elog "Install www-plugins/gnash to take advantage of it."
	fi
	if use nsplugin && has_version www-plugins/gnash[nsplugin]; then
		elog "Having two plugins installed for the same MIME type may confuse"
		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
		elog "USE flag for either gnash or lightspark. For details, see"
		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
	fi
}