[gentoo-commits] gentoo-x86 commit in sys-fs/vhba: ChangeLog vhba-20120422.ebuild vhba-1.2.1.ebuild vhba-20101015-r1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-fs/vhba: ChangeLog vhba-20120422.ebuild vhba-1.2.1.ebuild vhba-20101015-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/07/05 00:11:07

  Modified:             ChangeLog
  Added:                vhba-20120422.ebuild
  Removed:              vhba-1.2.1.ebuild vhba-20101015-r1.ebuild
  Log:
  Version bump. Drop ancient versions incompatible with modern kernels.
  
  (Portage version: 2.2.0_alpha115/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 sys-fs/vhba/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/vhba/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/vhba/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/vhba/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/vhba/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	24 May 2012 04:20:30 -0000	1.33
+++ ChangeLog	5 Jul 2012 00:11:07 -0000	1.34
@@ -1,6 +1,17 @@
 # ChangeLog for sys-fs/vhba
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/vhba/ChangeLog,v 1.33 2012/05/24 04:20:30 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/vhba/ChangeLog,v 1.34 2012/07/05 00:11:07 tetromino Exp $
+
+*vhba-20120422 (05 Jul 2012)
+
+  05 Jul 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  -files/1.2.1-kerneldir.patch, -files/vhba-1.2.1-kernel-2.6.33.patch,
+  -files/1.2.1-parallel_build.patch, -files/vhba-1.0.0-makefile.patch,
+  -files/vhba-1.0.0-scatterlist.patch, -files/vhba-1.0.0-scsicmnd.patch,
+  -vhba-1.2.1.ebuild, -files/vhba-1.2.1-kernel-2.6.34.patch,
+  -vhba-20101015-r1.ebuild,
+  -files/vhba-20101015-scsi-host-lock-push-down.patch, +vhba-20120422.ebuild:
+  Version bump. Drop ancient versions incompatible with modern kernels.
 
   24 May 2012; Mike Frysinger <vapier@gentoo.org> vhba-1.2.1.ebuild,
   vhba-20101015-r1.ebuild, vhba-20110915.ebuild:



1.1                  sys-fs/vhba/vhba-20120422.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/vhba/vhba-20120422.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/vhba/vhba-20120422.ebuild?rev=1.1&content-type=text/plain

Index: vhba-20120422.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/vhba/vhba-20120422.ebuild,v 1.1 2012/07/05 00:11:07 tetromino Exp $

EAPI="4"

inherit linux-mod user

MY_P=vhba-module-${PV}
DESCRIPTION="Virtual (SCSI) Host Bus Adapter kernel module for the CDEmu suite"
HOMEPAGE="http://cdemu.org"
SRC_URI="mirror://sourceforge/cdemu/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~x86"
IUSE=""

RDEPEND=">=sys-fs/udev-125"
DEPEND=""

S=${WORKDIR}/${MY_P}
MODULE_NAMES="vhba(block:${S})"
BUILD_TARGETS=all

pkg_setup() {
	CONFIG_CHECK="~BLK_DEV_SR ~CHR_DEV_SG"
	check_extra_config
	BUILD_PARAMS="KDIR=${KV_DIR}"
	linux-mod_pkg_setup

	enewgroup cdemu
}

src_prepare() {
	# Avoid "make jobserver unavailable" warning
	sed -e 's:\t$(KMAKE):\t+$(KMAKE):g' -i Makefile || die "sed failed"
}

src_install() {
	dodoc AUTHORS ChangeLog README
	linux-mod_src_install

	einfo "Generating udev rules ..."
	dodir /lib/udev/rules.d/
	cat > "${D}"/lib/udev/rules.d/70-vhba.rules <<-EOF || die
	# do not edit this file, it will be overwritten on update
	#
	KERNEL=="vhba_ctl", MODE="0660", OWNER="root", GROUP="cdemu"
	EOF
}

pkg_postinst() {
	elog "Don't forget to add your user to the cdemu group if you want to"
	elog "be able to use virtual cdemu devices."

	# Older versions of vhba installed their rule file in /etc/udev/rules.d,
	# which overrides rules in /lib/udev/rules.d. We remove the old file
	# automatically if it is identical to the default one installed by
	# vhba-1.2.1 or 20101015-r1. Note that the comment at the top of the rules
	# file states that it can be automatically overwritten by the system.
	old_rules="${ROOT}etc/udev/rules.d/70-vhba.rules"
	if [[ -f "${old_rules}" ]]; then
		case "$(md5sum ${old_rules})" in
		  2959b3cf61cfe6e466cc3516a7bc19de* | 1e7a7e5d6d28c811eeec98ec26ed5d28* )
		  	elog
			elog "Removing old ${old_rules} ..."
			rm -f "${old_rules}" ||
				eerror "Failed, please remove ${old_rules} manually."
			;;
		  * )
			ewarn
			ewarn "The ${old_rules} file from a previous"
			ewarn "installation of ${PN} is overriding ${P}'s"
			ewarn "udev rules. Unless you had deliberately customized it,"
			ewarn "you should remove it."
			ewarn
			;;
		esac
	fi

	linux-mod_pkg_postinst
}