[gentoo-commits] gentoo-x86 commit in x11-misc/bumblebee: bumblebee-3.0.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-misc/bumblebee: bumblebee-3.0.1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       12/09/14 20:24:21

  Modified:             ChangeLog
  Added:                bumblebee-3.0.1.ebuild
  Log:
  Version bump, bug #433381 by mrueg.
  
  (Portage version: 2.1.11.14/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  x11-misc/bumblebee/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/bumblebee/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/bumblebee/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/bumblebee/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/bumblebee/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	20 Jun 2012 12:49:22 -0000	1.8
+++ ChangeLog	14 Sep 2012 20:24:21 -0000	1.9
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/bumblebee
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/bumblebee/ChangeLog,v 1.8 2012/06/20 12:49:22 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/bumblebee/ChangeLog,v 1.9 2012/09/14 20:24:21 pacho Exp $
+
+*bumblebee-3.0.1 (14 Sep 2012)
+
+  14 Sep 2012; Pacho Ramos <pacho@gentoo.org> +bumblebee-3.0.1.ebuild:
+  Version bump, bug #433381 by mrueg.
 
   20 Jun 2012; Tomáš Chvátal <scarabeus@gentoo.org> bumblebee-3.0-r2.ebuild:
   Trivial commit, sort the logic and use ED instead of D.
@@ -41,4 +46,3 @@
   +files/bumblebee.nvidia-confd, +metadata.xml:
   Initial commit from bumblebee overlay, this fixes bug #384083. Thanks a lot to
   mva and rei4dan for their work.
-



1.1                  x11-misc/bumblebee/bumblebee-3.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/bumblebee/bumblebee-3.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/bumblebee/bumblebee-3.0.1.ebuild?rev=1.1&content-type=text/plain

Index: bumblebee-3.0.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/bumblebee/bumblebee-3.0.1.ebuild,v 1.1 2012/09/14 20:24:21 pacho Exp $

EAPI=4
inherit multilib systemd user

DESCRIPTION="Service providing elegant and stable means of managing Optimus graphics chipsets"
HOMEPAGE="https://github.com/Bumblebee-Project/Bumblebee"
SRC_URI="mirror://github/Bumblebee-Project/${PN/bu/Bu}/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86"

IUSE="+bbswitch video_cards_nouveau video_cards_nvidia"

RDEPEND="x11-misc/virtualgl
	bbswitch? ( sys-power/bbswitch )
	virtual/opengl
	x11-base/xorg-drivers[video_cards_nvidia?,video_cards_nouveau?]"
DEPEND=">=sys-devel/autoconf-2.68
	sys-devel/automake
	sys-devel/gcc
	virtual/pkgconfig
	dev-libs/glib:2
	x11-libs/libX11
	dev-libs/libbsd
	sys-apps/help2man"

REQUIRED_USE="|| ( video_cards_nouveau video_cards_nvidia )"

src_configure() {
	if use video_cards_nvidia ; then
		# Get paths to GL libs for all ABIs
		local nvlib=""
		for i in  $(get_all_libdirs) ; do
			nvlib="${nvlib}:/usr/${i}/opengl/nvidia/lib"
		done

		local nvpref="/usr/$(get_libdir)/opengl/nvidia"
		local xorgpref="/usr/$(get_libdir)/xorg/modules"
		ECONF_PARAMS="CONF_DRIVER=nvidia CONF_DRIVER_MODULE_NVIDIA=nvidia \
			CONF_LDPATH_NVIDIA=${nvlib#:} \
			CONF_MODPATH_NVIDIA=${nvpref}/lib,${nvpref}/extensions,${xorgpref}/drivers,${xorgpref}"
	fi

	econf ${ECONF_PARAMS}
}

src_install() {
	newconfd "${FILESDIR}"/bumblebee.confd bumblebee
	newinitd "${FILESDIR}"/bumblebee.initd bumblebee
	newenvd  "${FILESDIR}"/bumblebee.envd 99bumblebee
	systemd_dounit scripts/systemd/bumblebeed.service
	default
}

pkg_preinst() {
	use video_cards_nvidia || rm "${ED}"/etc/bumblebee/xorg.conf.nvidia
	use video_cards_nouveau || rm "${ED}"/etc/bumblebee/xorg.conf.nouveau

	enewgroup bumblebee
}

pkg_postinst() {
	ewarn "In order to use Bumblebee, add your user to 'bumblebee' group."
	ewarn "You may need to setup your /etc/bumblebee/bumblebee.conf"
}