[gentoo-commits] gentoo-x86 commit in x11-misc/xnee: xnee-3.13.ebuild ChangeLog xnee-3.11.ebuild xnee-3.10.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/xnee: xnee-3.13.ebuild ChangeLog xnee-3.11.ebuild xnee-3.10.ebuild

[Michael Weber (xmw)]

xmw         12/06/07 15:38:50

  Modified:             ChangeLog
  Added:                xnee-3.13.ebuild
  Removed:              xnee-3.11.ebuild xnee-3.10.ebuild
  Log:
  Version bump (bug 415657 by df), remove old.
  
  (Portage version: 2.1.10.63/cvs/Linux x86_64)

Revision  Changes    Path
1.25                 x11-misc/xnee/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xnee/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xnee/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xnee/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xnee/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	5 May 2012 04:53:50 -0000	1.24
+++ ChangeLog	7 Jun 2012 15:38:50 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/xnee
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/ChangeLog,v 1.24 2012/05/05 04:53:50 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/ChangeLog,v 1.25 2012/06/07 15:38:50 xmw Exp $
+
+*xnee-3.13 (07 Jun 2012)
+
+  07 Jun 2012; Michael Weber <xmw@gentoo.org> +xnee-3.13.ebuild,
+  -xnee-3.10.ebuild, -xnee-3.11.ebuild:
+  Version bump (bug 415657 by df), remove old.
 
   05 May 2012; Jeff Horelick <jdhore@gentoo.org> xnee-3.10.ebuild,
   xnee-3.11.ebuild, xnee-3.12.ebuild:



1.1                  x11-misc/xnee/xnee-3.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xnee/xnee-3.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xnee/xnee-3.13.ebuild?rev=1.1&content-type=text/plain

Index: xnee-3.13.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/xnee-3.13.ebuild,v 1.1 2012/06/07 15:38:50 xmw Exp $

EAPI=4

inherit eutils

DESCRIPTION="Program suite to record, replay and distribute user actions."
HOMEPAGE="http://www.sandklef.com/xnee/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gnome static-libs xosd"

RDEPEND="
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	x11-libs/libXext
	x11-libs/libXi
	x11-libs/libXtst
	x11-libs/libxcb
	gnome? (
		x11-libs/gtk+:2
		>=gnome-base/libgnomeui-2
		>=gnome-base/gconf-2
	)
"
DEPEND="${RDEPEND}
	x11-proto/inputproto
	virtual/pkgconfig
	sys-devel/gettext
	gnome? ( || ( media-gfx/imagemagick[jpeg,png]
		media-gfx/graphicsmagick[imagemagick,jpeg,png] ) )"

# This needs RECORD extension from X.org server which isn't necessarily
# enabled. Xlib: extension "RECORD" missing on display ":0.0".
RESTRICT="test"

src_configure() {
	local myconf

	if use xosd; then
		myconf="--enable-xosd --enable-verbose --enable-buffer_verbose"
	else
		myconf="--disable-xosd --disable-verbose --disable-buffer_verbose"
	fi

	econf \
		$(use_enable gnome gui) \
		--disable-gnome-applet \
		$(use_enable static-libs static) \
		--enable-cli \
		--enable-lib \
		--disable-static-programs \
		${myconf}
}

src_test() {
	Xemake check
}

src_install() {
	default
	dodoc AUTHORS BUGS ChangeLog FAQ NEWS README TODO
	use gnome && make_desktop_entry gnee Gnee ${PN} "Utility;GTK"
	use static-libs || rm -f "${ED}"usr/lib*/lib*.la
}