* [gentoo-commits] gentoo-x86 commit in media-gfx/digikam: ChangeLog digikam-2.8.0.ebuild
@ 2012-08-11 15:08 Andreas HAttel (dilfridge)
0 siblings, 0 replies; only message in thread
From: Andreas HAttel (dilfridge) @ 2012-08-11 15:08 UTC (permalink / raw
To: gentoo-commits
dilfridge 12/08/11 15:08:37
Modified: ChangeLog
Added: digikam-2.8.0.ebuild
Log:
Version bump, bug 430802, thanks creffett
(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)
Revision Changes Path
1.227 media-gfx/digikam/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.227&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.227&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?r1=1.226&r2=1.227
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v
retrieving revision 1.226
retrieving revision 1.227
diff -u -r1.226 -r1.227
--- ChangeLog 6 Aug 2012 17:49:46 -0000 1.226
+++ ChangeLog 11 Aug 2012 15:08:37 -0000 1.227
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/digikam
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.226 2012/08/06 17:49:46 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.227 2012/08/11 15:08:37 dilfridge Exp $
+
+*digikam-2.8.0 (11 Aug 2012)
+
+ 11 Aug 2012; Andreas K. Huettel <dilfridge@gentoo.org> +digikam-2.8.0.ebuild:
+ Version bump, bug 430802, thanks creffett
06 Aug 2012; Agostino Sarubbo <ago@gentoo.org> digikam-2.6.0.ebuild:
Stable for amd64, wrt bug #429842
1.1 media-gfx/digikam/digikam-2.8.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-2.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-2.8.0.ebuild?rev=1.1&content-type=text/plain
Index: digikam-2.8.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-2.8.0.ebuild,v 1.1 2012/08/11 15:08:37 dilfridge Exp $
EAPI=4
KDE_LINGUAS="af ar az be bg bn br bs ca cs csb cy da de el en_GB eo es et eu fa fi fo fr fy ga gl ha he hi hr hsb
hu id is it ja ka kk km ko ku lb lo lt lv mi mk mn ms mt nb nds ne nl nn nso oc pa pl pt pt_BR ro ru
rw se sk sl sq sr sr@Latn ss sv ta te tg th tr tt uk uz uz@cyrillic ven vi wa xh zh_CN zh_HK zh_TW zu"
KDE_HANDBOOK="optional"
CMAKE_MIN_VERSION="2.8"
KDE_MINIMAL="4.8"
KDE_DOC_DIRS="doc-digikam doc-showfoto"
inherit kde4-base
MY_PV=${PV/_/-}
MY_P=${PN}-${MY_PV}
DESCRIPTION="Digital photo management application for KDE"
HOMEPAGE="http://www.digikam.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
LICENSE="GPL-2
handbook? ( FDL-1.2 )"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="addressbook debug doc gphoto2 mysql semantic-desktop themedesigner +thumbnails video"
CDEPEND="
$(add_kdebase_dep kdelibs 'semantic-desktop=')
$(add_kdebase_dep kdebase-kioslaves)
$(add_kdebase_dep libkdcraw)
$(add_kdebase_dep libkexiv2)
$(add_kdebase_dep libkipi)
$(add_kdebase_dep marble plasma)
$(add_kdebase_dep solid)
media-libs/jasper
media-libs/lcms:0
media-libs/lensfun
media-libs/libkface
media-libs/libkgeomap
media-libs/liblqr
>=media-libs/libpgf-6.12.27
media-libs/libpng
media-libs/tiff
sci-libs/clapack
virtual/jpeg
x11-libs/qt-gui:4[qt3support]
|| ( x11-libs/qt-sql:4[mysql] x11-libs/qt-sql:4[sqlite] )
addressbook? ( $(add_kdebase_dep kdepimlibs) )
gphoto2? ( media-libs/libgphoto2 )
mysql? ( virtual/mysql )
"
RDEPEND="${CDEPEND}
$(add_kdebase_dep kreadconfig)
media-plugins/kipi-plugins
video? (
|| (
$(add_kdebase_dep mplayerthumbs)
$(add_kdebase_dep ffmpegthumbs)
)
)
"
DEPEND="${CDEPEND}
dev-libs/boost
sys-devel/gettext
doc? ( app-doc/doxygen )
"
S="${WORKDIR}/${MY_P}/core"
RESTRICT=test
# bug 366505
src_prepare() {
# just to make absolutely sure
rm -rf "${WORKDIR}/${MY_P}/extra" || die
# prepare the handbook
mkdir doc-digikam doc-showfoto || die
echo "add_subdirectory( en )" > doc-digikam/CMakeLists.txt || die
mv "${WORKDIR}/${MY_P}/doc/${PN}/digikam" doc-digikam/en || die
echo "add_subdirectory( en )" > doc-showfoto/CMakeLists.txt || die
mv "${WORKDIR}/${MY_P}/doc/${PN}/showfoto" doc-showfoto/en || die
sed -i -e 's:../digikam/:../../doc-digikam/en/:g' doc-showfoto/en/index.docbook || die
# prepare the translations
mv "${WORKDIR}/${MY_P}/po" po || die
find po -name "*.po" -and -not -name "digikam.po" -exec rm {} +
echo "find_package(Msgfmt REQUIRED)" >> CMakeLists.txt || die
echo "find_package(Gettext REQUIRED)" >> CMakeLists.txt || die
echo "add_subdirectory( po )" >> CMakeLists.txt || die
kde4-base_src_prepare
if use handbook; then
echo "add_subdirectory( doc-digikam )" >> CMakeLists.txt
echo "add_subdirectory( doc-showfoto )" >> CMakeLists.txt
fi
}
src_configure() {
local backend
use semantic-desktop && backend="Nepomuk" || backend="None"
# LQR = only allows to choose between bundled/external
local mycmakeargs=(
-DFORCED_UNBUNDLE=ON
-DWITH_LQR=ON
-DWITH_LENSFUN=ON
-DGWENVIEW_SEMANTICINFO_BACKEND=${backend}
$(cmake-utils_use_with addressbook KdepimLibs)
-DWITH_MarbleWidget=ON
$(cmake-utils_use_enable gphoto2 GPHOTO2)
$(cmake-utils_use_with gphoto2)
$(cmake-utils_use_with semantic-desktop Soprano)
$(cmake-utils_use_enable themedesigner)
$(cmake-utils_use_enable thumbnails THUMBS_DB)
$(cmake-utils_use_enable mysql INTERNALMYSQL)
$(cmake-utils_use_enable debug DEBUG_MESSAGES)
)
kde4-base_src_configure
}
src_compile() {
local mytargets="all"
use doc && mytargets+=" doc"
kde4-base_src_compile ${mytargets}
}
src_install() {
kde4-base_src_install
if use doc; then
# install the api documentation
insinto /usr/share/doc/${PF}/html
doins -r ${CMAKE_BUILD_DIR}/api/html/*
fi
}
pkg_postinst() {
kde4-base_pkg_postinst
if use doc; then
elog "The digikam api documentation has been installed at /usr/share/doc/${PF}/html"
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-08-11 15:08 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-08-11 15:08 [gentoo-commits] gentoo-x86 commit in media-gfx/digikam: ChangeLog digikam-2.8.0.ebuild Andreas HAttel (dilfridge)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox