[gentoo-commits] gentoo-x86 commit in sys-apps/less: less-452.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/less: less-452.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/10/23 08:15:26

  Modified:             ChangeLog
  Added:                less-452.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha141/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.154                sys-apps/less/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	9 Sep 2012 16:06:19 -0000	1.153
+++ ChangeLog	23 Oct 2012 08:15:26 -0000	1.154
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.153 2012/09/09 16:06:19 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.154 2012/10/23 08:15:26 radhermit Exp $
+
+*less-452 (23 Oct 2012)
+
+  23 Oct 2012; Tim Harder <radhermit@gentoo.org> +less-452.ebuild:
+  Version bump.
 
   09 Sep 2012; Raúl Porcel <armin76@gentoo.org> less-451.ebuild:
   alpha/ia64/m68k/s390/sh/sparc stable wrt #431956



1.1                  sys-apps/less/less-452.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-452.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/less/less-452.ebuild?rev=1.1&content-type=text/plain

Index: less-452.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-452.ebuild,v 1.1 2012/10/23 08:15:26 radhermit Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Excellent text file viewer"
HOMEPAGE="http://www.greenwoodsoftware.com/less/"
SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
	http://www-zeuthen.desy.de/~friebel/unix/less/code2color"

LICENSE="|| ( GPL-3 BSD-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="pcre unicode"

DEPEND=">=app-misc/editor-wrapper-3
	>=sys-libs/ncurses-5.2
	pcre? ( dev-libs/libpcre )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${P}.tar.gz
	cp "${DISTDIR}"/code2color "${S}"/
}

src_prepare() {
	epatch "${FILESDIR}"/code2color.patch
}

src_configure() {
	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
	export ac_cv_lib_ncurses_initscr=$(usex !unicode)
	econf \
		--with-regex=$(usex pcre pcre posix) \
		--with-editor="${EPREFIX}"/usr/libexec/editor
}

src_install() {
	default

	dobin code2color
	newbin "${FILESDIR}"/lesspipe.sh lesspipe
	dosym lesspipe /usr/bin/lesspipe.sh
	newenvd "${FILESDIR}"/less.envd 70less

	dodoc "${FILESDIR}"/README.Gentoo
}

pkg_postinst() {
	einfo "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
}