[gentoo-commits] gentoo-x86 commit in net-nntp/tin: tin-2.0.1.ebuild ChangeLog

["Jeroen Roovers (jer)" <jer@gentoo.org>]

jer         12/05/15 16:16:56

  Modified:             ChangeLog
  Added:                tin-2.0.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha105/cvs/Linux x86_64)

Revision  Changes    Path
1.33                 net-nntp/tin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/tin/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/tin/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/tin/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-nntp/tin/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	3 May 2012 04:32:51 -0000	1.32
+++ ChangeLog	15 May 2012 16:16:56 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for net-nntp/tin
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/ChangeLog,v 1.32 2012/05/03 04:32:51 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/ChangeLog,v 1.33 2012/05/15 16:16:56 jer Exp $
+
+*tin-2.0.1 (15 May 2012)
+
+  15 May 2012; Jeroen Roovers <jer@gentoo.org> +tin-2.0.1.ebuild:
+  Version bump.
 
   03 May 2012; Jeff Horelick <jdhore@gentoo.org> tin-2.0.0.ebuild:
   dev-util/pkgconfig -> virtual/pkgconfig



1.1                  net-nntp/tin/tin-2.0.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/tin/tin-2.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-nntp/tin/tin-2.0.1.ebuild?rev=1.1&content-type=text/plain

Index: tin-2.0.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/tin-2.0.1.ebuild,v 1.1 2012/05/15 16:16:56 jer Exp $

EAPI=4
inherit eutils toolchain-funcs versionator

DESCRIPTION="A threaded NNTP and spool based UseNet newsreader"
HOMEPAGE="http://www.tin.org/"
SRC_URI="ftp://ftp.tin.org/pub/news/clients/tin/v$(get_version_component_range 1-2)/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="cancel-locks debug doc +etiquette evil forgery gpg idn ipv6 mime nls sasl socks5 spell unicode"

RDEPEND="
	dev-libs/libpcre
	dev-libs/uulib
	gpg? ( app-crypt/gnupg )
	idn? ( net-dns/libidn )
	mime? ( net-mail/metamail )
	net-misc/urlview
	nls? ( sys-devel/gettext )
	sasl? ( virtual/gsasl )
	socks5? ( net-proxy/dante )
	sys-libs/ncurses[unicode?]
	unicode? ( dev-libs/icu )
"

DEPEND="
	${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	# Do not strip
	sed -i src/Makefile.in -e '388s|-s ||g' || die "sed src/Makefile.in failed"
}

src_configure() {
	if use evil || use cancel-locks; then
		sed -i -e"s/# -DEVIL_INSIDE/-DEVIL_INSIDE/" src/Makefile.in
	fi

	if use forgery
	then
		sed -i -e"s/^CPPFLAGS.*/& -DFORGERY/" src/Makefile.in
	fi

	local screen="ncurses"
	use unicode && screen="ncursesw"

	use etiquette || myconf="${myconf} --disable-etiquette"

	tc-export CC

	econf \
		--with-pcre=/usr \
		--enable-nntp-only \
		--enable-prototypes \
		--disable-echo \
		--disable-mime-strict-charset \
		--with-coffee  \
		--with-screen=${screen} \
		--with-nntp-default-server="${TIN_DEFAULT_SERVER:-${NNTPSERVER:-news.gmane.org}}" \
		$(use_enable ipv6) \
		$(use_enable debug) \
		$(use_enable gpg pgp-gpg) \
		$(use_enable nls) \
		$(use_enable cancel-locks) \
		$(use_with mime metamail /usr) \
		$(use_with spell ispell /usr) \
		$(use_with socks5 socks) $(use_with socks5) \
		${myconf}
}

src_compile() {
	emake build
}

src_install() {
	default

	# File collision?
	rm -f "${ED}"/usr/share/man/man5/{mbox,mmdf}.5

	dodoc doc/{CHANGES{,.old},CREDITS,TODO,WHATSNEW}
	use doc && dodoc doc/{*.sample,*.txt}

	insinto /etc/tin
	doins doc/tin.defaults
}