[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.1.6.ebuild ChangeLog freeipmi-1.1.4.ebuild freeipmi-1.1.1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.1.6.ebuild ChangeLog freeipmi-1.1.4.ebuild freeipmi-1.1.1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/06/29 13:46:41

  Modified:             ChangeLog
  Added:                freeipmi-1.1.6.ebuild
  Removed:              freeipmi-1.1.4.ebuild freeipmi-1.1.1.ebuild
  Log:
  Version bump; remove old non-stable candidates.
  
  (Portage version: 2.2.0_alpha113/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 sys-libs/freeipmi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	17 May 2012 23:52:30 -0000	1.48
+++ ChangeLog	29 Jun 2012 13:46:41 -0000	1.49
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/freeipmi
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.48 2012/05/17 23:52:30 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.49 2012/06/29 13:46:41 flameeyes Exp $
+
+*freeipmi-1.1.6 (29 Jun 2012)
+
+  29 Jun 2012; Diego E. Pettenò <flameeyes@gentoo.org> +freeipmi-1.1.6.ebuild,
+  -freeipmi-1.1.1.ebuild, -freeipmi-1.1.4.ebuild:
+  Version bump; remove old non-stable candidates.
 
 *freeipmi-1.1.5 (17 May 2012)
 
@@ -262,4 +268,3 @@
   25 Mar 2005; Robin H. Johnson <robbat2@gentoo.org> +metadata.xml,
   +freeipmi-0.1.3.ebuild:
   Initial commit. Ebuild by Robin H. Johnson <robbat2@gentoo.org>.
-



1.1                  sys-libs/freeipmi/freeipmi-1.1.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.1.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.1.6.ebuild?rev=1.1&content-type=text/plain

Index: freeipmi-1.1.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.1.6.ebuild,v 1.1 2012/06/29 13:46:41 flameeyes Exp $

EAPI=4

inherit autotools eutils

DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
HOMEPAGE="http://www.gnu.org/software/freeipmi/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz
	http://ftp.gluster.com/pub/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="dev-libs/libgcrypt"
DEPEND="${RDEPEND}
		virtual/os-headers"
RDEPEND="${RDEPEND}
	sys-apps/openrc"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.1.1-strictaliasing.patch

	AT_M4DIR="config" eautoreconf
}

src_configure() {
	econf \
		$(use_enable debug) \
		--disable-dependency-tracking \
		--enable-fast-install \
		--disable-static \
		--disable-init-scripts \
		--enable-logrotate-config \
		--localstatedir=/var
}

# There are no tests
src_test() { :; }

src_install() {
	emake DESTDIR="${D}" docdir="/usr/share/doc/${PF}" install || die "emake install failed"
	find "${D}" -name '*.la' -delete

	# freeipmi by defaults install _all_ commands to /usr/sbin, but
	# quite a few can be run remotely as standard user, so move them
	# in /usr/bin afterwards.
	dodir /usr/bin
	for file in ipmi{detect,ping,power,console}; do
		mv "${D}"/usr/{s,}bin/${file} || die

		# The default install symlinks these commands to add a dash
		# after the ipmi prefix; we repeat those after move for
		# consistency.
		rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
		dosym ${file} /usr/bin/${file/ipmi/ipmi-}
	done

	dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt

	keepdir \
		/var/cache/ipmimonitoringsdrcache \
		/var/lib/freeipmi \
		/var/log/{freeipmi,ipmiconsole}

	newinitd "${FILESDIR}"/ipmidetectd.initd.3 ipmidetectd

	newinitd "${FILESDIR}"/bmc-watchdog.initd.3 bmc-watchdog
	newconfd "${FILESDIR}"/bmc-watchdog.confd bmc-watchdog
}