[gentoo-commits] gentoo-x86 commit in net-misc/bfgminer: bfgminer-2.4.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/bfgminer: bfgminer-2.4.2.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    12/06/03 15:32:32

  Modified:             ChangeLog
  Added:                bfgminer-2.4.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  net-misc/bfgminer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/bfgminer/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/bfgminer/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/bfgminer/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/bfgminer/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	22 May 2012 16:10:09 -0000	1.8
+++ ChangeLog	3 Jun 2012 15:32:32 -0000	1.9
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/bfgminer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/bfgminer/ChangeLog,v 1.8 2012/05/22 16:10:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/bfgminer/ChangeLog,v 1.9 2012/06/03 15:32:32 blueness Exp $
+
+*bfgminer-2.4.2 (03 Jun 2012)
+
+  03 Jun 2012; Anthony G. Basile <blueness@gentoo.org> +bfgminer-2.4.2.ebuild:
+  Version bump
 
   22 May 2012; Samuli Suominen <ssuominen@gentoo.org> bfgminer-2.3.4.ebuild,
   bfgminer-2.3.5.ebuild, bfgminer-2.3.6.ebuild, bfgminer-2.4.0.ebuild,



1.1                  net-misc/bfgminer/bfgminer-2.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/bfgminer/bfgminer-2.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/bfgminer/bfgminer-2.4.2.ebuild?rev=1.1&content-type=text/plain

Index: bfgminer-2.4.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/bfgminer/bfgminer-2.4.2.ebuild,v 1.1 2012/06/03 15:32:32 blueness Exp $

EAPI="4"

inherit eutils

DESCRIPTION="Modular Bitcoin CPU/GPU/FPGA miner in C"
HOMEPAGE="https://bitcointalk.org/index.php?topic=78192.0"
SRC_URI="http://luke.dashjr.org/programs/bitcoin/files/${PN}/${PV}/${P}.tbz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"

IUSE="+adl altivec bitforce +cpumining examples hardened icarus ncurses +opencl padlock sse2 sse2_4way sse4 +udev ztex"
REQUIRED_USE="
	|| ( bitforce cpumining icarus opencl ztex )
	adl? ( opencl )
	altivec? ( cpumining ppc ppc64 )
	padlock? ( cpumining || ( amd64 x86 ) )
	sse2? ( cpumining || ( amd64 x86 ) )
	sse4? ( cpumining amd64 )
"

DEPEND="
	net-misc/curl
	ncurses? (
		sys-libs/ncurses
	)
	dev-libs/jansson
	udev? (
		sys-fs/udev
	)
	ztex? (
		virtual/libusb:1
	)
"
RDEPEND="${DEPEND}"
DEPEND="${DEPEND}
	virtual/pkgconfig
	sys-apps/sed
	adl? (
		x11-libs/amd-adl-sdk
	)
	opencl? (
		virtual/opencl
	)
	sse2? (
		>=dev-lang/yasm-1.0.1
	)
	sse4? (
		>=dev-lang/yasm-1.0.1
	)
"

src_prepare() {
	sed -i 's/\(^\#define WANT_.*\(SSE\|PADLOCK\|ALTIVEC\)\)/\/\/ \1/' miner.h
	ln -s /usr/include/ADL/* ADL_SDK/
}

src_configure() {
	local CFLAGS="${CFLAGS}"
	if ! use altivec; then
		sed -i 's/-faltivec//g' configure
	else
		CFLAGS="${CFLAGS} -DWANT_ALTIVEC=1"
	fi
	use padlock && CFLAGS="${CFLAGS} -DWANT_VIA_PADLOCK=1"
	if use sse2; then
		if use amd64; then
			CFLAGS="${CFLAGS} -DWANT_X8664_SSE2=1"
		else
			CFLAGS="${CFLAGS} -DWANT_X8632_SSE2=1"
		fi
	fi
	use sse2_4way && CFLAGS="${CFLAGS} -DWANT_SSE2_4WAY=1"
	use sse4 && CFLAGS="${CFLAGS} -DWANT_X8664_SSE4=1"
	use hardened && CFLAGS="${CFLAGS} -nopie"

	CFLAGS="${CFLAGS}" \
	econf \
		$(use_enable adl) \
		$(use_enable bitforce) \
		$(use_enable cpumining) \
		$(use_enable icarus) \
		$(use_with ncurses curses) \
		$(use_enable opencl) \
		$(use_with udev libudev) \
		$(use_enable ztex)
	if use opencl; then
		# sanitize directories
		sed -i 's~^\(\#define CGMINER_PREFIX \).*$~\1"'"${EPREFIX}/usr/lib/bfgminer/opencl"'"~' config.h
	fi
	if use ztex; then
		sed -i 's~bitstreams/~'"${EPREFIX}"'/usr/lib/bfgminer/ztex/~' libztex.c
	fi
}

src_install() {
	dobin bfgminer
	dodoc AUTHORS NEWS README API-README
	if use icarus; then
		dodoc FPGA-README
	fi
	if use opencl; then
		insinto /usr/lib/bfgminer/opencl
		doins *.cl
	fi
	if use ztex; then
		insinto /usr/lib/bfgminer/ztex
		doins bitstreams/*.bit
	fi
	if use examples; then
		docinto examples
		dodoc api-example.php miner.php API.java api-example.c
	fi
}