[gentoo-commits] gentoo-x86 commit in www-apps/davical: davical-1.1.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in www-apps/davical: davical-1.1.0.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     12/06/26 09:39:33

  Modified:             ChangeLog
  Added:                davical-1.1.0.ebuild
  Log:
  Bump for #423603
  
  (Portage version: 2.2.0_alpha113/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  www-apps/davical/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/davical/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/davical/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/davical/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/davical/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	14 Mar 2012 06:46:26 -0000	1.1
+++ ChangeLog	26 Jun 2012 09:39:33 -0000	1.2
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/davical
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/davical/ChangeLog,v 1.1 2012/03/14 06:46:26 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/davical/ChangeLog,v 1.2 2012/06/26 09:39:33 patrick Exp $
+
+*davical-1.1.0 (26 Jun 2012)
+
+  26 Jun 2012; Patrick Lauer <patrick@gentoo.org> +davical-1.1.0.ebuild:
+  Bump for #423603
 
   12 Mar 2012; lebarjack <francois.perichon@univ-lille2.fr>
   -davical-1.0.2.ebuild, +davical-1.0.2-r1.ebuild:
@@ -135,4 +140,3 @@
   +davical-0.9.5.ebuild, +files/postinstall-en-0.9.5.txt,
   +files/driver_ldap.patch, +files/rscds.conf, +metadata.xml:
   New ebuild for bug 195118 - (initial work by Cory Coager <ccoager@gmail.com>)
-



1.1                  www-apps/davical/davical-1.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/davical/davical-1.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/davical/davical-1.1.0.ebuild?rev=1.1&content-type=text/plain

Index: davical-1.1.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/davical/davical-1.1.0.ebuild,v 1.1 2012/06/26 09:39:33 patrick Exp $

EAPI=2

inherit depend.php webapp

DESCRIPTION="A CalDAV and CardDAV Server"
HOMEPAGE="http://davical.org/"
SRC_URI="http://debian.mcmillan.net.nz/packages/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

DEPEND="doc? ( dev-php/PEAR-PhpDocumentor )"
RDEPEND="app-admin/pwgen
	dev-lang/php[calendar,curl,pdo,postgres,xml]
	dev-perl/DBI
	dev-perl/DBD-Pg
	dev-perl/yaml
	>=dev-php/awl-0.51
	www-servers/apache"

need_php5
need_httpd

src_prepare() {
	epatch "${FILESDIR}/awl_location.patch"
	epatch "${FILESDIR}/inc_path.patch"
}

src_compile() {
	if use doc ; then
		einfo "Generating documentation"
		phpdoc -q -c "docs/api/phpdoc.ini"\
			|| die "Documentation failed to build"
	fi
	emake built-po || die "emake failed"
}

src_install() {
	webapp_src_preinst

	dodoc-php INSTALL README debian/README.Debian \
		testing/README.regression_tests TODO debian/changelog \
		|| die "dodoc failed"

	einfo "Installing web files"
	insinto "${MY_HTDOCSDIR}"
	doins -r htdocs/* htdocs/.htaccess || die "doins failed"

	einfo "Installing main files and i18n"
	insinto "${MY_HOSTROOTDIR}/${PN}"
	doins -r inc locale || die "doins failed"
	rm "${D}/${MY_HOSTROOTDIR}/${PN}/inc/always.php.in" || die

	einfo "Installing sql files"
	insinto "${MY_SQLSCRIPTSDIR}"
	doins -r dba/* || die "doins failed"

	if use doc ; then
		einfo "Installing documentation"
		dohtml -r docs/api/ docs/website/ || die "dohtml failed"
	fi

	insinto /etc/${PN}
	doins config/* "${FILESDIR}/vhost-example" \
		|| die "newins failed"

	webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"
	webapp_src_install

	fperms +x "${MY_SQLSCRIPTSDIR}/create-database.sh"
	fperms +x "${MY_SQLSCRIPTSDIR}/update-davical-database"
}