* [gentoo-commits] gentoo-x86 commit in dev-libs/kpathsea: ChangeLog kpathsea-6.1.0_p20120701.ebuild
@ 2012-07-26 11:34 Alexis Ballier (aballier)
0 siblings, 0 replies; only message in thread
From: Alexis Ballier (aballier) @ 2012-07-26 11:34 UTC (permalink / raw
To: gentoo-commits
aballier 12/07/26 11:34:56
Modified: ChangeLog
Added: kpathsea-6.1.0_p20120701.ebuild
Log:
Bump to the TeX Live 2012 version.
(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)
Revision Changes Path
1.29 dev-libs/kpathsea/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/ChangeLog?r1=1.28&r2=1.29
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog 26 Apr 2012 20:44:37 -0000 1.28
+++ ChangeLog 26 Jul 2012 11:34:56 -0000 1.29
@@ -1,6 +1,12 @@
# ChangeLog for dev-libs/kpathsea
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v 1.28 2012/04/26 20:44:37 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/ChangeLog,v 1.29 2012/07/26 11:34:56 aballier Exp $
+
+*kpathsea-6.1.0_p20120701 (26 Jul 2012)
+
+ 26 Jul 2012; Alexis Ballier <aballier@gentoo.org>
+ +kpathsea-6.1.0_p20120701.ebuild:
+ Bump to the TeX Live 2012 version.
26 Apr 2012; Alexis Ballier <aballier@gentoo.org>
kpathsea-6.0.1_p20110705.ebuild:
1.1 dev-libs/kpathsea/kpathsea-6.1.0_p20120701.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/kpathsea-6.1.0_p20120701.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/kpathsea/kpathsea-6.1.0_p20120701.ebuild?rev=1.1&content-type=text/plain
Index: kpathsea-6.1.0_p20120701.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/kpathsea/kpathsea-6.1.0_p20120701.ebuild,v 1.1 2012/07/26 11:34:56 aballier Exp $
EAPI=4
inherit texlive-common eutils
TEXMFD_VERSION="4"
DESCRIPTION="Library implementing generic path searching, configuration, and TeX-specific file searching"
HOMEPAGE="http://tug.org/texlive/"
SRC_URI="mirror://gentoo/texlive-${PV#*_p}-source.tar.xz
mirror://gentoo/${PN}-texmf.d-${TEXMFD_VERSION}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="doc source static-libs"
DEPEND="!<app-text/texlive-core-2010
!app-text/ptex"
RDEPEND="${DEPEND}"
S=${WORKDIR}/texlive-${PV#*_p}-source/texk/${PN}
TL_VERSION=2012
EXTRA_TL_MODULES="kpathsea"
EXTRA_TL_DOC_MODULES="kpathsea.doc"
for i in ${EXTRA_TL_MODULES} ; do
SRC_URI="${SRC_URI} mirror://gentoo/texlive-module-${i}-${TL_VERSION}.tar.xz"
done
SRC_URI="${SRC_URI} doc? ( "
for i in ${EXTRA_TL_DOC_MODULES} ; do
SRC_URI="${SRC_URI} mirror://gentoo/texlive-module-${i}-${TL_VERSION}.tar.xz"
done
SRC_URI="${SRC_URI} ) "
src_configure() {
# Too many regexps use A-Z a-z constructs, what causes problems with locales
# that don't have the same alphabetical order than ascii. Bug #347798
# So we set LC_ALL to C in order to avoid problems.
export LC_ALL=C
# Disable largefile because it seems to cause problems on big endian 32 bits
# systems...
econf \
--disable-largefile \
$(use_enable static-libs static)
}
src_install() {
emake DESTDIR="${D}" web2cdir="${EPREFIX}/usr/share/texmf/web2c" install
find "${D}" -name '*.la' -delete
dodir /usr/share # just in case
cp -pR "${WORKDIR}"/texmf "${ED}/usr/share/" || die "failed to install texmf trees"
if use source ; then
cp -pR "${WORKDIR}"/tlpkg "${ED}/usr/share/" || die "failed to install tlpkg files"
fi
# The default configuration expects it to be world writable, bug #266680
# People can still change it with texconfig though.
dodir /var/cache/fonts
fperms 1777 /var/cache/fonts
# Take care of fmtutil.cnf and texmf.cnf
dodir /etc/texmf/{fmtutil.d,texmf.d}
# Remove default texmf.cnf to ship our own, greatly based on texlive dvd's
# texmf.cnf
# It will also be generated from /etc/texmf/texmf.d files by texmf-update
rm -f "${ED}${TEXMF_PATH}/web2c/texmf.cnf"
insinto /etc/texmf/texmf.d
doins "${WORKDIR}/texmf.d/"*.cnf
# Remove fmtutil.cnf, it will be regenerated from /etc/texmf/fmtutil.d files
# by texmf-update
rm -f "${ED}${TEXMF_PATH}/web2c/fmtutil.cnf"
dosym /etc/texmf/web2c/fmtutil.cnf ${TEXMF_PATH}/web2c/fmtutil.cnf
dosym /etc/texmf/web2c/texmf.cnf ${TEXMF_PATH}/web2c/texmf.cnf
# Keep it as that's where the formats will go
keepdir /var/lib/texmf
dodoc BUGS ChangeLog NEWS PROJECTS README
}
pkg_postinst() {
etexmf-update
}
pkg_postrm() {
etexmf-update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-07-26 11:35 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-07-26 11:34 [gentoo-commits] gentoo-x86 commit in dev-libs/kpathsea: ChangeLog kpathsea-6.1.0_p20120701.ebuild Alexis Ballier (aballier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox