[gentoo-commits] gentoo-x86 commit in app-office/pybliographer: pybliographer-1.2.15.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-office/pybliographer: pybliographer-1.2.15.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     12/04/23 08:49:19

  Modified:             ChangeLog
  Added:                pybliographer-1.2.15.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.27                 app-office/pybliographer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/pybliographer/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/pybliographer/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/pybliographer/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/pybliographer/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	17 Apr 2012 16:06:21 -0000	1.26
+++ ChangeLog	23 Apr 2012 08:49:19 -0000	1.27
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/pybliographer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/pybliographer/ChangeLog,v 1.26 2012/04/17 16:06:21 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/pybliographer/ChangeLog,v 1.27 2012/04/23 08:49:19 patrick Exp $
+
+*pybliographer-1.2.15 (23 Apr 2012)
+
+  23 Apr 2012; Patrick Lauer <patrick@gentoo.org> +pybliographer-1.2.15.ebuild:
+  Bump
 
   17 Apr 2012; Brent Baude <ranger@gentoo.org> pybliographer-1.2.14.ebuild:
   Marking pybliographer-1.2.14 ppc for bug 404615



1.1                  app-office/pybliographer/pybliographer-1.2.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/pybliographer/pybliographer-1.2.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-office/pybliographer/pybliographer-1.2.15.ebuild?rev=1.1&content-type=text/plain

Index: pybliographer-1.2.15.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/pybliographer/pybliographer-1.2.15.ebuild,v 1.1 2012/04/23 08:49:19 patrick Exp $

EAPI="3"
PYTHON_DEPEND="2:2.6"

inherit autotools gnome2 python

DESCRIPTION="Pybliographer is a tool for working with bibliographic databases"
HOMEPAGE="http://pybliographer.org/"
SRC_URI="mirror://sourceforge/pybliographer/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

DOCS="AUTHORS ChangeLog* NEWS TODO README"

DEPEND=">=app-text/recode-3.6-r1
	app-text/scrollkeeper
	dev-libs/glib:2
	dev-python/gconf-python:2
	dev-python/gnome-vfs-python:2
	dev-python/libgnome-python:2
	dev-python/pygobject:2
	dev-python/pygtk:2
	>=dev-python/python-bibtex-1.2.5"
RDEPEND="${DEPEND}"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	gnome2_src_prepare

	# Disable byte-compilation of Python modules.
	sed -i \
		-e "/import compileall/d" \
		Makefile.am || die "sed failed"

	# Install Python modules into site-packages directories.
	find -name Makefile.am | xargs sed -i \
		-e "/^pybdir[[:space:]]*=[[:space:]]*/s:\$(datadir):$(python_get_sitedir):" || die "sed failed"
	sed -i \
		-e "s:\${datadir}/@PACKAGE@:$(python_get_sitedir)/@PACKAGE@:" \
		etc/installer.in || die "sed failed"
	sed -i \
		-e "s:gladedir = \$(datadir):gladedir = $(python_get_sitedir):" \
		Pyblio/GnomeUI/glade/Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	gnome2_src_configure --disable-depchecks
}

src_install() {
	gnome2_src_install
	python_convert_shebangs -r 2 "${ED}usr/bin"
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize pybliographer
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup pybliographer
}