* [gentoo-commits] gentoo-x86 commit in www-client/midori: metadata.xml ChangeLog midori-9999.ebuild midori-0.4.7.ebuild
@ 2012-09-20 8:30 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2012-09-20 8:30 UTC (permalink / raw
To: gentoo-commits
ssuominen 12/09/20 08:30:56
Modified: metadata.xml ChangeLog midori-9999.ebuild
Added: midori-0.4.7.ebuild
Log:
Version bump. New USE flag "zeitgeist" for optional dev-libs/libzeitgeist dependency.
(Portage version: 2.2.0_alpha128/cvs/Linux x86_64)
Revision Changes Path
1.13 www-client/midori/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/metadata.xml?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/metadata.xml?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/metadata.xml?r1=1.12&r2=1.13
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/midori/metadata.xml,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- metadata.xml 15 Apr 2012 12:50:14 -0000 1.12
+++ metadata.xml 20 Sep 2012 08:30:56 -0000 1.13
@@ -5,5 +5,6 @@
<use>
<flag name='deprecated'>Enable GTK+-2 instead of GTK+-3 because of external plugins like adobe-flash</flag>
<flag name='unique'>Enable single instance support using <pkg>dev-libs/libunique</pkg></flag>
+ <flag name='zeitgeist'>Add support for Zeitgeist event tracking system</flag>
</use>
</pkgmetadata>
1.98 www-client/midori/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?rev=1.98&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?rev=1.98&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/ChangeLog?r1=1.97&r2=1.98
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v
retrieving revision 1.97
retrieving revision 1.98
diff -u -r1.97 -r1.98
--- ChangeLog 18 Aug 2012 13:27:25 -0000 1.97
+++ ChangeLog 20 Sep 2012 08:30:56 -0000 1.98
@@ -1,6 +1,13 @@
# ChangeLog for www-client/midori
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.97 2012/08/18 13:27:25 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.98 2012/09/20 08:30:56 ssuominen Exp $
+
+*midori-0.4.7 (20 Sep 2012)
+
+ 20 Sep 2012; Samuli Suominen <ssuominen@gentoo.org> +midori-0.4.7.ebuild,
+ midori-9999.ebuild, metadata.xml:
+ Version bump. New USE flag "zeitgeist" for optional dev-libs/libzeitgeist
+ dependency.
18 Aug 2012; Johannes Huber <johu@gentoo.org> midori-0.4.6-r1.ebuild:
Stable for x86, wrt bug #430270
1.43 www-client/midori/midori-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-9999.ebuild?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-9999.ebuild?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-9999.ebuild?r1=1.42&r2=1.43
Index: midori-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- midori-9999.ebuild 15 May 2012 15:16:48 -0000 1.42
+++ midori-9999.ebuild 20 Sep 2012 08:30:56 -0000 1.43
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.42 2012/05/15 15:16:48 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-9999.ebuild,v 1.43 2012/09/20 08:30:56 ssuominen Exp $
EAPI=4
@@ -16,19 +16,19 @@
inherit eutils fdo-mime gnome2-utils python waf-utils ${_live_inherits}
-PV_vala_version=0.16
+VALA_VERSION=0.18
DESCRIPTION="A lightweight web browser based on WebKitGTK+"
HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
LICENSE="LGPL-2.1 MIT"
SLOT="0"
-IUSE="+deprecated doc gnome libnotify nls +unique"
+IUSE="+deprecated doc gnome libnotify nls +unique zeitgeist"
-RDEPEND="dev-db/sqlite:3
+RDEPEND=">=dev-db/sqlite-3.6.19:3
>=dev-libs/glib-2.22
dev-libs/libxml2
- net-libs/libsoup:2.4
+ >=net-libs/libsoup-2.34:2.4
x11-libs/libXScrnSaver
deprecated? (
net-libs/webkit-gtk:2
@@ -36,15 +36,17 @@
unique? ( dev-libs/libunique:1 )
)
!deprecated? (
+ >=app-crypt/gcr-3
net-libs/webkit-gtk:3
x11-libs/gtk+:3
unique? ( dev-libs/libunique:3 )
)
- gnome? ( net-libs/libsoup-gnome:2.4 )
- libnotify? ( >=x11-libs/libnotify-0.7 )"
+ gnome? ( >=net-libs/libsoup-gnome-2.34:2.4 )
+ libnotify? ( >=x11-libs/libnotify-0.7 )
+ zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
DEPEND="${RDEPEND}
|| ( dev-lang/python:2.7 dev-lang/python:2.6 )
- dev-lang/vala:${PV_vala_version}
+ dev-lang/vala:${VALA_VERSION}
dev-util/intltool
gnome-base/librsvg
doc? ( dev-util/gtk-doc )
@@ -66,10 +68,18 @@
fi
}
+src_prepare() {
+ # TODO: Both zeitgeist and gcr should have ./configure switch!
+ use zeitgeist || { sed -i -e 's:zeitgeist:&dIsAbLe:' wscript || die; }
+
+ # Force disabled because we don't have this custom renamed in Portage
+ sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
+}
+
src_configure() {
strip-linguas -i po
- VALAC="$(type -P valac-${PV_vala_version})" \
+ VALAC="$(type -P valac-${VALA_VERSION})" \
waf-utils_src_configure \
--disable-docs \
$(use_enable doc apidocs) \
1.1 www-client/midori/midori-0.4.7.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-0.4.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/midori/midori-0.4.7.ebuild?rev=1.1&content-type=text/plain
Index: midori-0.4.7.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.4.7.ebuild,v 1.1 2012/09/20 08:30:56 ssuominen Exp $
EAPI=4
unset _live_inherits
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="git://git.xfce.org/apps/${PN}"
_live_inherits=git-2
else
KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
fi
inherit eutils fdo-mime gnome2-utils python waf-utils ${_live_inherits}
VALA_VERSION=0.18
DESCRIPTION="A lightweight web browser based on WebKitGTK+"
HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
LICENSE="LGPL-2.1 MIT"
SLOT="0"
IUSE="+deprecated doc gnome libnotify nls +unique zeitgeist"
RDEPEND=">=dev-db/sqlite-3.6.19:3
>=dev-libs/glib-2.22
dev-libs/libxml2
>=net-libs/libsoup-2.34:2.4
x11-libs/libXScrnSaver
deprecated? (
net-libs/webkit-gtk:2
x11-libs/gtk+:2
unique? ( dev-libs/libunique:1 )
)
!deprecated? (
>=app-crypt/gcr-3
net-libs/webkit-gtk:3
x11-libs/gtk+:3
unique? ( dev-libs/libunique:3 )
)
gnome? ( >=net-libs/libsoup-gnome-2.34:2.4 )
libnotify? ( >=x11-libs/libnotify-0.7 )
zeitgeist? ( >=dev-libs/libzeitgeist-0.3.14 )"
DEPEND="${RDEPEND}
|| ( dev-lang/python:2.7 dev-lang/python:2.6 )
dev-lang/vala:${VALA_VERSION}
dev-util/intltool
gnome-base/librsvg
doc? ( dev-util/gtk-doc )
nls? ( sys-devel/gettext )"
pkg_setup() {
python_set_active_version 2
python_pkg_setup
DOCS=( AUTHORS ChangeLog HACKING INSTALL TODO TRANSLATE )
HTML_DOCS=( data/faq.html data/faq.css )
}
src_unpack() {
if [[ ${PV} == *9999* ]]; then
git-2_src_unpack
else
default
fi
}
src_prepare() {
# TODO: Both zeitgeist and gcr should have ./configure switch!
use zeitgeist || { sed -i -e 's:zeitgeist:&dIsAbLe:' wscript || die; }
# Force disabled because we don't have this custom renamed in Portage
sed -i -e 's:gcr-3-gtk2:&dIsAbLe:' wscript || die
}
src_configure() {
strip-linguas -i po
VALAC="$(type -P valac-${VALA_VERSION})" \
waf-utils_src_configure \
--disable-docs \
$(use_enable doc apidocs) \
$(use_enable unique) \
$(use_enable libnotify) \
--enable-addons \
$(use_enable nls) \
$(use_enable !deprecated gtk3) \
--disable-granite
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
gnome2_icon_cache_update
}
pkg_postrm() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-09-20 8:31 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-09-20 8:30 [gentoo-commits] gentoo-x86 commit in www-client/midori: metadata.xml ChangeLog midori-9999.ebuild midori-0.4.7.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox