[gentoo-commits] gentoo-x86 commit in sys-cluster/libqb: metadata.xml libqb-0.13.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-cluster/libqb: metadata.xml libqb-0.13.0.ebuild ChangeLog

[Kacper Kowalik (xarthisius)]

xarthisius    12/05/16 10:29:46

  Added:                metadata.xml libqb-0.13.0.ebuild ChangeLog
  Log:
  Initial import, ebuild written by me
  
  (Portage version: 2.2.0_alpha105/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sys-cluster/libqb/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>cluster</herd>
</pkgmetadata>



1.1                  sys-cluster/libqb/libqb-0.13.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/libqb-0.13.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/libqb-0.13.0.ebuild?rev=1.1&content-type=text/plain

Index: libqb-0.13.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/libqb/libqb-0.13.0.ebuild,v 1.1 2012/05/16 10:29:46 xarthisius Exp $

EAPI=4

AUTOTOOLS_AUTORECONF=1

inherit autotools-utils

DESCRIPTION="Library providing high performance logging, tracing, ipc, and poll"
HOMEPAGE="https://github.com/asalkeld/libqb"
SRC_URI="http://fedorahosted.org/releases/q/u/quarterback/${P}.tar.xz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc examples static-libs test"

RDEPEND="dev-libs/glib:2"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	test? ( dev-libs/check )
	doc? ( app-doc/doxygen[dot] )"

DOCS=(README.markdown ChangeLog)

src_prepare() {
	sed -e '/dist_doc_DATA/d' -i Makefile.am || die
	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(use_enable debug)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile
	use doc && autotools-utils_src_compile doxygen
}

src_install() {
	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/docs/html/")
	autotools-utils_src_install
	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*.c
	fi
}



1.1                  sys-cluster/libqb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/libqb/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sys-cluster/libqb
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/libqb/ChangeLog,v 1.1 2012/05/16 10:29:46 xarthisius Exp $

*libqb-0.13.0 (16 May 2012)

  16 May 2012; Kacper Kowalik <xarthisius@gentoo.org> +libqb-0.13.0.ebuild,
  +metadata.xml:
  Initial import, ebuild written by me