[gentoo-commits] gentoo-x86 commit in dev-libs/libindicate: libindicate-12.10.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/libindicate: libindicate-12.10.0.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    12/07/21 18:28:51

  Modified:             ChangeLog
  Added:                libindicate-12.10.0.ebuild
  Log:
  Version bump wrt #427512 by Pacho Ramos
  
  (Portage version: 2.2.0_alpha116/cvs/Linux x86_64)

Revision  Changes    Path
1.30                 dev-libs/libindicate/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	4 May 2012 13:12:52 -0000	1.29
+++ ChangeLog	21 Jul 2012 18:28:51 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libindicate
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.29 2012/05/04 13:12:52 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.30 2012/07/21 18:28:51 ssuominen Exp $
+
+*libindicate-12.10.0 (21 Jul 2012)
+
+  21 Jul 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +libindicate-12.10.0.ebuild:
+  Version bump wrt #427512 by Pacho Ramos
 
   04 May 2012; Johannes Huber <johu@gentoo.org> libindicate-0.6.1-r201.ebuild,
   libindicate-0.6.1-r300.ebuild:



1.1                  dev-libs/libindicate/libindicate-12.10.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/libindicate-12.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/libindicate-12.10.0.ebuild?rev=1.1&content-type=text/plain

Index: libindicate-12.10.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/libindicate-12.10.0.ebuild,v 1.1 2012/07/21 18:28:51 ssuominen Exp $

EAPI=4

AYATANA_VALA_VERSION=0.16

inherit autotools eutils flag-o-matic

DESCRIPTION="A library to raise flags on DBus for other components of the desktop to pick up and visualize"
HOMEPAGE="http://launchpad.net/libindicate"
SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"

LICENSE="LGPL-2.1 LGPL-3"
SLOT="3"
KEYWORDS="~amd64 ~x86"
IUSE="gtk +introspection"

RESTRICT="test" # consequence of the -no-mono.patch

RDEPEND=">=dev-libs/dbus-glib-0.100
	>=dev-libs/glib-2.30
	>=dev-libs/libdbusmenu-0.6.2:3[gtk?,introspection?]
	dev-libs/libxml2
	gtk? ( >=x11-libs/gtk+-3.2:3 )
	introspection? ( >=dev-libs/gobject-introspection-1 )
	!<${CATEGORY}/${PN}-0.6.1-r201"
EAUTORECONF_DEPEND="dev-util/gtk-doc-am
	gnome-base/gnome-common"
DEPEND="${RDEPEND}
	${EAUTORECONF_DEPEND}
	app-text/gnome-doc-utils
	dev-lang/vala:${AYATANA_VALA_VERSION}[vapigen]
	virtual/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.6.1-no-mono.patch
	sed -i -e "s:vapigen:vapigen-${AYATANA_VALA_VERSION}:" configure.ac || die
	eautoreconf
}

src_configure() {
	append-flags -Wno-error

	# python bindings are only for GTK+-2.x
	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-silent-rules \
		--disable-static \
		$(use_enable gtk) \
		$(use_enable introspection) \
		--disable-python \
		--disable-scrollkeeper \
		--with-gtk=3 \
		--with-html-dir=/usr/share/doc/${PF}/html
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS ChangeLog NEWS

	nonfatal dosym /usr/share/doc/${PF}/html/${PN} /usr/share/gtk-doc/html/${PN}

	prune_libtool_files
}