[gentoo-commits] gentoo-x86 commit in www-apps/egroupware: metadata.xml egroupware-1.8.004.20120613.ebuild ChangeLog egroupware-1.6.001.ebuild

[gentoo-commits] gentoo-x86 commit in www-apps/egroupware: metadata.xml egroupware-1.8.004.20120613.ebuild ChangeLog egroupware-1.6.001.ebuild

[Matti Bickel (mabi)]

mabi        12/06/23 15:25:36

  Modified:             metadata.xml ChangeLog
  Added:                egroupware-1.8.004.20120613.ebuild
  Removed:              egroupware-1.6.001.ebuild
  Log:
  version bump. remove old ebuild b/c of security bugs (see bug #284536). jpgraph check adapted from bug #342003
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  www-apps/egroupware/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/egroupware/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	24 Jan 2009 10:02:49 -0000	1.5
+++ metadata.xml	23 Jun 2012 15:25:36 -0000	1.6
@@ -3,9 +3,7 @@
 <pkgmetadata>
 	<herd>web-apps</herd>
 	<use>
-		<flag name='jpgraph'>Add <pkg>dev-php5/jpgraph</pkg> support</flag>
-		<flag name='mydms'>Install eGroupware-MyDMS</flag>
-		<flag name='icalsrv'>Install iCal Server (eGroupware-iCalSrv)</flag>
+		<flag name='jpgraph'>Add <pkg>dev-php/jpgraph</pkg> support</flag>
 		<flag name='gallery'>Install gallery2 port for eGW</flag>
 	</use>
 </pkgmetadata>



1.100                www-apps/egroupware/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/ChangeLog?rev=1.100&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/ChangeLog?rev=1.100&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/ChangeLog?r1=1.99&r2=1.100

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v
retrieving revision 1.99
retrieving revision 1.100
diff -u -r1.99 -r1.100
--- ChangeLog	24 Jan 2009 10:02:49 -0000	1.99
+++ ChangeLog	23 Jun 2012 15:25:36 -0000	1.100
@@ -1,6 +1,14 @@
 # ChangeLog for www-apps/egroupware
-# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v 1.99 2009/01/24 10:02:49 pva Exp $
+# Copyright 2002-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/ChangeLog,v 1.100 2012/06/23 15:25:36 mabi Exp $
+
+*egroupware-1.8.004.20120613 (23 Jun 2012)
+
+  23 Jun 2012; Matti Bickel <mabi@gentoo.org>
+  +egroupware-1.8.004.20120613.ebuild, -egroupware-1.6.001.ebuild,
+  files/postinstall-en-1.2.txt, metadata.xml:
+  version bump. remove old ebuild b/c of security bugs (see bug #284536).
+  jpgraph check adapted from bug #342003
 
 *egroupware-1.6.001 (24 Jan 2009)
 



1.1                  www-apps/egroupware/egroupware-1.8.004.20120613.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/egroupware-1.8.004.20120613.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/egroupware/egroupware-1.8.004.20120613.ebuild?rev=1.1&content-type=text/plain

Index: egroupware-1.8.004.20120613.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/egroupware/egroupware-1.8.004.20120613.ebuild,v 1.1 2012/06/23 15:25:36 mabi Exp $

EAPI=4

inherit eutils webapp

MY_PN=eGroupware

DESCRIPTION="Web-based GroupWare suite"
HOMEPAGE="http://www.egroupware.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}.tar.bz2
	mirror://sourceforge/${PN}/${MY_PN}-egw-pear-${PV}.tar.bz2
	gallery? ( mirror://sourceforge/${PN}/${MY_PN}-gallery-${PV}.tar.bz2 )"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="+jpgraph ldap mysql postgres gallery"

# php deps taken from rpm spec
# you can use pdo to access almost anything but sqlite is specifically required
# for the calendar module
# jpgraph is only needed for the projectmanager module
RDEPEND="jpgraph? ( dev-php/jpgraph )
	dev-php/pear
	dev-php/PEAR-Auth_SASL
	virtual/httpd-php
	dev-lang/php[gd,imap,pdo,posix,session,sqlite,ssl,unicode,xml,zip,zlib,ldap?,mysql?,postgres?]
	virtual/cron"

REQUIRED_USE="|| ( mysql postgres )"

need_httpd_cgi

S=${WORKDIR}/${PN}

src_prepare() {
	esvn_clean

	if use jpgraph; then
		einfo "Fixing jpgraph location"
		MY_JPGRAPH_VERSION="$(best_version dev-php/jpgraph)"
		MY_JPGRAPH_VERSION="${MY_JPGRAPH_VERSION/'dev-php/jpgraph-'/}"
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph.php'|'/usr/share/php/jpgraph/jpgraph.php'|" \
			projectmanager/inc/class.projectmanager_ganttchart.inc.php || die "sed jpgraph failed"
		sed -i "s|EGW_SERVER_ROOT . '/../jpgraph/src/jpgraph_gantt.php'|'/usr/share/php/jpgraph/jpgraph_gantt.php'|" \
			projectmanager/inc/class.projectmanager_ganttchart.inc.php || die "sed jpgraph failed"
		sed -i "s|$jpgraph_path .= SEP.'jpgraph';|$jpgraph_path = dirname('/usr/share/php/jpgraph/jpgraph.php');|" \
			setup/check_install.php || die "sed jpgraph failed"
		sed -i "s|'unknown';|'${MY_JPGRAPH_VERSION}';\n         \$available = version_compare(\$version,\$min_version,'>=');|" \
			setup/check_install.php || die "sed jpgraph failed"
	fi
}

src_install() {
	webapp_src_preinst

	dodoc doc/rpm-build/egroupware.cron

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_serverowned "${MY_HTDOCSDIR}/phpgwapi/images"

	webapp_postinst_txt en "${FILESDIR}/postinstall-en-1.2.txt"
	webapp_src_install
}

pkg_postinst() {
	if use ldap; then
		elog "If you are using LDAP contacts/addressbook, please read the upgrade instructions at"
		elog "http://www.egroupware.org/index.php?page_name=wiki&wikipage=ManualSetupUpdate"
		elog "before running the egroupware setup"
	fi

	elog "A cronjob to run eGroupware's async services is available at"
	elog "/usr/share/doc/${P}"

	webapp_pkg_postinst
}