[gentoo-commits] gentoo-x86 commit in net-misc/badvpn: ChangeLog badvpn-1.999.123-r2.ebuild badvpn-1.999.123-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/badvpn: ChangeLog badvpn-1.999.123-r2.ebuild badvpn-1.999.123-r1.ebuild

[William Hubbs (williamh)]

williamh    12/08/23 01:37:22

  Modified:             ChangeLog
  Added:                badvpn-1.999.123-r2.ebuild
  Removed:              badvpn-1.999.123-r1.ebuild
  Log:
  rev bump to fix init scripts for stable OpenRC users.
  
  (Portage version: 2.2.0_alpha121/cvs/Linux i686)

Revision  Changes    Path
1.5                  net-misc/badvpn/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	19 Aug 2012 18:09:49 -0000	1.4
+++ ChangeLog	23 Aug 2012 01:37:21 -0000	1.5
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/badvpn
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.4 2012/08/19 18:09:49 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/ChangeLog,v 1.5 2012/08/23 01:37:21 williamh Exp $
+
+*badvpn-1.999.123-r2 (23 Aug 2012)
+
+  23 Aug 2012; William Hubbs <williamh@gentoo.org> -badvpn-1.999.123-r1.ebuild,
+  +badvpn-1.999.123-r2.ebuild, files/badvpn-ncd.init, files/badvpn-server.init:
+  My initial rewrite of the init scripts broke them for stable OpenRc
+  users, so this fixes that issue.
 
   19 Aug 2012; Julian Ospald <hasufell@gentoo.org> metadata.xml:
   add williamh as maintainer



1.1                  net-misc/badvpn/badvpn-1.999.123-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.123-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/badvpn/badvpn-1.999.123-r2.ebuild?rev=1.1&content-type=text/plain

Index: badvpn-1.999.123-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/badvpn/badvpn-1.999.123-r2.ebuild,v 1.1 2012/08/23 01:37:21 williamh Exp $

EAPI=4
inherit eutils cmake-utils user

MY_P=${PN}-${PV/_rc/rc}
DESCRIPTION="Peer-to-peer VPN, NCD scripting language, tun2socks proxifier"
HOMEPAGE="http://code.google.com/p/badvpn/"
SRC_URI="http://badvpn.googlecode.com/files/${MY_P}.tar.bz2"

LICENSE="BSD"
KEYWORDS="~amd64 ~x86"
SLOT="0"
TARGETS="+client +ncd +server +tun2socks +udpgw"
IUSE="${TARGETS} debug"

COMMON_DEPEND="
	client? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	server? (
		dev-libs/nspr
		dev-libs/nss
		dev-libs/openssl
	)
	ncd? (
		dev-libs/openssl
	)"
RDEPEND="${COMMON_DEPEND}
	ncd? (
		net-firewall/iptables
		net-wireless/wpa_supplicant
		sys-apps/iproute2
		>=sys-fs/udev-171
	)"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig"
# we need at least one target
REQUIRED_USE="|| ( ${TARGETS//+/} )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewuser ${PN}
}

src_prepare() {
	# allow user to easily apply patches
	epatch_user
}

src_configure() {
	local mycmakeargs=(
		-DBUILD_NOTHING_BY_DEFAULT=1
		$(cmake-utils_use_build client CLIENT)
		$(cmake-utils_use_build server SERVER)
		$(cmake-utils_use_build ncd NCD)
		$(cmake-utils_use_build tun2socks TUN2SOCKS)
		$(cmake-utils_use_build udpgw UDPGW)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc ChangeLog

	if use server; then
		newinitd "${FILESDIR}"/${PN}-server.init ${PN}-server
		newconfd "${FILESDIR}"/${PN}-server.conf ${PN}-server
	fi

	if use ncd; then
		newinitd "${FILESDIR}"/${PN}-ncd.init ${PN}-ncd
		newconfd "${FILESDIR}"/${PN}-ncd.conf ${PN}-ncd
	fi
}