[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.8.3-r1.ebuild mc-4.8.3.ebuild

[gentoo-commits] gentoo-x86 commit in app-misc/mc: ChangeLog mc-4.8.3-r1.ebuild mc-4.8.3.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    12/04/23 15:59:12

  Modified:             ChangeLog
  Added:                mc-4.8.3-r1.ebuild
  Removed:              mc-4.8.3.ebuild
  Log:
  Fixed crash when changing ownership wit "CTRL-x o" (bug #413259)
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.253                app-misc/mc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.253&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?rev=1.253&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/ChangeLog?r1=1.252&r2=1.253

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v
retrieving revision 1.252
retrieving revision 1.253
diff -u -r1.252 -r1.253
--- ChangeLog	22 Apr 2012 14:53:53 -0000	1.252
+++ ChangeLog	23 Apr 2012 15:59:12 -0000	1.253
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/mc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.252 2012/04/22 14:53:53 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/ChangeLog,v 1.253 2012/04/23 15:59:12 polynomial-c Exp $
+
+*mc-4.8.3-r1 (23 Apr 2012)
+
+  23 Apr 2012; Lars Wendler <polynomial-c@gentoo.org> -mc-4.8.3.ebuild,
+  +mc-4.8.3-r1.ebuild, +files/mc-4.8.3-fix-chown-crash.patch:
+  non-maintainer commit: Fixed crash when changing ownership wit "CTRL-x o"
+  (bug #413259). Permission granted by slyfox.
 
 *mc-4.8.3 (22 Apr 2012)
 



1.1                  app-misc/mc/mc-4.8.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.8.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-misc/mc/mc-4.8.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: mc-4.8.3-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/mc/mc-4.8.3-r1.ebuild,v 1.1 2012/04/23 15:59:12 polynomial-c Exp $

EAPI=4

inherit eutils flag-o-matic

MY_P=${P/_/-}

DESCRIPTION="GNU Midnight Commander is a text based file manager"
HOMEPAGE="http://www.midnight-commander.org"
SRC_URI="http://www.midnight-commander.org/downloads/${MY_P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x86-solaris"
IUSE="+edit gpm mclib nls samba +slang test X +xdg"

RDEPEND=">=dev-libs/glib-2.8:2
	gpm? ( sys-libs/gpm )
	kernel_linux? ( sys-fs/e2fsprogs )
	samba? ( net-fs/samba )
	slang? ( >=sys-libs/slang-2 )
	!slang? ( sys-libs/ncurses )
	X? ( x11-libs/libX11
		x11-libs/libICE
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libSM )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )
	test? ( dev-libs/check )
	"

S=${WORKDIR}/${MY_P}

src_prepare() {
	cp "${FILESDIR}"/${P}-missing-do_panel_cd_stub_env.c \
		tests/src/filemanager/do_panel_cd_stub_env.c || die

	# bug #413259
	epatch "${FILESDIR}"/${P}-fix-chown-crash.patch
}

src_configure() {
	local myscreen=ncurses
	use slang && myscreen=slang
	[[ ${CHOST} == *-solaris* ]] && append-ldflags "-lnsl -lsocket"

	local homedir=".mc"
	use xdg && homedir="XDG"

	econf \
		--disable-dependency-tracking \
		$(use_enable nls) \
		--enable-vfs \
		$(use_enable kernel_linux vfs-undelfs) \
		--enable-charset \
		$(use_with X x) \
		$(use_enable samba vfs-smb) \
		$(use_with gpm gpm-mouse) \
		--with-screen=${myscreen} \
		$(use_with edit) \
		$(use_enable mclib) \
		$(use_enable test tests) \
		--with-homedir=${homedir}
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS README NEWS

	# fix bug #334383
	if use kernel_linux && [[ ${EUID} == 0 ]] ; then
		fowners root:tty /usr/libexec/mc/cons.saver
		fperms g+s /usr/libexec/mc/cons.saver
	fi
}

pkg_postinst() {
	elog "To enable exiting to latest working directory,"
	elog "put this into your ~/.bashrc:"
	elog ". ${EPREFIX}/usr/libexec/mc/mc.sh"
}