[gentoo-commits] gentoo-x86 commit in media-libs/libcanberra: ChangeLog libcanberra-0.29.ebuild

["Alexandre Rostovtsev (tetromino)" <tetromino@gentoo.org>]

tetromino    12/06/25 05:07:50

  Modified:             ChangeLog
  Added:                libcanberra-0.29.ebuild
  Log:
  Version bump with a few bugfixes. No longer uses gconf, meaning that gnome-settings-daemon-2.x will no longer automatically load the canberra gtk modules. Install devhelp docs in /usr/share/gtk-doc where devhelp expects to find them.
  
  (Portage version: 2.2.0_alpha112/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 media-libs/libcanberra/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	2 Jun 2012 12:21:29 -0000	1.82
+++ ChangeLog	25 Jun 2012 05:07:50 -0000	1.83
@@ -1,6 +1,15 @@
 # ChangeLog for media-libs/libcanberra
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.82 2012/06/02 12:21:29 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/ChangeLog,v 1.83 2012/06/25 05:07:50 tetromino Exp $
+
+*libcanberra-0.29 (25 Jun 2012)
+
+  25 Jun 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +libcanberra-0.29.ebuild:
+  Version bump with a few bugfixes. No longer uses gconf, meaning that
+  gnome-settings-daemon-2.x will no longer automatically load the canberra gtk
+  modules. Install devhelp docs in /usr/share/gtk-doc where devhelp expects to
+  find them.
 
   02 Jun 2012; Anthony G. Basile <blueness@gentoo.org>
   libcanberra-0.28-r5.ebuild:



1.1                  media-libs/libcanberra/libcanberra-0.29.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.29.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libcanberra/libcanberra-0.29.ebuild?rev=1.1&content-type=text/plain

Index: libcanberra-0.29.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libcanberra/libcanberra-0.29.ebuild,v 1.1 2012/06/25 05:07:50 tetromino Exp $

EAPI="4"

inherit libtool systemd autotools eutils

DESCRIPTION="Portable Sound Event Library"
HOMEPAGE="http://0pointer.de/lennart/projects/libcanberra/"
SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="alsa gnome gstreamer +gtk +gtk3 oss pulseaudio +sound tdb udev"

COMMON_DEPEND="media-libs/libvorbis
	>=sys-devel/libtool-2.2.6b
	alsa? (
		media-libs/alsa-lib
		udev? ( >=sys-fs/udev-160 ) )
	gstreamer? ( >=media-libs/gstreamer-0.10.15 )
	gtk? ( >=x11-libs/gtk+-2.20.0:2 )
	gtk3? ( x11-libs/gtk+:3 )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.11 )
	tdb? ( sys-libs/tdb )
"
RDEPEND="${COMMON_DEPEND}
	gnome? ( gnome-base/gsettings-desktop-schemas )
	sound? ( x11-themes/sound-theme-freedesktop )" # Required for index.theme wrt #323379
DEPEND="${COMMON_DEPEND}
	app-arch/xz-utils
	virtual/pkgconfig"

REQUIRED_USE="udev? ( alsa )"

src_prepare() {
	# https://bugs.freedesktop.org/show_bug.cgi?id=31454
	epatch "${FILESDIR}"/${PN}-0.28-underlinking.patch

	eautoreconf
}

src_configure() {
	econf \
		--docdir=/usr/share/doc/${PF} \
		--disable-dependency-tracking \
		$(use_enable alsa) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable gstreamer) \
		$(use_enable gtk) \
		$(use_enable gtk3) \
		$(use_enable tdb) \
		$(use_enable udev) \
		$(systemd_with_unitdir) \
		--disable-lynx \
		--disable-gtk-doc
}

src_install() {
	# Disable parallel installation until bug #253862 is solved
	emake -j1 DESTDIR="${D}" install

	# Remove useless .la files:
	# libcanberra uses lt_dlopenext instead of ld_dlopen to load the modules,
	# which means that it will first try appending ".la" to the given filename
	# prefix; if that fails, it will append the module extension for the
	# current system and try that (".so" on Linux, ".bundle" on Darwin, ".dll"
	# on Windows, etc.).  Only if both fail will it return an error.
	find "${D}" -name '*.la' -exec rm -f {} + || die "la file removal failed"
}