[gentoo-commits] gentoo-x86 commit in media-sound/mpg123: ChangeLog mpg123-1.14.1.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/mpg123: ChangeLog mpg123-1.14.1.ebuild

[Tim Harder (radhermit)]

radhermit    12/05/08 08:11:10

  Modified:             ChangeLog
  Added:                mpg123-1.14.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.256                media-sound/mpg123/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.256&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?rev=1.256&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/ChangeLog?r1=1.255&r2=1.256

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v
retrieving revision 1.255
retrieving revision 1.256
diff -u -r1.255 -r1.256
--- ChangeLog	5 May 2012 08:41:50 -0000	1.255
+++ ChangeLog	8 May 2012 08:11:10 -0000	1.256
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mpg123
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.255 2012/05/05 08:41:50 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/ChangeLog,v 1.256 2012/05/08 08:11:10 radhermit Exp $
+
+*mpg123-1.14.1 (08 May 2012)
+
+  08 May 2012; Tim Harder <radhermit@gentoo.org> +mpg123-1.14.1.ebuild:
+  Version bump.
 
   05 May 2012; Michał Górny <mgorny@gentoo.org> mpg123-1.13.2.ebuild,
   mpg123-1.13.7.ebuild, mpg123-1.13.8.ebuild, mpg123-1.14.0.ebuild:



1.1                  media-sound/mpg123/mpg123-1.14.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/mpg123-1.14.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/mpg123/mpg123-1.14.1.ebuild?rev=1.1&content-type=text/plain

Index: mpg123-1.14.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mpg123/mpg123-1.14.1.ebuild,v 1.1 2012/05/08 08:11:10 radhermit Exp $

EAPI=4
inherit toolchain-funcs libtool

DESCRIPTION="a realtime MPEG 1.0/2.0/2.5 audio player for layers 1, 2 and 3"
HOMEPAGE="http://www.mpg123.org/"
SRC_URI="http://www.mpg123.org/download/${P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="3dnow 3dnowext alsa altivec coreaudio ipv6 jack mmx nas oss portaudio pulseaudio sdl sse"

RDEPEND="alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )
	nas? ( media-libs/nas )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	sdl? ( media-libs/libsdl )
	sys-devel/libtool"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( AUTHORS ChangeLog NEWS NEWS.libmpg123 README )

src_prepare() {
	elibtoolize # for Darwin bundles
}

src_configure() {
	local _audio=dummy
	local _output=dummy
	local _cpu=generic_fpu

	for flag in nas portaudio sdl oss jack alsa pulseaudio coreaudio; do
		if use ${flag}; then
			_audio="${_audio} ${flag/pulseaudio/pulse}"
			_output=${flag/pulseaudio/pulse}
		fi
	done

	use altivec && _cpu=altivec

	if [[ $(tc-arch) == amd64 || ${ARCH} == x64-* ]]; then
		use sse && _cpu=x86-64
	elif use x86 && gcc-specs-pie ; then
		# Don't use any mmx, 3dnow, sse and 3dnowext #bug 164504
		_cpu=generic_fpu
	else
		use mmx && _cpu=mmx
		use 3dnow && _cpu=3dnow
		use sse && _cpu=x86
		use 3dnowext && _cpu=x86
	fi

	econf \
		--with-optimization=0 \
		--with-audio="${_audio}" \
		--with-default-audio=${_output} \
		--with-cpu=${_cpu} \
		--enable-network \
		$(use_enable ipv6)
}

src_install() {
	default
	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}