[gentoo-commits] gentoo-x86 commit in dev-libs/dbus-glib: ChangeLog dbus-glib-0.100-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/dbus-glib: ChangeLog dbus-glib-0.100-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/10/10 10:22:24

  Modified:             ChangeLog
  Added:                dbus-glib-0.100-r1.ebuild
  Log:
  Fix broken API docs; prevents build failure with libxslt-1.1.27 (bug #436454, thanks to Andrew Savchenko). Install API docs in /usr/share/gtk-doc to allow links from other packages' documentation files, and for compatibility with standard tools like dev-util/devhelp (bug #404965).
  
  (Portage version: 2.2.0_alpha134/cvs/Linux x86_64)

Revision  Changes    Path
1.108                dev-libs/dbus-glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog	25 Jul 2012 21:09:37 -0000	1.107
+++ ChangeLog	10 Oct 2012 10:22:23 -0000	1.108
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/dbus-glib
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v 1.107 2012/07/25 21:09:37 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v 1.108 2012/10/10 10:22:23 tetromino Exp $
+
+*dbus-glib-0.100-r1 (10 Oct 2012)
+
+  10 Oct 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +dbus-glib-0.100-r1.ebuild, +files/dbus-glib-0.100-dbus-glib-sections.txt:
+  Fix broken API docs; prevents build failure with libxslt-1.1.27 (bug #436454,
+  thanks to Andrew Savchenko). Install API docs in /usr/share/gtk-doc to allow
+  links from other packages' documentation files, and for compatibility with
+  standard tools like dev-util/devhelp (bug #404965).
 
   25 Jul 2012; Markus Meier <maekke@gentoo.org> dbus-glib-0.100.ebuild:
   arm stable, bug #416725



1.1                  dev-libs/dbus-glib/dbus-glib-0.100-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.100-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.100-r1.ebuild?rev=1.1&content-type=text/plain

Index: dbus-glib-0.100-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.100-r1.ebuild,v 1.1 2012/10/10 10:22:23 tetromino Exp $

EAPI=4
inherit bash-completion-r1 eutils

DESCRIPTION="D-Bus bindings for glib"
HOMEPAGE="http://dbus.freedesktop.org/"
SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="|| ( GPL-2 AFL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="debug doc static-libs test"

RDEPEND=">=dev-libs/expat-2
	>=dev-libs/glib-2.26
	>=sys-apps/dbus-1.6.2"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( dev-util/gtk-doc )"

# out of sources build directory
BD=${WORKDIR}/${P}-build
# out of sources build dir for make check
TBD=${WORKDIR}/${P}-tests-build

src_prepare() {
	# Wrong sections.txt file in the tarball; https://bugs.freedesktop.org/show_bug.cgi?id=55830
	cp "${FILESDIR}/${P}-dbus-glib-sections.txt" doc/reference/dbus-glib-sections.txt || die
}

src_configure() {
	local myconf=(
		--localstatedir="${EPREFIX}"/var
		--enable-bash-completion
		$(use_enable debug verbose-mode)
		$(use_enable debug asserts)
		$(use_enable static-libs static)
		$(use_enable doc gtk-doc)
		)

	mkdir "${BD}"
	cd "${BD}"
	einfo "Running configure in ${BD}"
	ECONF_SOURCE="${S}" econf "${myconf[@]}"

	if use test; then
		mkdir "${TBD}"
		cd "${TBD}"
		einfo "Running configure in ${TBD}"
		ECONF_SOURCE="${S}" econf \
			"${myconf[@]}" \
			$(use_enable test checks) \
			$(use_enable test tests) \
			$(use_enable test asserts) \
			$(use_with test test-socket-dir "${T}"/dbus-test-socket)
	fi
}

src_compile() {
	cd "${BD}"
	einfo "Running make in ${BD}"
	emake

	if use test; then
		cd "${TBD}"
		einfo "Running make in ${TBD}"
		emake
	fi
}

src_test() {
	cd "${TBD}"
	emake check
}

src_install() {
	# NEWS file is obsolete
	dodoc AUTHORS ChangeLog HACKING README

	cd "${BD}"
	emake DESTDIR="${D}" install

	newbashcomp "${ED}"/etc/bash_completion.d/dbus-bash-completion.sh dbus
	rm -rf "${ED}"/etc/bash_completion.d || die

	prune_libtool_files
}