[gentoo-commits] gentoo-x86 commit in media-video/aravis: aravis-0.1.13.ebuild ChangeLog aravis-0.1.12.ebuild aravis-0.1.11.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/aravis: aravis-0.1.13.ebuild ChangeLog aravis-0.1.12.ebuild aravis-0.1.11.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/04/30 19:37:46

  Modified:             ChangeLog
  Added:                aravis-0.1.13.ebuild
  Removed:              aravis-0.1.12.ebuild aravis-0.1.11.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.4                  media-video/aravis/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	29 Mar 2012 18:03:59 -0000	1.3
+++ ChangeLog	30 Apr 2012 19:37:46 -0000	1.4
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/aravis
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v 1.3 2012/03/29 18:03:59 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v 1.4 2012/04/30 19:37:46 flameeyes Exp $
+
+*aravis-0.1.13 (30 Apr 2012)
+
+  30 Apr 2012; Diego E. Pettenò <flameeyes@gentoo.org> +aravis-0.1.13.ebuild,
+  -aravis-0.1.11.ebuild, -aravis-0.1.12.ebuild:
+  Version bump.
 
 *aravis-0.1.12 (29 Mar 2012)
 



1.1                  media-video/aravis/aravis-0.1.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/aravis-0.1.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/aravis-0.1.13.ebuild?rev=1.1&content-type=text/plain

Index: aravis-0.1.13.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/aravis-0.1.13.ebuild,v 1.1 2012/04/30 19:37:46 flameeyes Exp $

EAPI=4

KEYWORDS="~amd64"

if [[ ${PV} == "9999" ]]; then
	KEYWORDS=""
	EGIT_REPO_URI="git://git.gnome.org/aravis"
	EGIT_COMMIT="${aravis_LIVE_COMMIT:-master}"
fi

inherit versionator ${EGIT_COMMIT+git-2 autotools}

DESCRIPTION="Library for video acquisition using Genicam cameras."
HOMEPAGE="http://live.gnome.org/Aravis"

LICENSE="LGPL-2.1"
SLOT="0"

IUSE="X gstreamer"

GST_DEPEND="media-libs/gstreamer
	media-libs/gst-plugins-base"

RDEPEND=">=dev-libs/glib-2.22
	dev-libs/libxml2
	X? (
		>=x11-libs/gtk+-2.12:2
		${GST_DEPEND}
		media-libs/gst-plugins-base
		media-plugins/gst-plugins-xvideo
	)
	gstreamer? ( ${GST_DEPEND} )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-libs/gobject-introspection"

if [[ -z ${EGIT_COMMIT} ]]; then
	SRC_URI="mirror://gnome/sources/${PN}/$(get_version_component_range 1-2)/${P}.tar.xz"
else
	DEPEND+=" dev-util/gtk-doc dev-util/intltool"
fi

src_prepare() {
	if [[ -n ${EGIT_COMMIT} ]]; then
		intltoolize || die
		gtkdocize || die
		eautoreconf
	fi
}

src_configure() {
	econf \
		--disable-silent-rules \
		--disable-static \
		$(use_enable X viewer) \
		$(use_enable gstreamer gst-plugin) \
		--enable-introspection
}

src_install() {
	emake install DESTDIR="${D}" aravisdocdir="/usr/share/doc/${PF}"
	find "${D}" -name '*.la' -delete
}