* [gentoo-commits] gentoo-x86 commit in media-sound/csound: ChangeLog csound-5.17.6-r1.ebuild
@ 2012-05-29 12:10 Tim Harder (radhermit)
0 siblings, 0 replies; 2+ messages in thread
From: Tim Harder (radhermit) @ 2012-05-29 12:10 UTC (permalink / raw
To: gentoo-commits
radhermit 12/05/29 12:10:22
Modified: ChangeLog
Added: csound-5.17.6-r1.ebuild
Log:
Revision bump. Drop unused vst USE flag and fix python library install dir.
(Portage version: 2.2.0_alpha108/cvs/Linux x86_64)
Revision Changes Path
1.18 media-sound/csound/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?r1=1.17&r2=1.18
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog 29 May 2012 12:02:15 -0000 1.17
+++ ChangeLog 29 May 2012 12:10:21 -0000 1.18
@@ -1,6 +1,11 @@
# ChangeLog for media-sound/csound
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v 1.17 2012/05/29 12:02:15 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v 1.18 2012/05/29 12:10:21 radhermit Exp $
+
+*csound-5.17.6-r1 (29 May 2012)
+
+ 29 May 2012; Tim Harder <radhermit@gentoo.org> +csound-5.17.6-r1.ebuild:
+ Revision bump. Drop unused vst USE flag and fix python library install dir.
*csound-5.17.11 (29 May 2012)
1.1 media-sound/csound/csound-5.17.6-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/csound-5.17.6-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/csound-5.17.6-r1.ebuild?rev=1.1&content-type=text/plain
Index: csound-5.17.6-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/csound-5.17.6-r1.ebuild,v 1.1 2012/05/29 12:10:21 radhermit Exp $
EAPI="4"
PYTHON_DEPEND="python? 2"
inherit eutils multilib python java-pkg-opt-2 cmake-utils toolchain-funcs versionator
MY_PN="${PN/c/C}"
MY_P="${MY_PN}${PV}"
DESCRIPTION="A sound design and signal processing system providing facilities for composition and performance"
HOMEPAGE="http://csounds.com/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+alsa beats chua csoundac +cxx debug double-precision dssi examples fltk +fluidsynth
+image jack java keyboard linear lua luajit nls osc openmp portaudio portmidi pulseaudio
python samples static-libs stk tcl test +threads +utils vim-syntax"
LANGS=" de en_GB en_US es_CO fr it ro ru"
IUSE+="${LANGS// / linguas_}"
RDEPEND=">=media-libs/libsndfile-1.0.16
alsa? ( media-libs/alsa-lib )
csoundac? ( x11-libs/fltk:1[threads?]
dev-libs/boost
=dev-lang/python-2* )
dssi? ( media-libs/dssi
media-libs/ladspa-sdk )
fluidsynth? ( media-sound/fluidsynth )
fltk? ( x11-libs/fltk:1[threads?] )
image? ( media-libs/libpng )
jack? ( media-sound/jack-audio-connection-kit )
java? ( >=virtual/jdk-1.5 )
keyboard? ( x11-libs/fltk:1[threads?] )
linear? ( sci-mathematics/gmm )
lua? (
luajit? ( dev-lang/luajit:2 )
!luajit? ( dev-lang/lua )
)
osc? ( media-libs/liblo )
portaudio? ( media-libs/portaudio )
portmidi? ( media-libs/portmidi )
pulseaudio? ( media-sound/pulseaudio )
stk? ( media-libs/stk )
tcl? ( >=dev-lang/tcl-8.5
>=dev-lang/tk-8.5 )
utils? ( !media-sound/snd )"
DEPEND="${RDEPEND}
sys-devel/flex
virtual/yacc
chua? ( dev-libs/boost )
csoundac? ( dev-lang/swig )
nls? ( sys-devel/gettext )
test? ( =dev-lang/python-2* )"
REQUIRED_USE="java? ( cxx )
linear? ( double-precision )
lua? ( cxx )
python? ( cxx )"
S=${WORKDIR}/${MY_P}
pkg_setup() {
if use openmp ; then
tc-has-openmp || die "Please switch to an openmp compatible compiler"
fi
if use python || use test ; then
python_set_active_version 2
fi
use python && python_pkg_setup
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-5.16.6-tests.patch
epatch "${FILESDIR}"/${P}-fltk.patch
epatch "${FILESDIR}"/${P}-porttime-in-portmidi.patch
sed -i -e "s:^\(csoundExecutable =\).*:\1 \"${WORKDIR}/${P}_build/csound\":" \
tests/test.py || die
sed -i -e '/set(PLUGIN_INSTALL_DIR/s/-${APIVERSION}//' CMakeLists.txt || die
if [[ $(get_libdir) == "lib64" ]] ; then
sed -i -e '/set(LIBRARY_INSTALL_DIR/s/lib/lib64/' CMakeLists.txt || die
fi
if use python ; then
sed -i -e "/set(PYTHON_MODULE_INSTALL_DIR/s#\${LIBRARY_INSTALL_DIR}#$(python_get_sitedir)#" CMakeLists.txt || die
fi
}
src_configure() {
local myconf
if use csoundac ; then
myconf+=" -DBUILD_CSOUND_AC_PYTHON_INTERFACE=$(usex python ON OFF)"
myconf+=" -DBUILD_CSOUND_AC_LUA_INTERFACE=$(usex lua ON OFF)"
fi
local mycmakeargs=(
-DBUILD_NEW_PARSER=ON
$(cmake-utils_use_use alsa ALSA) \
$(cmake-utils_use_build beats CSBEATS) \
$(cmake-utils_use_build chua CHUA_OPCODES) \
$(cmake-utils_use_build csoundac CSOUND_AC) \
$(cmake-utils_use_build cxx CXX_INTERFACE) \
$(cmake-utils_use debug NEW_PARSER_DEBUG) \
$(cmake-utils_use_use double-precision DOUBLE) \
$(cmake-utils_use_build dssi DSSI_OPCODES) \
$(cmake-utils_use_build fluidsynth FLUID_OPCODES) \
$(cmake-utils_use_use fltk FLTK) \
$(cmake-utils_use_build image IMAGE_OPCODES) \
$(cmake-utils_use_use jack JACK) \
$(cmake-utils_use_build jack JACK_OPCODES) \
$(cmake-utils_use_build java JAVA_INTERFACE) \
$(cmake-utils_use_build keyboard VIRTUAL_KEYBOARD) \
$(cmake-utils_use_build linear LINEAR_ALGEBRA_OPCODES) \
$(cmake-utils_use_build lua LUA_OPCODES) \
$(cmake-utils_use_build lua LUA_INTERFACE) \
$(cmake-utils_use_use nls GETTEXT) \
$(cmake-utils_use_build osc OSC_OPCODES) \
$(cmake-utils_use_use openmp OPEN_MP) \
$(cmake-utils_use_use portaudio PORTAUDIO) \
$(cmake-utils_use_use portmidi PORTMIDI) \
$(cmake-utils_use_use pulseaudio PULSEAUDIO) \
$(cmake-utils_use_build python PYTHON_OPCODES) \
$(cmake-utils_use_build python PYTHON_INTERFACE) \
$(cmake-utils_use_build static-libs STATIC_LIBRARY) \
$(cmake-utils_use_build stk STK_OPCODES) \
$(cmake-utils_use_build tcl TCLCSOUND) \
$(cmake-utils_use_build threads MULTI_CORE) \
$(cmake-utils_use_build utils UTILITIES) \
${myconf}
)
cmake-utils_src_configure
}
src_test() {
export LD_LIBRARY_PATH="${S}" OPCODEDIR="${S}" OPCODEDIR64="${S}"
cd tests
./test.py || die "tests failed"
}
src_install() {
cmake-utils_src_install
dodoc AUTHORS ChangeLog readme-csound5-complete.txt
# Generate env.d file
if use double-precision ; then
echo OPCODEDIR64=/usr/$(get_libdir)/${PN}/plugins64 > "${T}"/62${PN}
else
echo OPCODEDIR=/usr/$(get_libdir)/${PN}/plugins > "${T}"/62${PN}
fi
echo "CSSTRNGS=/usr/share/locale" >> "${T}"/62${PN}
use stk && echo "RAWWAVE_PATH=/usr/share/csound/rawwaves" >> "${T}"/62${PN}
doenvd "${T}"/62${PN}
if use examples ; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
use samples && dodoc -r samples
if use vim-syntax ; then
insinto /usr/share/vim/vimfiles/syntax
doins installer/misc/vim/csound_{csd,orc,sco}.vim
insinto /usr/share/vim/vimfiles/plugin
doins installer/misc/vim/csound.vim
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-sound/csound: ChangeLog csound-5.17.6-r1.ebuild
@ 2012-07-23 21:20 Tim Harder (radhermit)
0 siblings, 0 replies; 2+ messages in thread
From: Tim Harder (radhermit) @ 2012-07-23 21:20 UTC (permalink / raw
To: gentoo-commits
radhermit 12/07/23 21:20:53
Modified: ChangeLog
Removed: csound-5.17.6-r1.ebuild
Log:
Remove old.
(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)
Revision Changes Path
1.21 media-sound/csound/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/csound/ChangeLog?r1=1.20&r2=1.21
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog 23 Jul 2012 21:18:24 -0000 1.20
+++ ChangeLog 23 Jul 2012 21:20:53 -0000 1.21
@@ -1,6 +1,9 @@
# ChangeLog for media-sound/csound
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v 1.20 2012/07/23 21:18:24 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/csound/ChangeLog,v 1.21 2012/07/23 21:20:53 radhermit Exp $
+
+ 23 Jul 2012; Tim Harder <radhermit@gentoo.org> -csound-5.17.6-r1.ebuild:
+ Remove old.
23 Jul 2012; Tim Harder <radhermit@gentoo.org> csound-5.17.11.ebuild,
+files/csound-5.17.11-bison-2.6.patch,
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-07-23 21:21 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-07-23 21:20 [gentoo-commits] gentoo-x86 commit in media-sound/csound: ChangeLog csound-5.17.6-r1.ebuild Tim Harder (radhermit)
-- strict thread matches above, loose matches on Subject: below --
2012-05-29 12:10 Tim Harder (radhermit)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox