[gentoo-commits] gentoo-x86 commit in sys-cluster/knem: knem-1.0.0.ebuild ChangeLog knem-0.9.8.ebuild knem-0.9.7.ebuild

[gentoo-commits] gentoo-x86 commit in sys-cluster/knem: knem-1.0.0.ebuild ChangeLog knem-0.9.8.ebuild knem-0.9.7.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      12/10/12 10:44:12

  Modified:             ChangeLog
  Added:                knem-1.0.0.ebuild
  Removed:              knem-0.9.8.ebuild knem-0.9.7.ebuild
  Log:
  [sys-cluster/knem] Version bump
  
  (Portage version: 2.2.0_alpha137/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  sys-cluster/knem/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	29 Apr 2012 13:00:11 -0000	1.4
+++ ChangeLog	12 Oct 2012 10:44:12 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/knem
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v 1.4 2012/04/29 13:00:11 alexxy Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/ChangeLog,v 1.5 2012/10/12 10:44:12 alexxy Exp $
+
+*knem-1.0.0 (12 Oct 2012)
+
+  12 Oct 2012; Alexey Shvetsov <alexxy@gentoo.org> +knem-1.0.0.ebuild,
+  -knem-0.9.7.ebuild, -knem-0.9.8.ebuild:
+  [sys-cluster/knem] Version bump
 
 *knem-0.9.8 (29 Apr 2012)
 
@@ -18,4 +24,3 @@
   20 Jan 2012; Alexey Shvetsov <alexxy@gentoo.org> +files/45-knem.rules,
   +knem-0.9.7.ebuild, +metadata.xml:
   Initial import
-



1.1                  sys-cluster/knem/knem-1.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/knem-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/knem/knem-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: knem-1.0.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/knem/knem-1.0.0.ebuild,v 1.1 2012/10/12 10:44:12 alexxy Exp $

EAPI=4

inherit autotools linux-mod linux-info toolchain-funcs multilib

DESCRIPTION="High-Performance Intra-Node MPI Communication"
HOMEPAGE="http://runtime.bordeaux.inria.fr/knem/"
SRC_URI="http://runtime.bordeaux.inria.fr/knem/download/${P}.tar.gz"

LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug modules"

DEPEND="
		sys-apps/hwloc
		virtual/linux-sources"
RDEPEND="
		sys-apps/hwloc
		virtual/modutils"

MODULE_NAMES="knem(misc:${S}/driver/linux)"
BUILD_TARGETS="all"
BUILD_PARAMS="KDIR=${KERNEL_DIR}"

pkg_setup() {
	linux-info_pkg_setup
	linux-mod_pkg_setup
	ARCH="$(tc-arch-kernel)"
	ABI="${KERNEL_ABI}"
}

src_prepare() {
	sed 's:driver/linux::g' -i Makefile.am
	eautoreconf
}

src_configure() {
	econf \
		--enable-hwloc \
		--with-linux="${KERNEL_DIR}" \
		--with-linux-release=${KV_FULL} \
		$(use_enable debug)
}

src_compile() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_compile || die "failed to build driver"
	fi
}

src_install() {
	default
	if use modules; then
		cd "${S}/driver/linux"
		linux-mod_src_install || die "failed to install driver"
	fi

	# Drop funny unneded stuff
	rm "${ED}/usr/sbin/knem_local_install" || die
	rmdir "${ED}/usr/sbin" || die
	# install udev rules
	local udevdir=/lib/udev
	if has_version sys-fs/udev ; then
		udevdir="$($(tc-getPKG_CONFIG) --variable=udevdir udev)"
	fi
	insinto "${udevdir}/rules.d"
	doins "${FILESDIR}/45-knem.rules" || die
	rm "${ED}/etc/10-knem.rules" || die
}