[gentoo-commits] gentoo-x86 commit in games-kids/gcompris: ChangeLog gcompris-12.01-r1.ebuild

[gentoo-commits] gentoo-x86 commit in games-kids/gcompris: ChangeLog gcompris-12.01-r1.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    12/07/16 06:41:08

  Modified:             ChangeLog
  Added:                gcompris-12.01-r1.ebuild
  Log:
  Drop the python use flag because it results in confusing lack of functionality (bug #350795)
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.77                 games-kids/gcompris/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-kids/gcompris/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-kids/gcompris/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-kids/gcompris/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -u -r1.76 -r1.77
--- ChangeLog	26 May 2012 03:02:48 -0000	1.76
+++ ChangeLog	16 Jul 2012 06:41:08 -0000	1.77
@@ -1,6 +1,13 @@
 # ChangeLog for games-kids/gcompris
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v 1.76 2012/05/26 03:02:48 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/ChangeLog,v 1.77 2012/07/16 06:41:08 mr_bones_ Exp $
+
+*gcompris-12.01-r1 (16 Jul 2012)
+
+  16 Jul 2012; Michael Sterrett <mr_bones_@gentoo.org>
+  +gcompris-12.01-r1.ebuild:
+  Drop the python use flag because it results in confusing lack of
+  functionality (bug #350795)
 
   26 May 2012; Michael Sterrett <mr_bones_@gentoo.org>
   -files/gcompris-9.6.1-build.patch, -gcompris-9.6.1.ebuild:



1.1                  games-kids/gcompris/gcompris-12.01-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-kids/gcompris/gcompris-12.01-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-kids/gcompris/gcompris-12.01-r1.ebuild?rev=1.1&content-type=text/plain

Index: gcompris-12.01-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-kids/gcompris/gcompris-12.01-r1.ebuild,v 1.1 2012/07/16 06:41:08 mr_bones_ Exp $

EAPI=2

PYTHON_DEPEND="2:2.6"
PYTHON_USE_WITH="sqlite threads"

inherit autotools eutils python games

DESCRIPTION="full featured educational application for children from 2 to 10"
HOMEPAGE="http://gcompris.net/"
SRC_URI="mirror://sourceforge/gcompris/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gnet"

RDEPEND="x11-libs/gtk+:2
	gnome-base/librsvg[gtk]
	media-libs/gstreamer:0.10
	media-libs/gst-plugins-good
	media-plugins/gst-plugins-ogg
	media-plugins/gst-plugins-alsa
	media-plugins/gst-plugins-vorbis
	media-libs/sdl-mixer
	media-libs/libsdl
	dev-libs/libxml2
	dev-libs/popt
	virtual/libintl
	games-board/gnuchess
	dev-db/sqlite:3
	gnet? ( net-libs/gnet:2 )
	dev-python/pygtk"
DEPEND="${RDEPEND}
	gnome-base/gnome-common
	dev-perl/XML-Parser
	sys-devel/gettext
	sys-apps/texinfo
	app-text/texi2html
	virtual/pkgconfig"
RDEPEND="${RDEPEND}
	media-gfx/tuxpaint
	sci-electronics/gnucap"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
	games_pkg_setup
}

src_prepare() {
	# Drop DEPRECATED flags, bug #387817
	sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' \
		src/gcompris/Makefile.am src/gcompris/Makefile.in \
		src/goocanvas/src/Makefile.am src/goocanvas/src/Makefile.in \
		|| die

	epatch "${FILESDIR}"/${P}-build.patch
	cp /usr/share/gettext/config.rpath .
	eautoreconf
}

src_configure() {
	GNUCHESS="${GAMES_BINDIR}"/gnuchess \
	egamesconf \
		--disable-dependency-tracking \
		--datarootdir="${GAMES_DATADIR}" \
		--datadir="${GAMES_DATADIR}" \
		--localedir=/usr/share/locale \
		--infodir=/usr/share/info \
		--with-python="$(PYTHON -a)" \
		$(use_enable gnet) \
		--enable-sqlite \
		--enable-py-build-only
}

src_compile() {
	emake -j1 || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	find "${D}" -name '*.la' -exec rm -f '{}' +
	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
	prepgamesdirs
}