[gentoo-commits] gentoo-x86 commit in sys-boot/os-prober: ChangeLog os-prober-1.53.ebuild os-prober-1.47.ebuild os-prober-1.51.ebuild

[gentoo-commits] gentoo-x86 commit in sys-boot/os-prober: ChangeLog os-prober-1.53.ebuild os-prober-1.47.ebuild os-prober-1.51.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    12/06/29 16:25:50

  Modified:             ChangeLog
  Added:                os-prober-1.53.ebuild
  Removed:              os-prober-1.47.ebuild os-prober-1.51.ebuild
  Log:
  Version bump to version from wheezy. Drop older and stable the to-be-stable-debian version.
  
  (Portage version: 2.2.0_alpha114/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.14                 sys-boot/os-prober/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	30 Mar 2012 04:21:10 -0000	1.13
+++ ChangeLog	29 Jun 2012 16:25:49 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for sys-boot/os-prober
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.13 2012/03/30 04:21:10 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/ChangeLog,v 1.14 2012/06/29 16:25:49 scarabeus Exp $
+
+*os-prober-1.53 (29 Jun 2012)
+
+  29 Jun 2012; Tomáš Chvátal <scarabeus@gentoo.org> -os-prober-1.47.ebuild,
+  -os-prober-1.51.ebuild, +os-prober-1.53.ebuild:
+  Version bump to version from wheezy. Drop older and stable the
+  to-be-stable-debian version.
 
 *os-prober-1.51 (30 Mar 2012)
 



1.1                  sys-boot/os-prober/os-prober-1.53.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.53.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/os-prober/os-prober-1.53.ebuild?rev=1.1&content-type=text/plain

Index: os-prober-1.53.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/os-prober/os-prober-1.53.ebuild,v 1.1 2012/06/29 16:25:49 scarabeus Exp $

EAPI=4

inherit eutils multilib toolchain-funcs

DESCRIPTION="Utility to detect other OSs on a set of drives"
HOMEPAGE="http://packages.debian.org/source/sid/os-prober"
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

src_prepare() {
	find "${S}" -type f -exec sed -i -e "s:/usr/lib/:/usr/libexec/:g" {} + || die

	# use default GNU rules
	rm Makefile
}

src_compile() {
	tc-export CC
	emake newns
}

src_install() {
	dobin os-prober linux-boot-prober

	exeinto /usr/libexec/os-prober
	doexe newns

	insinto /usr/share/os-prober
	doins common.sh

	keepdir /var/lib/os-prober

	local debarch=${ARCH%-*} dir

	case ${debarch} in
		amd64)		debarch=x86 ;;
		ppc|ppc64)	debarch=powerpc ;;
	esac

	for dir in os-probes{,/mounted,/init} linux-boot-probes{,/mounted}; do
		exeinto /usr/libexec/$dir
		doexe $dir/common/*
		if [[ -d $dir/$debarch ]]; then
			doexe $dir/$debarch/*
		fi
	done

	if use amd64 || use x86; then
		exeinto /usr/libexec/os-probes/mounted
		doexe os-probes/mounted/powerpc/20macosx
	fi

	dodoc README TODO debian/changelog
}

pkg_postinst() {
	elog "If you intend for os-prober to detect versions of Windows installed on"
	elog "NTFS-formatted partitions, your system must be capable of reading the"
	elog "NTFS filesystem. One way to do this is by installing sys-fs/ntfs3g"
}