[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: e2fsprogs-libs-1.42.6.ebuild ChangeLog

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      12/10/07 16:17:39

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.42.6.ebuild
  Log:
  Version bump #437434 by Bernhard Hartleb.
  
  (Portage version: 2.2.0_alpha131/cvs/Linux x86_64)

Revision  Changes    Path
1.93                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.93&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.93&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.92&r2=1.93

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.92
retrieving revision 1.93
diff -u -r1.92 -r1.93
--- ChangeLog	20 Aug 2012 16:24:22 -0000	1.92
+++ ChangeLog	7 Oct 2012 16:17:39 -0000	1.93
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.92 2012/08/20 16:24:22 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.93 2012/10/07 16:17:39 vapier Exp $
+
+*e2fsprogs-libs-1.42.6 (07 Oct 2012)
+
+  07 Oct 2012; Mike Frysinger <vapier@gentoo.org> +e2fsprogs-libs-1.42.6.ebuild:
+  Version bump #437434 by Bernhard Hartleb.
 
   20 Aug 2012; Sébastien Fabbro <bicatali@gentoo.org>
   e2fsprogs-libs-1.42.5.ebuild:



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.6.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.42.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.6.ebuild,v 1.1 2012/10/07 16:17:39 vapier Exp $

EAPI="2"

case ${PV} in
*_pre*) UP_PV="${PV%_pre*}-WIP-${PV#*_pre}" ;;
*)      UP_PV=${PV} ;;
esac

inherit toolchain-funcs eutils

DESCRIPTION="e2fsprogs libraries (common error and subsystem)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${PN}-${UP_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="nls static-libs"

RDEPEND="!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41.8"
DEPEND="nls? ( sys-devel/gettext )
	virtual/pkgconfig"

S=${WORKDIR}/${P%_pre*}

src_prepare() {
	printf 'all:\n%%:;@:\n' > doc/Makefile.in # don't bother with docs #305613
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	# we use blkid/uuid from util-linux now
	ac_cv_lib_uuid_uuid_generate=yes \
	ac_cv_lib_blkid_blkid_get_cache=yes \
	ac_cv_path_LDCONFIG=: \
	QUOTA_CMT='#' \
	econf \
		--disable-lib{blkid,uuid} \
		--disable-quota \
		--enable-${libtype}-shlibs \
		$(tc-has-tls || echo --disable-tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die
	gen_usr_ldscript -a com_err ss
	# configure doesn't have an option to disable static libs :/
	use static-libs || find "${D}" -name '*.a' -delete
}