* [gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: gpsd-3.6.ebuild ChangeLog
@ 2012-05-23 14:20 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2012-05-23 14:20 UTC (permalink / raw
To: gentoo-commits
vapier 12/05/23 14:20:01
Modified: ChangeLog
Added: gpsd-3.6.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha102/cvs/Linux x86_64)
Revision Changes Path
1.86 sci-geosciences/gpsd/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/ChangeLog?r1=1.85&r2=1.86
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog 21 May 2012 22:37:12 -0000 1.85
+++ ChangeLog 23 May 2012 14:20:01 -0000 1.86
@@ -1,6 +1,12 @@
# ChangeLog for sci-geosciences/gpsd
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.85 2012/05/21 22:37:12 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/ChangeLog,v 1.86 2012/05/23 14:20:01 vapier Exp $
+
+*gpsd-3.6 (23 May 2012)
+
+ 23 May 2012; Mike Frysinger <vapier@gentoo.org> +files/gpsd-3.6-debug.patch,
+ +files/gpsd-3.6-rpath.patch, +gpsd-3.6.ebuild:
+ Version bump.
*gpsd-3.5 (21 May 2012)
1.1 sci-geosciences/gpsd/gpsd-3.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-3.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-geosciences/gpsd/gpsd-3.6.ebuild?rev=1.1&content-type=text/plain
Index: gpsd-3.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-geosciences/gpsd/gpsd-3.6.ebuild,v 1.1 2012/05/23 14:20:01 vapier Exp $
EAPI="4"
PYTHON_DEPEND="python? 2:2.6"
RESTRICT_PYTHON_ABIS="3.*"
SUPPORT_PYTHON_ABIS="1"
SCONS_MIN_VERSION="1.2.1"
inherit eutils user multilib distutils scons-utils toolchain-funcs
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://git.savannah.nongnu.org/gpsd.git"
inherit git-2
else
SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="GPS daemon and library to support USB/serial GPS devices and various GPS/mapping clients"
HOMEPAGE="http://catb.org/gpsd/"
LICENSE="BSD"
SLOT="0"
GPSD_PROTOCOLS=(
ashtech aivdm clientdebug earthmate evermore fv18 garmin
garmintxt gpsclock itrax mtk3301 nmea ntrip navcom oceanserver
oldstyle oncore rtcm104v2 rtcm104v3 sirf superstar2 timing tsip
tripmate tnt ubx
)
IUSE_GPSD_PROTOCOLS=${GPSD_PROTOCOLS[@]/#/gpsd_protocols_}
IUSE="${IUSE_GPSD_PROTOCOLS} bluetooth cxx debug dbus ipv6 ncurses ntp python qt4 +shm +sockets test udev usb X"
REQUIRED_USE="X? ( python )"
RDEPEND="X? ( dev-python/pygtk:2 )
ncurses? ( sys-libs/ncurses )
bluetooth? ( net-wireless/bluez )
usb? ( virtual/libusb:1 )
dbus? (
sys-apps/dbus
dev-libs/dbus-glib
)
ntp? ( net-misc/ntp )
qt4? ( x11-libs/qt-gui )"
DEPEND="${RDEPEND}
test? ( sys-devel/bc )"
# xml packages are for man page generation
if [[ ${PV} == "9999" ]] ; then
DEPEND+="
app-text/xmlto
=app-text/docbook-xml-dtd-4.1*"
fi
pkg_setup() {
use python && python_pkg_setup
}
src_prepare() {
epatch "${FILESDIR}"/${PN}-3.3-ldflags.patch
epatch "${FILESDIR}"/${PN}-3.4-always-install-man-pages.patch
epatch "${FILESDIR}"/${PN}-3.4-no-man-gen.patch
epatch "${FILESDIR}"/${PN}-3.6-debug.patch
epatch "${FILESDIR}"/${PN}-3.6-rpath.patch
# Avoid useless -L paths to the install dir
sed -i \
-e '/^env.Prepend(LIBPATH=.installdir(.libdir.).)$/d' \
-e 's:\<STAGING_PREFIX\>:SYSROOT:g' \
SConstruct || die
# Extract python info out of SConstruct so we can use saner distribute
if use python ; then
pyvar() { sed -n "/^ *$1 *=/s:.*= *::p" SConstruct ; }
local pybins=$(pyvar python_progs)
local pysrcs=$(sed -n '/^ *python_extensions = {/,/}/{s:^ *::;s:os[.]sep:"/":g;p}' SConstruct)
local packet=$(python -c "${pysrcs}; print(python_extensions['gps/packet'])")
local client=$(python -c "${pysrcs}; print(python_extensions['gps/clienthelpers'])")
sed \
-e "s|@VERSION@|$(pyvar gpsd_version)|" \
-e "s|@URL@|$(pyvar website)|" \
-e "s|@EMAIL@|$(pyvar devmail)|" \
-e "s|@SCRIPTS@|${pybins}|" \
-e "s|@GPS_PACKET_SOURCES@|${packet}|" \
-e "s|@GPS_CLIENT_SOURCES@|${client}|" \
-e "s|@SCRIPTS@|$(pyvar python_progs)|" \
"${FILESDIR}"/${PN}-3.3-setup.py > setup.py || die
distutils_src_prepare
fi
}
src_configure() {
myesconsargs=(
prefix="${EPREFIX}/usr"
libdir="\$prefix/$(get_libdir)"
chrpath=False
gpsd_user=gpsd
gpsd_group=uucp
strip=False
python=False
$(use_scons bluetooth bluez)
$(use_scons cxx libgpsmm)
$(use_scons debug)
$(use_scons dbus dbus_export)
$(use_scons ipv6)
$(use_scons ncurses)
$(use_scons ntp ntpshm)
$(use_scons ntp pps)
$(use_scons shm shm_export)
$(use_scons sockets socket_export)
$(use_scons qt4 libQgpsmm)
$(use_scons usb)
)
# enable specified protocols
local protocol
for protocol in ${GPSD_PROTOCOLS[@]} ; do
myesconsargs+=( $(use_scons gpsd_protocols_${protocol} ${protocol}) )
done
}
src_compile() {
tc-export CC CXX PKG_CONFIG
export SHLINKFLAGS=${LDFLAGS} LINKFLAGS=${LDFLAGS}
escons
use python && distutils_src_compile
}
src_install() {
DESTDIR="${D}" escons install $(usex udev udev-install "")
newconfd "${FILESDIR}"/gpsd.conf-2 gpsd
newinitd "${FILESDIR}"/gpsd.init-2 gpsd
if use python ; then
distutils_src_install
# Delete all X related packages if user doesn't want them
if ! use X ; then
local p
for p in $(grep -Il 'import .*pygtk' *) ; do
find "${D}"/usr/bin -name "${p}*" -delete
done
fi
fi
}
pkg_preinst() {
# Run the gpsd daemon as gpsd and group uucp; create it here
# as it doesn't seem to be needed during compile/install ...
enewuser gpsd -1 -1 -1 "uucp"
}
pkg_postinst() {
use python && distutils_pkg_postinst
}
pkg_postrm() {
use python && distutils_pkg_postrm
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-05-23 14:20 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-05-23 14:20 [gentoo-commits] gentoo-x86 commit in sci-geosciences/gpsd: gpsd-3.6.ebuild ChangeLog Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox