public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in dev-python/ipython: ipython-0.12.1.ebuild ChangeLog
@ 2012-04-24 17:07 Sebastien Fabbro (bicatali)
  0 siblings, 0 replies; 2+ messages in thread
From: Sebastien Fabbro (bicatali) @ 2012-04-24 17:07 UTC (permalink / raw
  To: gentoo-commits

bicatali    12/04/24 17:07:42

  Modified:             ChangeLog
  Added:                ipython-0.12.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.56/cvs/Linux x86_64)

Revision  Changes    Path
1.91                 dev-python/ipython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.91&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.91&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?r1=1.90&r2=1.91

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v
retrieving revision 1.90
retrieving revision 1.91
diff -u -r1.90 -r1.91
--- ChangeLog	10 Mar 2012 19:57:27 -0000	1.90
+++ ChangeLog	24 Apr 2012 17:07:42 -0000	1.91
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/ipython
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.90 2012/03/10 19:57:27 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.91 2012/04/24 17:07:42 bicatali Exp $
+
+*ipython-0.12.1 (24 Apr 2012)
+
+  24 Apr 2012; Sébastien Fabbro <bicatali@gentoo.org> +ipython-0.12.1.ebuild:
+  Version bump
 
   10 Mar 2012; Ulrich Müller <ulm@gentoo.org> metadata.xml:
   Fix UTF-8 encoding of metadata.xml.



1.1                  dev-python/ipython/ipython-0.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild?rev=1.1&content-type=text/plain

Index: ipython-0.12.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild,v 1.1 2012/04/24 17:07:42 bicatali Exp $

EAPI=4

# python eclass cruft
PYTHON_USE_DEPEND="readline? sqlite?"
PYTHON_MODNAME="IPython"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.[45] *-jython"

inherit distutils elisp-common eutils virtualx

DESCRIPTION="Advanced interactive shell for Python"
HOMEPAGE="http://ipython.org/"
SRC_URI="http://archive.ipython.org/release/${PV}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc emacs examples matplotlib mongodb notebook qt4 readline +smp
	sqlite test wxwidgets"

CDEPEND="dev-python/decorator
	|| ( dev-python/argparse =dev-lang/python-2.7* >=dev-lang/python-3.2 )
	dev-python/pexpect
	dev-python/pyparsing
	dev-python/simplegeneric
	emacs? ( app-emacs/python-mode virtual/emacs )
	matplotlib? ( dev-python/matplotlib )
	mongodb? ( dev-python/pymongo )
	smp? ( dev-python/pyzmq )
	wxwidgets? ( dev-python/wxpython )"
RDEPEND="${CDEPEND}
	notebook? ( >=www-servers/tornado-2.1
			dev-python/pygments
			dev-python/pyzmq )
	qt4? ( || ( dev-python/PyQt4 dev-python/pyside )
			dev-python/pygments
			dev-python/pyzmq )"
DEPEND="${CDEPEND}
	test? ( dev-python/nose )"

src_prepare() {
	distutils_src_prepare
	epatch "${FILESDIR}"/${PN}-0.12-globalpath.patch

	# fix for gentoo python scripts
	sed -i \
		-e "/ipython_cmd/s/ipython3/ipython/g" \
		IPython/frontend/terminal/console/tests/test_console.py \
		IPython/lib/irunner.py \
		IPython/testing/tools.py || die

	sed -i \
		-e "s/find_scripts(True, suffix='3')/find_scripts(True)/" \
		setup3.py || die

	# failing tests
	sed -i \
		-e 's/test_smoketest_aimport/_&/' \
		-e 's/test_smoketest_autoreload/_&/' \
		 IPython/extensions/tests/test_autoreload.py || die
	sed -i \
		-e 's/test_pylab_import_all_disabled/_&/' \
		-e 's/test_pylab_import_all_enabled/_&/' \
		IPython/lib/tests/test_irunner_pylab_magic.py || die
	sed -i \
		-e '/test_startup_py/i\\@dec.known_failure_py3' \
		-e '/test_startup_ipy/i\\@dec.known_failure_py3' \
		IPython/core/tests/test_profile.py || die
	sed -i \
		-e '/test_tclass/i\\    @dec.known_failure_py3' \
		IPython/core/tests/test_run.py || die

	# installation directory for documentation
	sed -i \
		-e "/docdirbase  = pjoin/s/ipython/${PF}/" \
		-e "/pjoin(docdirbase,'manual')/s/manual/html/" \
		setupbase.py || die "sed failed"

	rm -rf docs/html/{.buildinfo,_sources,objects.inv} || die

	if ! use doc; then
		sed -i \
			-e "/(pjoin(docdirbase, 'extensions'), igridhelpfiles),/d" \
			-e 's/ + manual_files//' \
			setupbase.py || die
	fi

	if ! use examples; then
		sed -i \
			-e 's/+ example_files//' \
			setupbase.py || die
	fi
}

src_compile() {
	distutils_src_compile
	use emacs && elisp-compile docs/emacs/ipython.el
}

src_test() {
	if use mongodb; then
		mkdir -p "${T}/mongo.db"
		mongod --dbpath "${T}/mongo.db" --fork --logpath "${T}/mongo.log"
	fi

	testing() {
		"$(PYTHON)" setup.py \
			build -b "build-${PYTHON_ABI}" \
			install --root="${T}/tests-${PYTHON_ABI}" > /dev/null || die
		# Initialize ~/.ipython directory.
		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
			ipython <<< "" > /dev/null || return 1
		# Run tests (-v for more verbosity).
		PATH="${T}/tests-${PYTHON_ABI}${EPREFIX}/usr/bin:${PATH}" \
			PYTHONPATH="${T}/tests-${PYTHON_ABI}${EPREFIX}$(python_get_sitedir)" \
			iptest -v || return 1
	}
	VIRTUALX_COMMAND="python_execute_function" virtualmake testing

	use mongodb && killall -u "$(id -nu)" mongod
}

src_install() {
	distutils_src_install
	if use emacs; then
		pushd docs/emacs > /dev/null
		elisp-install ${PN} ${PN}.el*
		elisp-site-file-install "${FILESDIR}"/62ipython-gentoo.el
		popd > /dev/null
	fi
}

pkg_postinst() {
	distutils_pkg_postinst
	use emacs && elisp-site-regen
}

pkg_postrm() {
	distutils_pkg_postrm
	use emacs && elisp-site-regen
}






^ permalink raw reply	[flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-python/ipython: ipython-0.12.1.ebuild ChangeLog
@ 2012-06-06  5:17 Benda XU (heroxbd)
  0 siblings, 0 replies; 2+ messages in thread
From: Benda XU (heroxbd) @ 2012-06-06  5:17 UTC (permalink / raw
  To: gentoo-commits

heroxbd     12/06/06 05:17:02

  Modified:             ipython-0.12.1.ebuild ChangeLog
  Log:
  keyword ~amd64-linux and ~x86-linux
  
  (Portage version: 2.1.10.57/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  dev-python/ipython/ipython-0.12.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild?r1=1.1&r2=1.2

Index: ipython-0.12.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ipython-0.12.1.ebuild	24 Apr 2012 17:07:42 -0000	1.1
+++ ipython-0.12.1.ebuild	6 Jun 2012 05:17:02 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild,v 1.1 2012/04/24 17:07:42 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.1.ebuild,v 1.2 2012/06/06 05:17:02 heroxbd Exp $
 
 EAPI=4
 
@@ -18,7 +18,7 @@
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
 IUSE="doc emacs examples matplotlib mongodb notebook qt4 readline +smp
 	sqlite test wxwidgets"
 



1.92                 dev-python/ipython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/ipython/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	24 Apr 2012 17:07:42 -0000	1.91
+++ ChangeLog	6 Jun 2012 05:17:02 -0000	1.92
@@ -1,6 +1,9 @@
 # ChangeLog for dev-python/ipython
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.91 2012/04/24 17:07:42 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.92 2012/06/06 05:17:02 heroxbd Exp $
+
+  06 Jun 2012; Benda Xu <heroxbd@gentoo.org> ipython-0.12.1.ebuild:
+  keyword ~amd64-linux and ~x86-linux
 
 *ipython-0.12.1 (24 Apr 2012)
 






^ permalink raw reply	[flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-06-06  5:17 UTC | newest]

Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-06-06  5:17 [gentoo-commits] gentoo-x86 commit in dev-python/ipython: ipython-0.12.1.ebuild ChangeLog Benda XU (heroxbd)
  -- strict thread matches above, loose matches on Subject: below --
2012-04-24 17:07 Sebastien Fabbro (bicatali)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox