* [gentoo-commits] gentoo-x86 commit in dev-db/mongodb: mongodb-2.2.0-r1.ebuild ChangeLog
@ 2012-10-09 18:54 Ian Stakenvicius (axs)
0 siblings, 0 replies; only message in thread
From: Ian Stakenvicius (axs) @ 2012-10-09 18:54 UTC (permalink / raw
To: gentoo-commits
axs 12/10/09 18:54:01
Modified: ChangeLog
Added: mongodb-2.2.0-r1.ebuild
Log:
Use upstream embedded spidermonkey (bug 390631); build against boost indeoendent of eselect
(Portage version: 2.1.11.9/cvs/Linux x86_64)
Revision Changes Path
1.47 dev-db/mongodb/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?r1=1.46&r2=1.47
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog 7 Oct 2012 14:59:52 -0000 1.46
+++ ChangeLog 9 Oct 2012 18:54:01 -0000 1.47
@@ -1,6 +1,14 @@
# ChangeLog for dev-db/mongodb
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.46 2012/10/07 14:59:52 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.47 2012/10/09 18:54:01 axs Exp $
+
+*mongodb-2.2.0-r1 (09 Oct 2012)
+
+ 09 Oct 2012; Ian Stakenvicius <axs@gentoo.org>
+ +files/mongodb-2.2-r1-fix-boost.patch, +files/mongodb-2.2-r1-fix-scons.patch,
+ +mongodb-2.2.0-r1.ebuild:
+ Use upstream embedded spidermonkey (bug 390631); build against boost
+ indeoendent of eselect
07 Oct 2012; Fabian Groffen <grobian@gentoo.org> mongodb-2.2.0.ebuild:
Fix for Prefix
1.1 dev-db/mongodb/mongodb-2.2.0-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.2.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.2.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: mongodb-2.2.0-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/mongodb-2.2.0-r1.ebuild,v 1.1 2012/10/09 18:54:01 axs Exp $
EAPI=4
SCONS_MIN_VERSION="1.2.0"
BOOST_MAX_SLOT="1.49"
inherit eutils boost-utils flag-o-matic multilib pax-utils scons-utils user versionator
MY_P=${PN}-src-r${PV/_rc/-rc}
DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
HOMEPAGE="http://www.mongodb.org"
SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz
mms-agent? ( http://dev.gentoo.org/~ultrabug/20120830-10gen-mms-agent.zip )"
LICENSE="AGPL-3 Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mms-agent static-libs v8"
PDEPEND="mms-agent? ( dev-python/pymongo )"
RDEPEND="
v8? ( dev-lang/v8 )
<dev-libs/boost-1.50
dev-libs/libpcre[cxx]
dev-util/google-perftools
net-libs/libpcap
app-arch/snappy"
DEPEND="${RDEPEND}
sys-libs/readline
sys-libs/ncurses"
S=${WORKDIR}/${MY_P}
pkg_setup() {
enewgroup mongodb
enewuser mongodb -1 -1 /var/lib/${PN} mongodb
scons_opts=" --cc=$(tc-getCC) --cxx=$(tc-getCXX)"
scons_opts+=" --use-system-tcmalloc"
scons_opts+=" --use-system-pcre"
scons_opts+=" --use-system-snappy"
scons_opts+=" --use-system-boost"
if use v8; then
scons_opts+=" --usev8"
else
scons_opts+=" --usesm"
fi
local boostver=$(boost-utils_get_best_slot)
scons_opts+=" --boost-version=${boostver/./_}"
append-cxxflags "-I$(boost-utils_get_includedir)"
}
src_prepare() {
epatch "${FILESDIR}/${PN}-2.2-r1-fix-scons.patch"
epatch "${FILESDIR}/${PN}-2.2-r1-fix-boost.patch"
# FIXME: apply only this fix [1] on x86 boxes as it breaks /usr/lib symlink
# on amd64 machines [2].
# [1] https://jira.mongodb.org/browse/SERVER-5575
# [2] https://bugs.gentoo.org/show_bug.cgi?id=434664
if use !prefix && [[ "$(get_libdir)" == "lib" ]]; then
epatch "${FILESDIR}/${PN}-2.2-fix-x86client.patch"
fi
}
src_compile() {
escons ${scons_opts} all
}
src_install() {
escons ${scons_opts} --full --nostrip install --prefix="${ED}"/usr
use static-libs || rm "${ED}/usr/$(get_libdir)/libmongoclient.a"
use v8 && pax-mark m "${ED}"/usr/bin/{mongo,mongod}
for x in /var/{lib,log,run}/${PN}; do
keepdir "${x}"
fowners mongodb:mongodb "${x}"
done
doman debian/mongo*.1
dodoc README docs/building.md
newinitd "${FILESDIR}/${PN}.initd" ${PN}
newconfd "${FILESDIR}/${PN}.confd" ${PN}
newinitd "${FILESDIR}/${PN/db/s}.initd" ${PN/db/s}
newconfd "${FILESDIR}/${PN/db/s}.confd" ${PN/db/s}
insinto /etc/logrotate.d/
newins "${FILESDIR}/${PN}.logrotate" ${PN}
if use mms-agent; then
local MY_PN="mms-agent"
local MY_D="/opt/${MY_PN}"
insinto ${MY_D}
doins "${WORKDIR}/${MY_PN}/"*
fowners -R mongodb:mongodb ${MY_D}
newinitd "${FILESDIR}/${MY_PN}.initd" ${MY_PN}
newconfd "${FILESDIR}/${MY_PN}.confd" ${MY_PN}
fi
}
src_test() {
escons ${scons_opts} test
"${S}"/test --dbpath=unittest || die
}
pkg_postinst() {
if [[ ${REPLACING_VERSIONS} < 1.8 ]]; then
ewarn "You just upgraded from a previous version of mongodb !"
ewarn "Make sure you run 'mongod --upgrade' before using this version."
fi
elog "Journaling is now enabled by default, see /etc/conf.d/${PN}"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-10-09 18:54 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-10-09 18:54 [gentoo-commits] gentoo-x86 commit in dev-db/mongodb: mongodb-2.2.0-r1.ebuild ChangeLog Ian Stakenvicius (axs)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox