[gentoo-commits] gentoo-x86 commit in dev-db/mongodb: mongodb-2.0.5.ebuild ChangeLog mongodb-2.0.3.ebuild

[gentoo-commits] gentoo-x86 commit in dev-db/mongodb: mongodb-2.0.5.ebuild ChangeLog mongodb-2.0.3.ebuild

[Alexys Jacob (ultrabug)]

ultrabug    12/05/11 08:13:57

  Modified:             ChangeLog
  Added:                mongodb-2.0.5.ebuild
  Removed:              mongodb-2.0.3.ebuild
  Log:
  Version bump, generic mms-agent URL, drop old.
  
  (Portage version: 2.1.10.56/cvs/Linux x86_64)

Revision  Changes    Path
1.36                 dev-db/mongodb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	3 Apr 2012 08:48:00 -0000	1.35
+++ ChangeLog	11 May 2012 08:13:57 -0000	1.36
@@ -1,6 +1,12 @@
 # ChangeLog for dev-db/mongodb
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.35 2012/04/03 08:48:00 ultrabug Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/ChangeLog,v 1.36 2012/05/11 08:13:57 ultrabug Exp $
+
+*mongodb-2.0.5 (11 May 2012)
+
+  11 May 2012; Ultrabug <ultrabug@gentoo.org> -mongodb-2.0.3.ebuild,
+  -files/mongodb-2.0.3-fix-scons.patch, +mongodb-2.0.5.ebuild:
+  Version bump, generic mms-agent URL, drop old.
 
   03 Apr 2012; Ultrabug <ultrabug@gentoo.org> mongodb-2.0.4.ebuild:
   ebuild cleanup



1.1                  dev-db/mongodb/mongodb-2.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mongodb/mongodb-2.0.5.ebuild?rev=1.1&content-type=text/plain

Index: mongodb-2.0.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mongodb/mongodb-2.0.5.ebuild,v 1.1 2012/05/11 08:13:57 ultrabug Exp $

EAPI=4
SCONS_MIN_VERSION="1.2.0"

inherit eutils multilib pax-utils scons-utils versionator

MY_P=${PN}-src-r${PV/_rc/-rc}

DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
HOMEPAGE="http://www.mongodb.org"
SRC_URI="http://downloads.mongodb.org/src/${MY_P}.tar.gz
	mms-agent? ( https://mms.10gen.com/settings/10gen-mms-agent.zip )"

LICENSE="AGPL-3 Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mms-agent static-libs v8"

PDEPEND="mms-agent? ( dev-python/pymongo )"
RDEPEND="!v8? ( <dev-lang/spidermonkey-1.8[unicode] )
	v8? ( dev-lang/v8 )
	dev-libs/boost
	dev-libs/libpcre[cxx]
	net-libs/libpcap
	app-arch/snappy
	"
DEPEND="${RDEPEND}
	sys-libs/readline
	sys-libs/ncurses"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	enewgroup mongodb
	enewuser mongodb -1 -1 /var/lib/${PN} mongodb

	scons_opts=" --cxx=$(tc-getCXX) --use-system-all --sharedclient"
	if use v8; then
		scons_opts+=" --usev8"
	else
		scons_opts+=" --usesm"
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-2.0-fix-scons.patch"

	# drop -Werror
	sed -i -e '/Werror/d' SConstruct || die

	sed -i -e "s@jsapi.h@js/jsapi.h@g" \
		-e "s@jsobj.h@js/jsobj.h@g" \
		-e "s@jsdate.h@js/jsdate.h@g" \
		-e "s@jsregexp.h@js/jsregexp.h@g" scripting/engine_spidermonkey.h || die
}

src_compile() {
	escons ${scons_opts} all
}

src_install() {
	escons ${scons_opts} --full --nostrip install --prefix="${D}"/usr

	use static-libs || rm "${D}/usr/$(get_libdir)/libmongoclient.a"

	use v8 && pax-mark m "${D}"/usr/bin/{mongo,mongod}

	for x in /var/{lib,log,run}/${PN}; do
		keepdir "${x}"
		fowners mongodb:mongodb "${x}"
	done

	doman debian/mongo*.1
	dodoc README docs/building.md

	newinitd "${FILESDIR}/${PN}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}.confd" ${PN}
	newinitd "${FILESDIR}/${PN/db/s}.initd" ${PN/db/s}
	newconfd "${FILESDIR}/${PN/db/s}.confd" ${PN/db/s}

	if use mms-agent; then
		local MY_PN="mms-agent"
		local MY_D="/opt/${MY_PN}"
		insinto ${MY_D}
		doins "${WORKDIR}/${MY_PN}/"*
		fowners -R mongodb:mongodb ${MY_D}
		newinitd "${FILESDIR}/${MY_PN}.initd" ${MY_PN}
		newconfd "${FILESDIR}/${MY_PN}.confd" ${MY_PN}
	fi
}

src_test() {
	escons ${scons_opts} test
	"${S}"/test --dbpath=unittest || die
}

pkg_postinst() {
	if [[ ${REPLACING_VERSIONS} < 1.8 ]]; then
		ewarn "You just upgraded from a previous version of mongodb !"
		ewarn "Make sure you run 'mongod --upgrade' before using this version."
	fi
	elog "Journaling is now enabled by default, see /etc/conf.d/${PN}"
}