* [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: gimp-2.8.2.ebuild ChangeLog
@ 2012-08-24 19:11 Sebastian Pipping (sping)
0 siblings, 0 replies; 2+ messages in thread
From: Sebastian Pipping (sping) @ 2012-08-24 19:11 UTC (permalink / raw
To: gentoo-commits
sping 12/08/24 19:11:50
Modified: ChangeLog
Added: gimp-2.8.2.ebuild
Log:
media-gfx/gimp: 2.8.2 (bug #432574)
(Portage version: 2.1.10.65/cvs/Linux x86_64)
Revision Changes Path
1.381 media-gfx/gimp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.381&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.381&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?r1=1.380&r2=1.381
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v
retrieving revision 1.380
retrieving revision 1.381
diff -u -r1.380 -r1.381
--- ChangeLog 9 Aug 2012 18:23:00 -0000 1.380
+++ ChangeLog 24 Aug 2012 19:11:50 -0000 1.381
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/gimp
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.380 2012/08/09 18:23:00 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.381 2012/08/24 19:11:50 sping Exp $
+
+*gimp-2.8.2 (24 Aug 2012)
+
+ 24 Aug 2012; Sebastian Pipping <sping@gentoo.org> +gimp-2.8.2.ebuild:
+ Bump to 2.8.2 (bug #432574)
09 Aug 2012; Brent Baude <ranger@gentoo.org> gimp-2.6.12-r2.ebuild:
Marking gimp-2.6.12-r2 ppc for bug 418425
1.1 media-gfx/gimp/gimp-2.8.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild?rev=1.1&content-type=text/plain
Index: gimp-2.8.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild,v 1.1 2012/08/24 19:11:50 sping Exp $
EAPI="3"
PYTHON_DEPEND="python? 2:2.5"
inherit versionator autotools eutils gnome2 fdo-mime multilib python
DESCRIPTION="GNU Image Manipulation Program"
HOMEPAGE="http://www.gimp.org/"
SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${P}.tar.bz2"
LICENSE="GPL-3 LGPL-3"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
IUSE="alsa aalib altivec bzip2 curl dbus debug doc exif gnome postscript jpeg jpeg2k lcms mmx mng pdf png python smp sse svg tiff udev webkit wmf xpm"
for lang in ${LANGS}; do
IUSE+=" linguas_${lang}"
done
RDEPEND=">=dev-libs/glib-2.30.2:2
>=dev-libs/atk-2.2.0
>=x11-libs/gtk+-2.24.10:2
>=x11-libs/gdk-pixbuf-2.24.1:2
>=x11-libs/cairo-1.10.2
>=x11-libs/pango-1.29.4
xpm? ( x11-libs/libXpm )
>=media-libs/freetype-2.1.7
>=media-libs/fontconfig-2.2.0
sys-libs/zlib
dev-libs/libxml2
dev-libs/libxslt
x11-themes/hicolor-icon-theme
>=media-libs/babl-0.1.10
>=media-libs/gegl-0.2.0
aalib? ( media-libs/aalib )
alsa? ( media-libs/alsa-lib )
curl? ( net-misc/curl )
dbus? ( dev-libs/dbus-glib )
gnome? ( gnome-base/gvfs )
webkit? ( >=net-libs/webkit-gtk-1.6.1:2 )
jpeg? ( virtual/jpeg:0 )
jpeg2k? ( media-libs/jasper )
exif? ( >=media-libs/libexif-0.6.15 )
lcms? ( >=media-libs/lcms-1.16:0 )
mng? ( media-libs/libmng )
pdf? ( >=app-text/poppler-0.12.4[cairo] )
png? ( >=media-libs/libpng-1.2.37:0 )
python? ( >=dev-python/pygtk-2.10.4:2 )
tiff? ( >=media-libs/tiff-3.5.7:0 )
svg? ( >=gnome-base/librsvg-2.36.0:2 )
wmf? ( >=media-libs/libwmf-0.2.8 )
x11-libs/libXcursor
sys-libs/zlib
bzip2? ( app-arch/bzip2 )
postscript? ( app-text/ghostscript-gpl )
udev? ( sys-fs/udev[gudev] )"
DEPEND="${RDEPEND}
sys-apps/findutils
virtual/pkgconfig
>=dev-util/intltool-0.40.1
>=sys-devel/gettext-0.17
doc? ( >=dev-util/gtk-doc-1 )
>=sys-devel/libtool-2.2
>=sys-devel/automake-1.11
dev-util/gtk-doc-am" # due to our call to eautoreconf below (bug #386453)
DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
S="${WORKDIR}"/${P}
pkg_setup() {
G2CONF="--enable-default-binary \
--with-x \
--disable-silent-rules \
$(use_with aalib aa) \
$(use_with alsa) \
$(use_enable altivec) \
$(use_with bzip2) \
$(use_with curl libcurl) \
$(use_with dbus) \
$(use_with gnome gvfs) \
$(use_with webkit) \
$(use_with jpeg libjpeg) \
$(use_with jpeg2k libjasper) \
$(use_with exif libexif) \
$(use_with lcms) \
$(use_with postscript gs) \
$(use_enable mmx) \
$(use_with mng libmng) \
$(use_with pdf poppler) \
$(use_with png libpng) \
$(use_enable python) \
$(use_enable smp mp) \
$(use_enable sse) \
$(use_with svg librsvg) \
$(use_with tiff libtiff) \
$(use_with udev gudev) \
$(use_with wmf) \
--with-xmc \
$(use_with xpm libxpm) \
--without-xvfb-run"
if use python; then
python_set_active_version 2
python_pkg_setup
fi
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-2.7.4-no-deprecation.patch # bug 395695, comment 9 and 16
eautoreconf # If you remove this: remove dev-util/gtk-doc-am from DEPEND, too
echo '#!/bin/sh' > py-compile
gnome2_src_prepare
}
_clean_up_locales() {
elog "Cleaning up locales..."
for lang in ${LANGS}; do
use "linguas_${lang}" && {
elog "- keeping ${lang}"
continue
}
rm -Rf "${D}"/usr/share/locale/"${lang}" || die
done
}
src_install() {
gnome2_src_install
if use python; then
python_convert_shebangs -r $(python_get_version) "${ED}"
python_need_rebuild
fi
# Workaround for bug #321111 to give GIMP the least
# precedence on PDF documents by default
mv "${D}"/usr/share/applications/{,zzz-}gimp.desktop || die
find "${D}" -name '*.la' -delete || die
_clean_up_locales
}
pkg_postinst() {
gnome2_pkg_postinst
use python && python_mod_optimize /usr/$(get_libdir)/gimp/2.0/python \
/usr/$(get_libdir)/gimp/2.0/plug-ins
}
pkg_postrm() {
gnome2_pkg_postrm
use python && python_mod_cleanup /usr/$(get_libdir)/gimp/2.0/python \
/usr/$(get_libdir)/gimp/2.0/plug-ins
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: gimp-2.8.2.ebuild ChangeLog
@ 2012-09-03 22:26 Sebastian Pipping (sping)
0 siblings, 0 replies; 2+ messages in thread
From: Sebastian Pipping (sping) @ 2012-09-03 22:26 UTC (permalink / raw
To: gentoo-commits
sping 12/09/03 22:26:02
Modified: gimp-2.8.2.ebuild ChangeLog
Log:
media-gfx/gimp: Fix dead gimp-console.1 symlink (bug #433527)
(Portage version: 2.1.10.65/cvs/Linux x86_64)
Revision Changes Path
1.2 media-gfx/gimp/gimp-2.8.2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild?r1=1.1&r2=1.2
Index: gimp-2.8.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gimp-2.8.2.ebuild 24 Aug 2012 19:11:50 -0000 1.1
+++ gimp-2.8.2.ebuild 3 Sep 2012 22:26:02 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild,v 1.1 2012/08/24 19:11:50 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/gimp-2.8.2.ebuild,v 1.2 2012/09/03 22:26:02 sping Exp $
EAPI="3"
PYTHON_DEPEND="python? 2:2.5"
@@ -143,6 +143,10 @@
find "${D}" -name '*.la' -delete || die
+ # Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+ local gimp_app_version=$(get_version_component_range 1-2)
+ mv "${D}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
_clean_up_locales
}
1.382 media-gfx/gimp/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.382&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?rev=1.382&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/gimp/ChangeLog?r1=1.381&r2=1.382
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v
retrieving revision 1.381
retrieving revision 1.382
diff -u -r1.381 -r1.382
--- ChangeLog 24 Aug 2012 19:11:50 -0000 1.381
+++ ChangeLog 3 Sep 2012 22:26:02 -0000 1.382
@@ -1,6 +1,9 @@
# ChangeLog for media-gfx/gimp
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.381 2012/08/24 19:11:50 sping Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/gimp/ChangeLog,v 1.382 2012/09/03 22:26:02 sping Exp $
+
+ 03 Sep 2012; Sebastian Pipping <sping@gentoo.org> gimp-2.8.2.ebuild:
+ Prevent dead symlink gimp-console.1 (bug #433527)
*gimp-2.8.2 (24 Aug 2012)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-09-03 22:26 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-08-24 19:11 [gentoo-commits] gentoo-x86 commit in media-gfx/gimp: gimp-2.8.2.ebuild ChangeLog Sebastian Pipping (sping)
-- strict thread matches above, loose matches on Subject: below --
2012-09-03 22:26 Sebastian Pipping (sping)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox