[gentoo-commits] gentoo-x86 commit in dev-libs/nspr: nspr-4.9.1-r2.ebuild ChangeLog nspr-4.9.1-r1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-libs/nspr: nspr-4.9.1-r2.ebuild ChangeLog nspr-4.9.1-r1.ebuild

[Jory Pratt (anarchy)]

anarchy     12/06/24 03:56:49

  Modified:             ChangeLog
  Added:                nspr-4.9.1-r2.ebuild
  Removed:              nspr-4.9.1-r1.ebuild
  Log:
  Fix undefined references on x32
  
  (Portage version: 2.1.11.1/cvs/Linux x86_64)

Revision  Changes    Path
1.191                dev-libs/nspr/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?rev=1.191&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?rev=1.191&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/ChangeLog?r1=1.190&r2=1.191

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v
retrieving revision 1.190
retrieving revision 1.191
diff -u -r1.190 -r1.191
--- ChangeLog	22 Jun 2012 02:57:33 -0000	1.190
+++ ChangeLog	24 Jun 2012 03:56:49 -0000	1.191
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/nspr
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v 1.190 2012/06/22 02:57:33 anarchy Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/ChangeLog,v 1.191 2012/06/24 03:56:49 anarchy Exp $
+
+*nspr-4.9.1-r2 (24 Jun 2012)
+
+  24 Jun 2012; Jory A. Pratt <anarchy@gentoo.org> -nspr-4.9.1-r1.ebuild,
+  +nspr-4.9.1-r2.ebuild, +files/nspr-4.9.1-x32_v0.1.patch,
+  -files/nspr-4.9.1-x32.patch:
+  Fix undefined references for x32
 
 *nspr-4.9.1-r1 (22 Jun 2012)
 



1.1                  dev-libs/nspr/nspr-4.9.1-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/nspr-4.9.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/nspr/nspr-4.9.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: nspr-4.9.1-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/nspr/nspr-4.9.1-r2.ebuild,v 1.1 2012/06/24 03:56:49 anarchy Exp $

EAPI=3
WANT_AUTOCONF="2.1"

inherit autotools eutils multilib toolchain-funcs versionator

MIN_PV="$(get_version_component_range 2)"

DESCRIPTION="Netscape Portable Runtime"
HOMEPAGE="http://www.mozilla.org/projects/nspr/"
SRC_URI="ftp://ftp.mozilla.org/pub/mozilla.org/nspr/releases/v${PV}/src/${P}.tar.gz"

LICENSE="|| ( MPL-1.1 GPL-2 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="debug"

src_prepare() {
	mkdir build inst
	epatch "${FILESDIR}"/${PN}-4.8-config.patch
	epatch "${FILESDIR}"/${PN}-4.6.1-config-1.patch
	epatch "${FILESDIR}"/${PN}-4.6.1-lang.patch
	epatch "${FILESDIR}"/${PN}-4.7.0-prtime.patch
	epatch "${FILESDIR}"/${PN}-4.7.1-solaris.patch
	epatch "${FILESDIR}"/${PN}-4.7.4-solaris.patch
	epatch "${FILESDIR}"/${PN}-4.8.3-aix-gcc.patch
	# Patch needs updating
	#epatch "${FILESDIR}"/${PN}-4.8.3-aix-soname.patch
	epatch "${FILESDIR}"/${PN}-4.8.4-darwin-install_name.patch
	epatch "${FILESDIR}"/${PN}-4.8.9-link-flags.patch
	epatch "${FILESDIR}"/${PN}-4.9.1-x32_v0.1.patch

	# We must run eautoconf to regenerate configure
	cd "${S}"/mozilla/nsprpub
	eautoconf

	# make sure it won't find Perl out of Prefix
	sed -i -e "s/perl5//g" "${S}"/mozilla/nsprpub/configure || die

	# Respect LDFLAGS
	sed -i -e 's/\$(MKSHLIB) \$(OBJS)/\$(MKSHLIB) \$(LDFLAGS) \$(OBJS)/g' \
		"${S}"/mozilla/nsprpub/config/rules.mk || die
}

src_configure() {
	cd "${S}"/build

	echo > "${T}"/test.c
	$(tc-getCC) -c "${T}"/test.c -o "${T}"/test.o
	case $(scanelf -BF'%M' "${T}"/test.o)$(scanmacho -BF'%M' "${T}"/test.o) in
		ELFCLASS64*|POWERPC64*|X86_64*) myconf="${myconf} --enable-64bit";;
		ELFCLASS32*|POWERPC*|I386*|ARM*) ;;
		*) die "Failed to detect whether your arch is 64bits or 32bits, disable distcc if you're using it, please";;
	esac

	myconf="${myconf} --libdir=${EPREFIX}/usr/$(get_libdir)"

	LC_ALL="C" ECONF_SOURCE="../mozilla/nsprpub" econf \
		$(use_enable debug) \
		$(use_enable !debug optimize) \
		${myconf} || die "econf failed"
}

src_compile() {
	cd "${S}"/build
	if tc-is-cross-compiler; then
		emake CC="$(tc-getBUILD_CC)" CXX="$(tc-getBUILD_CXX)" \
			-C config nsinstall || die "failed to build"
		mv config/{,native-}nsinstall
		sed -s 's#/nsinstall$#/native-nsinstall#' -i config/autoconf.mk
		rm config/nsinstall.o
	fi
	emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" || die "failed to build"
}

src_install () {
	# Their build system is royally confusing, as usual
	MINOR_VERSION=${MIN_PV} # Used for .so version
	cd "${S}"/build
	emake DESTDIR="${D}" install || die "emake install failed"

	cd "${ED}"/usr/$(get_libdir)
	for file in *.a; do
		einfo "removing static libraries as upstream has requested!"
		rm -f ${file} || die "failed to remove static libraries."
	done

	local n=
	# aix-soname.patch does this already
	[[ ${CHOST} == *-aix* ]] ||
	for file in *$(get_libname); do
		n=${file%$(get_libname)}$(get_libname ${MINOR_VERSION})
		mv ${file} ${n} || die "failed to mv files around"
		ln -s ${n} ${file} || die "failed to symlink files."
		if [[ ${CHOST} == *-darwin* ]]; then
			install_name_tool -id "${EPREFIX}/usr/$(get_libdir)/${n}" ${n} || die
		fi
	done

	# install nspr-config
	dobin "${S}"/build/config/nspr-config || die "failed to install nspr-config"

	# Remove stupid files in /usr/bin
	rm -f "${ED}"/usr/bin/prerr.properties || die "failed to cleanup unneeded files"
}