[gentoo-commits] gentoo-x86 commit in media-video/mjpg-streamer: mjpg-streamer-0_pre20120421.ebuild ChangeLog

["Amadeusz Zolnowski (aidecoe)" <aidecoe@gentoo.org>]

aidecoe     12/04/23 10:00:59

  Modified:             ChangeLog
  Added:                mjpg-streamer-0_pre20120421.ebuild
  Log:
  Proxy commit on behalf of Andrzej Pauli <andrzej.pauli@gmail.com>.
  
  Version bump.  Fixes bug #411931.
  
  (Portage version: 2.1.10.57/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  media-video/mjpg-streamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	21 Apr 2012 20:20:45 -0000	1.2
+++ ChangeLog	23 Apr 2012 10:00:59 -0000	1.3
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/mjpg-streamer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v 1.2 2012/04/21 20:20:45 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/ChangeLog,v 1.3 2012/04/23 10:00:59 aidecoe Exp $
+
+*mjpg-streamer-0_pre20120421 (23 Apr 2012)
+
+  23 Apr 2012; Amadeusz Żołnowski <aidecoe@gentoo.org>
+  +files/0_pre20120421-make-var-instead-of-cmd.patch,
+  +mjpg-streamer-0_pre20120421.ebuild:
+  Proxy commit on behalf of Andrzej Pauli <andrzej.pauli@gmail.com>.  Version
+  bump.  Fixes bug #411931.
 
   21 Apr 2012; Amadeusz Żołnowski <aidecoe@gentoo.org>
   mjpg-streamer-0_pre20110522.ebuild:



1.1                  media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild?rev=1.1&content-type=text/plain

Index: mjpg-streamer-0_pre20120421.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mjpg-streamer/mjpg-streamer-0_pre20120421.ebuild,v 1.1 2012/04/23 10:00:59 aidecoe Exp $

EAPI=4

inherit eutils

DESCRIPTION="MJPG-streamer takes JPGs from Linux-UVC compatible webcams"
HOMEPAGE="http://sourceforge.net/projects/mjpg-streamer"
SRC_URI="http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

INPUT_PLUGINS="input_testpicture input_control input_file input_uvc "
OUTPUT_PLUGINS="output_file output_udp output_http output_autofocus output_rtsp"
IUSE_PLUGINS="${INPUT_PLUGINS} ${OUTPUT_PLUGINS}"
IUSE="${IUSE_PLUGINS} www v4l"
REQUIRED_USE="|| ( ${INPUT_PLUGINS} )
	|| ( ${OUTPUT_PLUGINS} )
	v4l? ( input_uvc )"

RDEPEND="virtual/jpeg
	v4l? ( input_uvc? ( media-libs/libv4l ) )"
DEPEND="${RDEPEND}
	input_testpicture? ( media-gfx/imagemagick )"

src_prepare() {
	epatch "${FILESDIR}/${PV}-make-var-instead-of-cmd.patch"

	local flag switch

	for flag in ${IUSE_PLUGINS}; do
		use ${flag} && switch='' || switch='#'
		sed -i \
			-e "s|^#*PLUGINS +\?= ${flag}.so|${switch}PLUGINS += ${flag}.so|" \
			Makefile
	done
}

src_compile() {
	local v4l=$(use v4l && use input_uvc && echo 'USE_LIBV4L2=true')
	emake ${v4l}
}

src_install() {
	into /usr
	dobin ${PN//-/_}
	dolib.so *.so

	if use www ; then
		insinto /usr/share/${PN}
		doins -r www
	fi

	dodoc README TODO

	newinitd "${FILESDIR}"/${PN}.initd ${PN}
	newconfd "${FILESDIR}"/${PN}.confd ${PN}
}

pkg_postinst() {
	elog "Remember to set an input and output plugin for mjpg-streamer."

	if use www ; then
		echo
		elog "An example webinterface has been installed into"
		elog "/usr/share/mjpg-streamer/www for your usage."
	fi
}