[gentoo-commits] gentoo-x86 commit in sci-libs/geos: geos-3.3.3.ebuild ChangeLog geos-3.3.2.ebuild

[gentoo-commits] gentoo-x86 commit in sci-libs/geos: geos-3.3.3.ebuild ChangeLog geos-3.3.2.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    12/05/24 16:25:05

  Modified:             ChangeLog
  Added:                geos-3.3.3.ebuild
  Removed:              geos-3.3.2.ebuild
  Log:
  Version bump to version 3.3.3.
  
  (Portage version: 2.2.0_alpha107/cvs/Linux x86_64)

Revision  Changes    Path
1.63                 sci-libs/geos/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	6 May 2012 17:45:16 -0000	1.62
+++ ChangeLog	24 May 2012 16:25:05 -0000	1.63
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/geos
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v 1.62 2012/05/06 17:45:16 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/ChangeLog,v 1.63 2012/05/24 16:25:05 scarabeus Exp $
+
+*geos-3.3.3 (24 May 2012)
+
+  24 May 2012; Tomáš Chvátal <scarabeus@gentoo.org> +geos-3.3.3.ebuild,
+  -geos-3.3.2.ebuild:
+  Version bump to version 3.3.3.
 
   06 May 2012; Fabian Groffen <grobian@gentoo.org>
   +files/3.3.2-solaris-isnan.patch, geos-3.3.2.ebuild:



1.1                  sci-libs/geos/geos-3.3.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/geos-3.3.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/geos/geos-3.3.3.ebuild?rev=1.1&content-type=text/plain

Index: geos-3.3.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/geos/geos-3.3.3.ebuild,v 1.1 2012/05/24 16:25:05 scarabeus Exp $

EAPI=4

PYTHON_DEPEND="python? 2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"
inherit autotools eutils python

DESCRIPTION="Geometry engine library for Geographic Information Systems"
HOMEPAGE="http://trac.osgeo.org/geos/"
SRC_URI="http://download.osgeo.org/geos/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x64-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="doc php python ruby static-libs"

RDEPEND="php? ( dev-lang/php:5.3 )
	ruby? ( dev-lang/ruby )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	php? ( dev-lang/swig )
	python? ( dev-lang/swig )
	ruby? ( dev-lang/swig )"

pkg_setup() {
	use python && python_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/3.2.0-python.patch \
		"${FILESDIR}"/3.2.0-darwin.patch \
		"${FILESDIR}"/3.3.2-solaris-isnan.patch
	eautoreconf
	echo "#!${EPREFIX}/bin/bash" > py-compile
}

src_configure() {
	econf \
		$(use_enable python) \
		$(use_enable ruby) \
		$(use_enable php) \
		$(use_enable static-libs static)
}

src_compile() {
	emake
	if use python; then
		emake -C swig/python clean
		python_copy_sources swig/python
		building() {
			emake \
				PYTHON_CPPFLAGS="-I${EPREFIX}$(python_get_includedir)" \
				PYTHON_LDFLAGS="$(python_get_library -l)" \
				SWIG_PYTHON_CPPFLAGS="-I${EPREFIX}$(python_get_includedir)" \
				pyexecdir="${EPREFIX}$(python_get_sitedir)" \
				pythondir="${EPREFIX}$(python_get_sitedir)"
		}
		python_execute_function -s --source-dir swig/python building
	fi
	use doc && emake -C "${S}/doc" doxygen-html
}

src_install() {
	default
	if use python; then
		installation() {
			emake \
				DESTDIR="${D}" \
				pyexecdir="${EPREFIX}$(python_get_sitedir)" \
				pythondir="${EPREFIX}$(python_get_sitedir)" \
				install
		}
		python_execute_function -s --source-dir swig/python installation
		python_clean_installation_image
	fi
	use doc && dohtml -r "${S}/doc" doxygen_docs/html/*
	find "${ED}" -name '*.la' -exec rm -f {} +
}

pkg_postinst() {
	use python && python_mod_optimize geos/geos.py
}

pkg_postrm() {
	use python && python_mod_cleanup geos/geos.py
}